Jump to content
Sign in to follow this  
Grosminet

IPC & _WinAPI_ReadProcessMemory issue

Recommended Posts

Hi,

I'm blocked on a strange issue concerning the use of '_WinAPI_ReadProcessMemory' to retrieve one 'String' between 2 cooperating applications based on the IPC method using a private 'Windows Message' handler (thanks to '_WinAPI_RegisterWindowMessage').

Let's me explain what happens:

1) - From a small GUI 'ipc-sender' application, the user can type any string (like 'abcde') and click a 'Send Data' button to exchange this info with another small 'ipc-receiver' application. the coding is done in such way ( '_DumpStruct()' method) that a trace of the data sent is dumped in an edit viewer inside the GUI: see the 'ipc-sender' script source below -->

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=ipc_sender.exe
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <MsgBoxConstants.au3>
#include <WinAPI.au3>
#include <WinAPISys.au3>
#include <ProcessConstants.au3>
#include <FontConstants.au3>
#include <GuiEdit.au3>
#include <ScrollBarsConstants.au3>
#include <Array.au3>

; Author : Grosminet

    Global Const $WM_IPC_PRIVATE_Grosminet = _WinAPI_RegisterWindowMessage('ipc_sender_to_receiver')
    Global Const $sAPP_me = "ipc_sender"
    Global Const $sAPP_other = "ipc_receiver"

    Global $guiw = 1000, $guih = 300, $guix = (@desktopwidth - $guiw - 50), $guiy = $guih + 150, $sp = 10, $x = $sp, $y = $sp, $w, $hbut = 28, $h
    Global $hParentGUI, $hSendBut, $hlocalPID, $hSendEdit, $hRecEdit
    Global $debug = true, $info, $PIDAppMe, $hOtherProcess
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    $hParentGui = GUICreate($sAPP_me, $guiw, $guih, $guix, $guiy)
    $w = ($guiw - 3*$sp) / 4
    $h = ($guih - 3* $sp) / 2
    $hSendBut = GUICtrlCreateButton("Send data", $x, $y, $w, $hbut)
    $y += $hbut + $sp
    $hlocalPID = GUIctrlCreateLabel("PID=", $x, $y, $w, $h)
    $x += $w + $sp
    $y = $sp
    $hSendEdit = GUIctrlCreateEdit("abcde", $x, $y, 3* $w, $h)
    $x = $sp
    $y += $h + $sp
    $hRecEdit = GUIctrlCreateEdit("", $x, $y, 4* $w, $h)
    GUICtrlSetFont(-1, 9, $FW_NORMAL, Default, "Courier New")
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    GUISetState(@SW_SHOW, $hParentGui)
    GUICtrlSetData($hlocalPID, "PID= " & @AutoItPID)
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    ; Get the RECEIVER application 'process handle'
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    Opt("WinTitleMatchMode", 1)
    $hOtherProcess = WinGetHandle($sAPP_other)
    if @error then
        MsgBox($MB_SYSTEMMODAL, "ERROR", "Unable to retrieve handle of " & $sAPP_other & ", error= " & @error)
        exit
    endif
    $info = " Receiver application --> " & $sAPP_other & " - Handle= " & $hOtherProcess & @crlf
    _ShowInfo($info)
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _myExit()
            Case $hSendBut
                _SendDATA_to_X()
        EndSwitch
    WEnd
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    Func _SendDATA_to_X()
        Local $sValue_To_Send = GUICtrlRead($hSendEdit)
        Local $iStringSize = StringLen($sValue_To_Send) + 1
        local $TagInfoStruct = "struct;wchar buf[" & $iStringSize & "];endstruct"
        Local $tValue_To_Send = DllStructCreate($TagInfoStruct)
        DllStructSetData($tValue_To_Send, "buf", $sValue_To_Send)
        ;
        Local $pValue_To_Send = DllStructGetPtr($tValue_To_Send)
        Local $iSizeStruct = DllStructGetSize($tValue_To_Send)
        $info = '_SendDATA_to_X(): Pointer to text= ' & $pValue_To_Send & " - Size of text= " & $iStringSize  & " - Size of structure= " & $iSizeStruct & @CRLF
        _ShowInfo($info)
        $info = _DumpStruct($pValue_To_Send, $iSizeStruct)
        _ShowInfo($info)
        ;
        local $ret = _WinAPI_PostMessage($hOtherProcess, $WM_IPC_PRIVATE_Grosminet, $pValue_To_Send, $iSizeStruct)
        If not $ret Then
            MsgBox($MB_SYSTEMMODAL, "ERROR", "_SendDATA_to_X(): " & $sAPP_me & " --> _WinAPI_PostMessage error= " &  _WinAPI_GetLastError())
        else
            Local $sData_Sent = StringLeft(DllStructGetData($tValue_To_Send, "buf"), $iStringSize)
            $info = '................: --> Data sent = ' & $sData_Sent & @CRLF
            _ShowInfo($info)
        endif
        $pValue_To_Send = 0
        $tValue_To_Send = 0
    EndFunc   ;==>_SendDATA_to_X
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    Func _ShowInfo($msg)
        if $debug then ConsoleWrite($msg)
        GUICtrlSetData($hRecEdit, GUICtrlRead($hRecEdit) & $msg)
        Local $iEnd = StringLen(GUICtrlRead($hRecEdit))
        _GUICtrlEdit_SetSel($hRecEdit, $iEnd, $iEnd)
        _GUICtrlEdit_Scroll($hRecEdit, $SB_SCROLLCARET)
    Endfunc ; _ShowInfo
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    Func _myExit()
        GUIDelete()
        exit
    Endfunc ; _myExit
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    Func _DumpStruct($p_STRUCT, $iSizeStruct)
        ; $iSizeStruct = the size of the struct in bytes (DllStructGetSize)
        
        Local $TagStructDump = "struct;align;byte[" & $iSizeStruct & "];endstruct"

        Local $t_Struct = DllStructCreate($TagStructDump, $p_STRUCT)
        Local $i
        Local $structInfo = ""
        _ConsoleWriteInfo($structInfo, "Structure size: " & $iSizeStruct & " byte(s):" & @crlf)
        for $i = 0 to $iSizeStruct - 1
            _ConsoleWriteInfo($structInfo, hex(DllStructGetData($t_Struct, 1, $i), 2) & " ")
            if (Mod($i+1, 8) = 0) then
                _ConsoleWriteInfo($structInfo, @CRLF)
            Endif
        Next
        _ConsoleWriteInfo($structInfo, @CRLF)
        return $structInfo
    EndFunc ; _DumpStruct
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    Func _ConsoleWriteInfo(ByRef $msg, $txt)
        $msg &= $txt
    EndFunc ; _ConsoleWriteInfo

