GUIcreatbutton with for loop.

[nlta1992]

I want creat GUI, have button 1 to 10, but only use loop for ... to ... step ... next.

Thanks.

[LeCarre]

Could you be more clear on what you need?

[Melba23]

nlta1992,

Something like this perhaps?

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

; Array to hold button ControlIDs
Global $aButton[11]

$hGUI = GUICreate("Test", 500, 500)

; A double loop to space out the buttons - but you could very easily have a single one instead
For $i = 0 To 1
    For $j = 1 To 5
        $iIndex = ($i * 5) + $j
        ; Create button using a suitable algorithm to locate it
        $aButton[$iIndex] = GUICtrlCreateButton("Button " & $iIndex, 10 + (250 * $i), ($j * 50) - 30, 80, 30)
    Next
Next

GUISetState()

While 1

    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case Else
            ; See if a button was pressed
            For $i = 1 To 10
                If $iMsg = $aButton[$i] Then
                    ; Do what is necessary
                    MsgBox($MB_SYSTEMMODAL, "Pressed", "Button " & $i)
                    ; No point in looking further
                    ExitLoop
                EndIf
            Next
    EndSwitch

WEnd

M23

[nlta1992]

Ok thanks Melba23 

[antonioj84]

Hey Melba,

Can you show a quick example how would you do that with a check radio button, starting state will be uncheck.

 

Thanks

[Melba23]

antonioj84,

Simply replace GUICtrlCreateButton with GUICtrlCreateRadio.

M23

[antonioj84]

Melba,  your coding style is awesome . 

[antonioj84]

adding unique name radio button

; Array to hold button ControlIDs
;Global $aButton[11]    ; 4x 5 = 21
Global $aButton[11]
Global $aName[11]=["0","Ajohn","Bjohn","Cjohn","Djohn","Ejohn","Fjohn","Jjohn","Hjohn","Ijohn","Jjohn"]
$hGUI = GUICreate("Test", 500, 500)

; A double loop to space out the buttons - but you could very easily have a single one instead
For $i = 0 To 1        ; 0 to 3  x4
    For $j = 1 To 5
        $iIndex = ($i * 5) + $j
        ; Create button using a suitable algorithm to locate it
        $aButton[$iIndex] = GUICtrlCreateRadio($aName[$iIndex] &$iIndex, 10 + (150 * $i), ($j * 50) - 30, 80, 30) ; $index,20
    Next
Next

GUISetState()

While 1

    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case Else
            ; See if a button was pressed
            For $i = 1 To 10             ;20
                If $iMsg = $aButton[$i] Then
                    ; Do what is necessary
                    MsgBox($MB_SYSTEMMODAL, "Pressed", "Button " & $i)
                    ; No point in looking further
                    ExitLoop
                EndIf
            Next
    EndSwitch

WEnd