Sorting STR-Arrays Numerical...possible?

[knolle93]

Hey guys im still stucking at my Script from my prevous Thread.

Spoiler

expandcollapse popup

Func Refresh()
IniDelete(@Scriptdir&"\data.ini","Daten")
CreateBelegungsliste()
$aSBL = "Tag"&@TAB&"Umzüge"&@CRLF & _ArrayToString($Belegungsliste,@TAB,1)

GUICtrlSetData($Edit1, $aSBL)

EndFunc

;~ CreateBelegungsliste()







Func CreateBelegungsliste()
;~ ##############################################################
;~          Some Variables
;~ ##############################################################
$inifile = @Scriptdir&"\data.ini"
$i = 1
$aOrdnerInhalte = _FileListToArray(@ScriptDir,"*",2)

;~ ##############################################################
;~          Infi Loop
;~ ##############################################################
While 1

      If $i > $aOrdnerInhalte[0] Then
      ExitLoop
      EndIf


;~ write all acquired data to an ini file
   Local $aDirWA = DirGetSize(@ScriptDir&"\"&$aOrdnerInhalte[$i],1)
   IniWrite($inifile,"Daten",$aOrdnerinhalte[$i],$aDirWA[1])
;~    ++1
   $i = $i + 1

WEnd
;~ Read ini file and create array out of it to use in gui
Global $Belegungsliste = IniReadSection($inifile,"Daten")

EndFunc

 

Now I have the following Problem..

 

First i want to explain what i want to achieve..

I have a FileServer with PDF txt and doc files. The Files are Stored in an Folderstructure (Year/Month/each day or XX-XXdays)

Now i want to display the Days and the count of Files in an Gui which works til this point!

 

this is how it looks in the gui but i want the order to look like in the filesystem

Is there a way or a "dirty" Workaround to fix the Output of the Array so it fits the numerical sorting? Strings like 25-30 cant be removed from my fileserver

 

I hope you can help me

 

best regards.

 

[Melba23]

knolle93,

A common question. Convert the numeric elements in the array to actual numbers by using Number() and then AutoIt will sort them numerically.

M23

[knolle93]

2 minutes ago, Melba23 said:

knolle93,

A common question. Convert the numeric elements in the array to actual numbers by using Number() and then AutoIt will sort them numerically.

M23

Will this work even if there are entrys like "9-13" or "22 Vacation"?

[BrewManNH]

11 minutes ago, knolle93 said:

Will this work even if there are entrys like "9-13" or "22 Vacation"?

It would take less time to try it and see what the results are rather than asking here.

[Melba23]

knolle93,

17 minutes ago, knolle93 said:

Will this work even if there are entrys like "9-13" or "22 Vacation"?

Almost certainly not as the Number function will crop anything following the digits - sorry, I did not notice you had such elements. I suggest creating an additional column in the array to store the returns from Number and sorting the array on that column before deleting it. See if you can work it out - if not come back and ask again.

M23

[mikell]

Another way - maybe

#Include <Array.au3>

$s = "1,2,3,4,5,6,7,8,9-13,14,15,16-17,18,19,20,21 Vacation,22 Vacation,25-30"
$a = StringSplit($s, ",", 2)
_ArrayShuffle($a)
_ArrayDisplay($a)

$loop = 1
While $loop 
    $loop = 0
    For $i = 1 To UBound($a)-1
        If Number($a[$i-1]) > Number($a[$i]) Then $loop = _ArraySwap($a, $i-1, $i)
    Next
WEnd
_ArrayDisplay($a)

 

[Malkey]

Here's mikell's example above functionized, with options.

#include <Array.au3>

Local $iDesc = 0, $iAlpha = 1
$s = "1,2,3,4,5,6,7,8,9-13,14,15,16-17,18,19,20,21 Vacation,22 Vacation,25-30"
$a = StringSplit($s, ",", 2)
_ArrayShuffle($a)
_ArrayDisplay($a, "Shuffled Arrtay")

_ArrayDisplay(_ArraySortANAD($a),       "Asc Num Sort")
_ArrayDisplay(_ArraySortANAD($a, 1, 0), "Des Num Sort")
_ArrayDisplay(_ArraySortANAD($a, 0, 1), "Asc Alph Sort")
_ArrayDisplay(_ArraySortANAD($a, 1, 1), "Des Alph Sort")


; Sorts an array Alpha or Numeric and sorts Ascending or Descending. (ANAD)
; Default Ascending Numeric sort.
Func _ArraySortANAD($a, $iDesc = 0, $iAlpha = 0)
    $loop = 1
    While $loop
        $loop = 0
        For $i = 1 To UBound($a) - 1
            If (Number($a[$i - 1]) > Number($a[$i]) And $iDesc = 0 And $iAlpha = 0) Or _   ; Ascending, Numeric sort
                (Number($a[$i - 1]) < Number($a[$i]) And $iDesc <> 0 And $iAlpha = 0) Or _ ; Descending, Numeric sort
                ($a[$i - 1] > $a[$i] And $iDesc = 0 And $iAlpha <> 0) Or _                 ; Ascending, Alpha sort
                ($a[$i - 1] < $a[$i] And $iDesc <> 0 And $iAlpha <> 0) _                   ; Descending, Alpha sort
                Then $loop = _ArraySwap($a, $i - 1, $i)
        Next
    WEnd
    Return $a
EndFunc   ;==>_ArraySortANAD