[Solved] Stop GUI until message box closed

[AnonymousX]

Hello,

I'm trying to make it so that when a message box pops up that the GUI will be unresponsive until that message box has been closed. From reading through the help the closest thing I can find is the WinWaitClose function, however this doesn't work fully as desired. If user tries to click on GUI the actions are more just waiting for the message box to close, so that once it closes everything happens at once. I want it so that the GUI is completely unusable until message box is closed. 

 

Below is test code to demonstrate the problem and help explain what I want. Any advice on this?

 

#include <GUIConstantsEx.au3>

Example()

Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Example")
    Local $idOK = GUICtrlCreateButton("OK", 310, 370, 85, 25)
    local $but = GUICtrlCreateButton("Hello", 150,150,85,25)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)
    MsgBox( 262144,"Message","Try hitting the hello button several times,without closing this window. Now close this window and see how script wasn't restricted it just was waiting and storing the instructions")



    WinWaitClose("Message")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idOK
                Exit
            case $but
                MsgBox(0,"","Hello")

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

 

Edited March 27, 2017 by AnonymousX

[232showtime]

#include <GUIConstantsEx.au3>

Example()

Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Example")
    Local $idOK = GUICtrlCreateButton("OK", 310, 370, 85, 25)
    Local $but = GUICtrlCreateButton("Hello", 150, 150, 85, 25)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)
    GUISetState(@SW_DISABLE, $hGUI) ;added
    MsgBox(262144, "Message", "Try hitting the hello button several times,without closing this window. Now close this window and see how script wasn't restricted it just was waiting and storing the instructions")
    GUISetState(@SW_ENABLE, $hGUI);added


;~  WinWaitClose("Message")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idOK
                Exit
            Case $but

                MsgBox(0, "", "Hello")

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

EDIT: check the help file for additional info

Edited March 25, 2017 by 232showtime

[Melba23]

AnonymousX,

A better solution is to set the correct style for the MsgBox like this:

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Example")
    Local $idOK = GUICtrlCreateButton("OK", 310, 370, 85, 25)
    local $but = GUICtrlCreateButton("Hello", 150,150,85,25)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)
    MsgBox($MB_TOPMOST + $MB_TASKMODAL,"Message","Try hitting the hello button several times,without closing this window. Now close this window and see how script wasn't restricted it just was waiting and storing the instructions")

    WinWaitClose("Message")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idOK
                Exit
            case $but
                MsgBox(0,"","Hello")

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

All is explained in the Modal MsgBox Styles tutorial in the Wiki.

M23

 

[Trong]

Normal way:

#include <GUIConstantsEx.au3>

Example()

Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Example")
    Local $idOK = GUICtrlCreateButton("OK", 310, 370, 85, 25)
    Local $but = GUICtrlCreateButton("Hello", 150, 150, 85, 25)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)
    MsgBox(262144, "Message", "Try hitting the hello button several times,without closing this window. " & _
            "Now close this window and see how script wasn't restricted it just was waiting and storing the instructions", 0, $hGUI)

;~     WinWaitClose("Message")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idOK
                Exit
            Case $but
                MsgBox(0, "", "Hello")

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

 

[AnonymousX]

Thanks everyone for the help!

Special thanks to you Melba23,

That is exactly how I thought it should be done, I just would have never known by the description in the message box help what " Task modal " meant, and never would have thought to test that. Thanks for helping!

 

Edited March 27, 2017 by AnonymousX