_IELinkGetCollection - How to write an array in a For - In - Next loop?

[Sanja]

Dear forum,

I want to get all the links from a website via _IELinkGetCollection and store them imediatley in an array.

As the title states I have a problem with creating an array in a For - In - Next loop.

I know, I know the helpfile says that arrays in an For-In-Next loop are readonly. I thought that aplies only to the array I am reading - not the one I am writing in, if they are different arrays.

Anyway, I tried the following:

#include <AutoItConstants.au3>
#include <IE.au3>
#include <Array.au3>

Local $oIEBasic = _IE_Example ("basic")

Local $aLinkPaths
Local $oAllWebsiteLinks = _IELinkGetCollection($oIEBAsic)
Local $i = 0

For $oSingleLink In $oAllWebsiteLinks
     $i = $i + 1
     $aLinkPaths [$i] = _IEPropertyGet ($oSingleLink, "innertext")
Next

_IEQuit ($oIEBasic)

Exit

Which leads to the following error message:

"Line 29
$aLinkPaths [$i] = _IEPropertyGet ($oSingleLink, "innertext")
$aLinkPaths ^ ERROR
Error: Subscript used on non-accessible variable."

Then I tried a For-To loop, which just freezes the script so I have to end it with the task manager and also does not show any array.
To be honest I dont even know if I am allowed to treat a collection object as an array...

#include <AutoItConstants.au3>
#include <IE.au3>
#include <Array.au3>

Local $oIEBasic = _IE_Example ("basic")

Local $aLinkPaths
Local $oAllWebsiteLinks = _IELinkGetCollection($oIEBAsic)

For $oAllWebsiteLinks [0] To UBound ($oAllWebsiteLinks) - 1
     $aLinkPaths [$i] = _IEPropertyGet ($oSingleLink, "innertext")
Next

_ArrayDisplay ($aLinkPaths)                 

_IEQuit ($oIEBasic)

Exit

I found a solution with the _ArrayAdd function.

#include <AutoItConstants.au3>
#include <IE.au3>
#include <Array.au3>

Local $oIEBasic = _IE_Example ("basic")

Local $aLinkPaths [0]
Local $sLinkInnerText
Local $oAllWebsiteLinks = _IELinkGetCollection($oIEBAsic)

For $oSingleLink In $oAllWebsiteLinks
      $sLinkInnerText = _IEPropertyGet ($oSingleLink, "innertext")
      _ArrayAdd ( $aLinkPaths, $sLinkInnerText)
Next

_ArrayDisplay ($aLinkPaths)

_IEQuit ($oIEBasic)

Exit

So I already have a solution for my problem which works just fine. It seems that I am allowed  and fill an array in a For-In-Next loop by just adding values to an existing array. I am just curious if there is an "easier" way to do what I wanted with a solution which looks more like what I tried to first two times.

Thank you in advance.

[jchd]

Try this:

#include <AutoItConstants.au3>
#include <IE.au3>
#include <Array.au3>

Local $oIEBasic = _IE_Example("basic")

Local $oAllWebsiteLinks = _IELinkGetCollection($oIEBAsic)
Local $aLinkPaths[@extended]
Local $i = 0

For $oSingleLink In $oAllWebsiteLinks
     $aLinkPaths[$i] = _IEPropertyGet($oSingleLink, "innertext")
     $i = $i + 1
Next

_IEQuit ($oIEBasic)

_ArrayDisplay($aLinkPaths)

Help on _IELinkGetCollection() says that @extended returns the number of links in the collection.

[Sanja]

Ah right, I didnt think of alle the @... functions.

Now it works just as intended.

Thank you very much, jchd!