[Solved] AdlibRegister fails after 'stop executing' uncompiled script

[Simpel]

Hi, I wrote a script using 2 GUIs. At some point I AdlibRegister a function to always WinActivate GUI1 if GUI2 is activated.

Most of the time it works perfect. But I have the feeling that nearly always if I stop executing the uncompiled au3 with Strg+Break and restart the script then the AdlibRegister returns 1 but will not run. If I exit the script with Exit everything is fine.

Did I noticed it right? Is there a AdlibRegister issue if script is aborted? Is there a possibility to fix this?

Regards, Conrad

P.S. The script is about 1000 lines, so I think it wouldn't be helpful posting it. And I have no idea how to make it very small but prove the issue.

Edited March 25, 2017 by Simpel
[Solved]

[Jos]

35 minutes ago, Simpel said:

Strg+Break

You mean in SciTE?  This will kill the process so don't expect any clean termination of the script.

Jos

[InunoTaishou]

#include <GUIConstants.au3>
#include <WinAPI.au3>
#include <WinAPISys.au3>

Global Const $WA_ACTIVE = 1
Global Const $WA_CLICKACTIVE = 2

Global $hMain = GUICreate("Window 1")
Global $hSecond = GUICreate("Window 2")

GUIRegisterMsg($WM_ACTIVATE, WM_ACTIVATE)

GUISetState(@SW_SHOW, $hMain)
GUISetState(@SW_SHOW, $hSecond)


While (True)
    Switch (GUIGetMsg())
        Case $GUI_EVENT_CLOSE
            Exit 0
    EndSwitch
WEnd

Func WM_ACTIVATE($hWnd, $iMsg, $wParam, $lParam)
    Switch (_WinAPI_LoWord($wParam))
        Case $WA_ACTIVE, $WA_CLICKACTIVE
            Switch ($hWnd)
                Case $hSecond
                    ConsoleWrite("[" & @MIN & ":" & @SEC & ":" & @MSEC & "] Second window set to active, changing to main" & @LF)
                    Return _WinAPI_SetActiveWindow($hMain)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_ACTIVATE

Give that a go instead of using AdLibRegister. Just use GUIRegisterMsg($WM_ACTIVATE, "") to turn off the activate function

Edited March 26, 2017 by InunoTaishou
Changed $WA_INACTIVE to $WA_CLICKACTIVE, had the proper value, just the wrong name

[Simpel]

Hi @InunoTaishou,

your example works perfect. I have to prove whether I can put it into my script without greater problems. I'll give it a try.

Thank you and regards, Conrad

[Simpel]

There was no problem to implement this. Thanks again.