a problem with _ArrayToString

[DanielIvanCorti]

Hi all,

I am facing a problem with _ArrayToString: when it's used on an array filled usign BinaryToString, it only puts the first element in the string generated. I have been trying for an hour different solutions without success..

#include <String.au3>
#include <Array.au3>
global $array[4]

$array[0] = BinaryToString(99)
$array[1] = BinaryToString(89)

_ArrayDisplay($array)

MsgBox(0, "", _ArrayToString($array))

Am I wrong or is there a bug?

Thank you very much,
Daniel

Edited November 20, 2016 by DanielIvanCorti

[Melba23]

DanielIvanCorti,

Welcome to the AutoIt forums.

Looking at the way AutoIt stores the BinaryToString result, it seems it pads the return with zeros as you can see here:

#include <String.au3>
#include <Array.au3>
global $array[4]

$array[0] = BinaryToString(99)
$array[1] = BinaryToString(89)
ConsoleWrite(StringToBinary($array[0]) & " - " & StringLen($array[0]) & @CRLF)
ConsoleWrite(StringToBinary($array[1]) & " - " & StringLen($array[1]) & @CRLF)

_ArrayDisplay($array)

$sString = _ArrayToString($array)

ConsoleWrite(StringToBinary($sString) & " - " & $sString & @CRLF)

MsgBox(0, "", _ArrayToString($array))

So the string created by _ArrayToString terminates at the first 00 which is interpreted as EOL. Now to look into why it does this.

A question for you: why are you using BinaryToString to convert the elements for storage?

M23

Edited November 20, 2016 by Melba23
Added question

[DanielIvanCorti]

Hi M23,
thank you for your reply.

Umh.. I am a bit confused now..

I am taking a string into an array as binary and doing BitXOR operations (to decrypt a text), it works fine. But as you can see I cannot have back the plaintext string from the array..

Func _Crypt gives its output as HEX to simplify the handling of the crypted message.

#include <Array.au3>
#include <String.au3>

$string = "ABCD"
$key="GGHJ"
$Crypted = _Crypt(StringSplit($string, ""), StringSplit($key, ""))
$Decrypted = _Decrypt(StringSplit($Crypted, ":"), StringSplit($key, ""))

MsgBox(0, "", $Crypted)
MsgBox(0, "", $Decrypted)

Func _Crypt($array, $key)
   For $a = 1 To $array[0]
      $array[$a] = Hex(BitXOR(StringToBinary($array[$a]), StringToBinary($key[$a])),2)
   Next
Return _ArrayToString($array, ":", 1)
EndFunc

Func _Decrypt($array, $key)
    _ArrayDisplay($array)
   MsgBox(0, "", _ArrayToString($array, "", 1))
   For $a = 1 To $array[0]
      $array[$a] = BinaryToString(BitXOR(Dec($array[$a]), StringToBinary($key[$a])))
   Next
Return _ArrayToString($array, "", 1)
EndFunc

[Melba23]

DanielIvanCorti,

The immediate solution to the problem is easy - use StringLeft to extract only the first character of the decrypted string, so removing all the unwanted EOLs:

$array[$a] = StringLeft(BinaryToString(BitXOR(Dec($array[$a]), StringToBinary($key[$a]))), 1)

However, I am unsure quite why the returned string is padded with these additional 00 characters - I will investigate further.

M23

[DanielIvanCorti]

Ok, thank you very much for your help.

One last question.. is it correct to do XOR like am I doing? BitXOR is really doing the XOR between bits or it is operating on the RAPPRESENTATION of that bits (like if it was a string)?

Edited November 21, 2016 by DanielIvanCorti

[Melba23]

DanielIvanCorti,

The explanation for the added zeroes is that AutoIt treats the number as a 32-bit integer (4 bytes) so its binary variant is same.

No idea about the new question - well beyond my ken.

M23

[UEZ]

As a workaround you can use this function:

Func _Decrypt($array, $key)
    _ArrayDisplay($array)
   MsgBox(0, "", _ArrayToString($array, "", 1))
   For $a = 1 To $array[0]
      $array[$a] = StringStripWS(BinaryToString(BitXOR(Dec($array[$a]), StringToBinary($key[$a]))), 8)
   Next
Return _ArrayToString($array, "", 1)
EndFunc

 

[DanielIvanCorti]

Thank you