GuiExtender problem

[Melba23]

antonioj84,

No need to "hack" anything, the UDF works just fine with borderless GUIs:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#include "GUIExtender.au3"

#include <SendMessage.au3>

Global Const $SC_DRAGMOVE = 0xF012

HotKeySet("{ESC}", "_Exit")

$hGUI = GUICreate("Vertical", 300, 390, 100, 100, BitOR($WS_POPUP, $WS_BORDER))
GUISetBkColor(0xFF0000, $hGUI)

_GUIExtender_Init($hGUI)

_GUIExtender_Section_Create($hGUI, 0, 60)
GUICtrlCreateGroup(" 1 - Static ", 10, 10, 280, 50)
; Create action button for next section
_GUIExtender_Section_Activate($hGUI, 2, "", "", 270, 40, 15, 15) ; Normal button
; Create native controls within the section creation structure - before starting next section
$cButton_1 = GUICtrlCreateButton("Toggle All", 20, 25, 80, 20)

_GUIExtender_Section_Create($hGUI, Default, 110) ; using Default for position follows on from previous sections
GUICtrlCreateGroup(" 2 - Extendable ", 10, 70, 280, 100)

_GUIExtender_Section_Create($hGUI, -1, 60) ; As does -1
GUICtrlCreateGroup(" 3 - Static", 10, 180, 280, 50)
_GUIExtender_Section_Activate($hGUI, 4, "Close 4", "Open 4", 125, 195, 60, 20, 1) ; Push button

_GUIExtender_Section_Create($hGUI, -1, 60)
GUICtrlCreateGroup(" 4 - Extendable ", 10, 240, 280, 50)

_GUIExtender_Section_Create($hGUI) ; using the default values for both location and size fills the remainder of the GUI
GUICtrlCreateGroup(" 5 - Static", 10, 300, 280, 80)
; Create and action button for all sections
_GUIExtender_Section_Activate($hGUI, 0, "Close All", "Open All", 20, 340, 60, 20) ; Normal button

; Close section creation
_GUIExtender_Section_Create($hGUI, -99)

GUICtrlCreateGroup("", -99, -99, 1, 1)

_GUIExtender_Section_Action($hGUI, 4, 0)

GUISetState()

While 1
    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYDOWN
            _SendMessage($hGUI, $WM_SYSCOMMAND, $SC_DRAGMOVE, 0)
        Case $cButton_1
            _GUIExtender_Section_Action($hGUI, 0, 9) ; Mode 9 = toggle all moveable sections
    EndSwitch

    _GUIExtender_EventMonitor($hGUI, $iMsg) ; Check for click on section action control

WEnd

Func _Exit()
    Exit
EndFunc

M23

[antonioj84]

thanks you are correct , i had to comment these 2 lines in my menu and i had borderless menu. 

;$iStyle2 = BitOR($WS_MAXIMIZEBOX, $WS_CAPTION, $WS_SYSMENU) ; Style without minimize box
;GUISetStyle($iStyle2)

 

Edited July 3, 2017 by antonioj84
error