2) - From a small GUI 'ipc-receiver' application, the user can check the values of data received thanks to the same '_DumpStruct()' method: --> see the 'ipc-receiver' script :

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=ipc_receiver.exe
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <MsgBoxConstants.au3>
#include <WinAPI.au3>
#include <WinAPISys.au3>
#include <ProcessConstants.au3>
#include <FontConstants.au3>
#include <GuiEdit.au3>
#include <ScrollBarsConstants.au3>
#include <WinAPIDiag.au3>

; Author : Grosminet

    Global Const $WM_IPC_PRIVATE_Grosminet = _WinAPI_RegisterWindowMessage('ipc_sender_to_receiver')
    Global Const $sAPP_me = "ipc_receiver"
    Global Const $sAPP_other = "ipc_sender"
    Global Const $sSenderEXE = @scriptdir & "\" & $sAPP_other & ".exe"

    Global $guiw = 1000, $guih = 300, $guix = (@desktopwidth - $guiw - 50), $guiy = 100, $sp = 10, $x = $sp, $y = $sp, $w, $hbut = 28, $h
    Global $hParentGUI, $hlocalPID, $hRecEdit
    Global $debug = true, $info, $hProcessOther, $PIDAppMe, $PIDAppOther, $iRead, $aret
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    $hParentGui = GUICreate($sAPP_me, $guiw, $guih, $guix, $guiy)
    $w = ($guiw - 2*$sp)
    $hlocalPID = GUIctrlCreateLabel("PID=", $x, $y, $w, $hbut)
    $y += $hbut + $sp
    $h = ($guih - $y - $sp)
    $hRecEdit = GUIctrlCreateEdit("", $x, $y, $w, $h)
    GUICtrlSetFont(-1, 9, $FW_NORMAL, Default, "Courier New")
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    GUIRegisterMsg($WM_IPC_PRIVATE_Grosminet, 'WM_FROM_APP')
    GUISetState(@SW_SHOW, $hParentGui)
    GUICtrlSetData($hlocalPID, "PID= " & @AutoItPID)
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    ; Get the SENDER application 'pid'
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    $PIDAppOther = ShellExecute($sSenderEXE)
    if $PIDAppOther = -1 then
        MsgBox($MB_SYSTEMMODAL, "ERROR", "Unable to start " & $sAPP_other & " --> error= " & @error)
        exit
    Endif
    sleep(500)
    $info = "Ready to receive ! Please send a text ..." & @CRLF
    _ShowInfo($info)
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    ; Get the SENDER application 'process handle'
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    $hProcessOther = _WinAPI_OpenProcess($PROCESS_VM_READ, False, $PIDAppOther)
    if @error Then
        $info = "_WinAPI_OpenProcess() error: " & @error & @crlf
        _ShowInfo($info)
        exit
    endif
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _myExit()
        EndSwitch
    WEnd
; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    Func WM_FROM_APP($hWnd, $iMsg, $wParam, $lParam)
        $info = "..... METHOD 1: _WinAPI_CreateBuffer ....." & @crlf
        _ShowInfo($info)
        _Method_1($wParam, $lParam)
        ;
        $info = "..... METHOD 2: DllStructCreate .........." & @crlf
        _ShowInfo($info)
        _Method_2($wParam, $lParam)
    EndFunc   ;==>WM_FROM_APP
; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    Func _Method_1($wParam, $lParam)
        Local $iStrucSize_SENT = Int($lParam)
        Local $pBuffer = _WinAPI_CreateBuffer($iStrucSize_SENT)
        $aret = _WinAPI_ReadProcessMemory($hProcessOther, $wParam, $pBuffer, $iStrucSize_SENT, $iRead)
        ;
        $info = _DumpStruct($pBuffer, $iStrucSize_SENT)
        _ShowInfo($info)
        _ShowInfo(_WinAPI_GetString($pBuffer) & @crlf & "--------------------------------" & @crlf)
        _WinAPI_FreeMemory($pBuffer)
    EndFunc ; _Method_1
; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    Func _Method_2($wParam, $lParam)
        Local $iStrucSize_SENT = Int($lParam)
        local $TagInfoStruct = "struct;align;byte buf[" & $iStrucSize_SENT & "];endstruct"
        Local $tbuffer = DllStructCreate($TagInfoStruct)
        Local $iSizeStruct = DllStructGetSize($tbuffer)
        Local $pBuffer = DllStructGetPtr($tbuffer)
        $aret = _WinAPI_ReadProcessMemory($hProcessOther, $wParam, $pBuffer, $iStrucSize_SENT, $iRead)
        ;
        $info = _DumpStruct($pBuffer, $iStrucSize_SENT)
        _ShowInfo($info)
        _ShowInfo(_WinAPI_GetString($pBuffer) & @crlf & "--------------------------------" & @crlf)
        $pBuffer = 0
    EndFunc ; _Method_2
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    Func _ShowInfo($msg)
        if $debug then ConsoleWrite($msg)
        GUICtrlSetData($hRecEdit, GUICtrlRead($hRecEdit) & $msg)
        Local $iEnd = StringLen(GUICtrlRead($hRecEdit))
        _GUICtrlEdit_SetSel($hRecEdit, $iEnd, $iEnd)
        _GUICtrlEdit_Scroll($hRecEdit, $SB_SCROLLCARET)
    Endfunc ; _ShowInfo
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    Func _myExit()
        _WinAPI_CloseHandle($hProcessOther)
        ProcessClose($PIDAppOther)
        GUIDelete()
        exit
    Endfunc ; _myExit
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    Func _DumpStruct($p_STRUCT, $iSizeStruct)
        ; $iSizeStruct = the size of the struct in bytes (DllStructGetSize)
        
        Local $TagStructDump = "struct;align;byte[" & $iSizeStruct & "];endstruct"

        Local $t_Struct = DllStructCreate($TagStructDump, $p_STRUCT)
        Local $i
        Local $structInfo = ""
        _ConsoleWriteInfo($structInfo, "Structure size: " & $iSizeStruct & " byte(s):" & @crlf)
        for $i = 0 to $iSizeStruct - 1
            _ConsoleWriteInfo($structInfo, hex(DllStructGetData($t_Struct, 1, $i), 2) & " ")
            if (Mod($i+1, 8) = 0) then
                _ConsoleWriteInfo($structInfo, @CRLF)
            Endif
        Next
        _ConsoleWriteInfo($structInfo, @CRLF)
        return $structInfo
    EndFunc ; _DumpStruct
    ; ooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    Func _ConsoleWriteInfo(ByRef $msg, $txt)
        $msg &= $txt
    EndFunc ; _ConsoleWriteInfo

The ISSUE : systematically, the 3 first bytes received are 'corrupted' !!! ???

NOTE: You must repeat several times sending the same string to check that  bytes sent" and "bytes received"  are equal EXCEPT the 3 first ones !

I'm quite sure that my code is somewhere wrong ! BUT I'm not able to discover myself WHERE ! I have tried to use 2 methods to read and save the external memory bytes (using the '_WinAPI_CreateBuffer' function, and the 'DllStructCreate' function) --> BOTH give me back the same issue.

