Detect Double Click on GUI button

[IanN1990 14]

Hi, 

 

I am trying to detect a gui button double click without using TimerInit or a global mouse hook.

Below is some code i have tried but cant understand why it is not working.

 

; *** Start added by AutoIt3Wrpper ***
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
; *** End added by AutoIt3Wrapper ***
#AutoIt3Wrapper_UseX64=n
#AutoIt3Wrapper_Run_AU3Check=n
#AutoIt3Wrapper_Add_Constants=n

$hGUI = GUICreate("Test", 500, 500)
$Button = GUICtrlCreateButton("test", 10, 10, 400, 30)
GUIRegisterMsg($WM_COMMAND, "MY_WM_COMMAND")
GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func MY_WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $nNotifyCode = BitShift($wParam, 16)
    Local $nID = BitAND($wParam, 0x0000FFFF)
    Local $hCtrl = $lParam
    If $nNotifyCode = $BN_DBLCLK And $nID = $Button Then
        ConsoleWrite("B")
       ; do stuff
        Return 0
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc

Now i know the GUI register has worked, My_WM_Command is receiving messages, $nID is getting the correct handle but $nNotifyCode is always the same?

Edited May 19, 2017 by IanN1990

[BrewManNH 1,178]

Change this line:

$Button = GUICtrlCreateButton("test", 10, 10, 400, 30, BitOR($BS_NOTIFY, $GUI_SS_DEFAULT_BUTTON))

As stated by MSDN page on the page for notifications.

Quote

BN_DBLCLK notification code

Sent when the user double-clicks a button. This notification code is sent automatically for BS_USERBUTTON, BS_RADIOBUTTON, and BS_OWNERDRAW buttons. Other button types send BN_DBLCLK only if they have the BS_NOTIFY style.

 

Edited May 19, 2017 by BrewManNH