--> So I suspect that my understanding of the '_WinAPI_ReadProcessMemory' function is maybe wrong and I do not correctly call this API.

??? Is it correct if I say, [according the MSDN 's ReadProcessMemory explanation or the #include <WinAPI.au3> library code of this function] :

- the base address of memory to be read is the pointer received from my private WM handler --> i.e. $wParam (regarding my script receiver code)

- the buffer pointer where to save bytes read (starting from $wParam) is the pointer created using '_WinAPI_CreateBuffer' or 'DllStructCreate + DllStructGetPtr' functions

- the number of bytes to be read is the information provided by the $lParam variable (regarding my script receiver code)

- AND of course, the external memory base-address will only be readable if the 'ipc-sender' application handler is correctly declared ($hProcessOther = _WinAPI_OpenProcess($PROCESS_VM_READ, False, $PIDAppOther)).

There is probably other methods to share strings between cooperating applications, and surely more simple and elegant ones, BUT I'm focusing on these scripts where in fact the types of data to share are not limited to the 'String' type, but could concern any kind of structure.

Any advice or help to explain me what happens would be welcome.

Great Thanks in advance for your time passed to help me...

Alain.

These are my environment characteristics:

AutoIT : 3.3.14.2

OS: Windows 7 Home Premium Service Pack 1 / 7601

 

 

ipc_receiver.au3

ipc_sender.au3

Share this post


Link to post
Share on other sites

Hi,

No reply  ??? ...

Well, I have found this post : brainstorming-ipc-string-exchange, where "GUINNESS" indicates : ' Well I personally think WM_COPYDATA is an elegant solution ...'

So I will follow this advice and post later the corresponding results: ... first trials seems OK ...

I still be curious about the issue described previously !

Alain.

Here are the final scripts:

receiver.au3

sender.au3

Edited by Grosminet
Adding last results.

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  

  • Recently Browsing   0 members

    No registered users viewing this page.

  • Similar Content

    • By SteveJM
      When I use DllStructCreate() to reserve a chunk of memory I would like to know if I can rely on that memory being initialized to zero. Experience suggests that it is, but I have been searching to try and find a definitive statement anywhere that this is the case. I apologise if I have missed somewhere. Part of the reason for this question is so that my next search (after my personal memory has dimmed) should yield a link to this post, hopefully with an answer.
      A number of DLLs I use have structs where a few parts have to be explicitly set and other parts are reserved with the instruction that they must be set to zero. Because DllStructCreate() appears to zero-initialise the memory, I tend to forget to do it explicitly and everything seems to work. I am wondering whether I have been lucky and am storing up trouble for myself. It seems likely that the OS has been asked for zeroed memory, but without a promise in the documentation for DllStructCreate(),  perhaps that could change? Perhaps the developers wish to reserve the right to change their minds?
    • By argumentum
      so in https://www.autoitscript.com/forum/topic/193254-solved-ipc-between-system-and-user/ I asked around about IPCs and got all the answers I was looking for.
      Now the question is: what IPC is most "resilient" on an overwhelmed PC, meaning, the CPU is at 100%, memory is top out and, as is always, need to rely on the IPC.
      ..and all this happened because I open over 100 GUIs at once 😜
      ..but it happens sporadically on low CPU or memory demand anyways.
      ..should I sleep() some time before running another instance ?
      I did not know if to make the question in technical, chat, ..or here. So it's here.   
      Since you will ask what I've tried, I've used the IPC from the Fork UDFish ( WM_COPYDATA that can do Admin/user mix ) and the FMIPC file mapping,  that work under the same conditions.
      So, how do you handle IPC if it fails ?
       
    • By tatane
      Hi,
      I would like to send an array from a script to a another. This array has 1000 rows and 4 columns with this kind of data :
      1st row  =     528  ;  31  ;   HOSTNAME|1|02:45:47|abcdefgh|username|5   ;   old
      2nd row = ...
      What IPC should I use ?
       
       
    • By argumentum
      I was in need of an IPC (Interprocess communication) between system, admin and user levels, and ended up writing this UDF to suit my wantings.
      Hope you find it useful too.
      Works from WinXP/Server2003 to the now current Win10/Server2016.
      It communicates between any mix of x32, x64, Admin, User.

      In the zip file, there is the UDF and an example: FMIPC(v0.2018.04.04).zip
      Special thanks to @RTFC for the help in the support forum   
    • By argumentum
      There is this topic on Examples about IPC. My question is: What is the best IPC to work with between a script running as SYSTEM level, User level, and Administrator level to interact with each other ? 
      Thanks
×
×
  • Create New...