Jump to content
Sign in to follow this  
SkoubyeWan

Tabbing Between Input Fields to Scroll GUI

Recommended Posts

I have searched for how to do this and am coming up dry.  Probably simple and I am overlooking it.  Any help is greatly appreciated.

I have a large number of input fields in a GUI with a scroll bar.  Hitting the tab key moves between them just fine, but when you get to the last visible input box and then hit tab, the cursor is now moving between input boxes that are not visible.  I can use the scroll bar to move down to show additional input boxes and where the cursor is located.  However, I would like the tab key to just scroll the window to the input box containing the cursor automatically so it is visible.  Here is a dramatically cut back version of the code to illustrate the issue.  Thank you in advance for any assistance.

#include <Array.au3>
#include <StaticConstants.au3>
#include <GUIScrollbars_Ex.au3>

Global $iIndex = 0
Global $aArray[40]
Global $idInput[40]

Global $Form1 = GUICreate("Form1", 500, 500, -1, 100)

_GUIScrollbars_Generate($Form1, 0, 1000)

Global $Label1 = GUICtrlCreateLabel("Enter the Data for Each Field", 56, 16, 339, 33)

While $iIndex <= 30
    $idInput[$iIndex] = GUICtrlCreateInput("", 56, 56 + $iIndex * 29, 400, 28, -1)
    $iIndex += 1
WEnd

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

 

Share this post


Link to post
Share on other sites

SkoubyeWan,

That was a fun little challenge!

As you were already using my GUIScrollbars_Ex UDF I used another function from it to scroll the GUI when required (it works when both tabbing down and shift-tabbing up):

#include <Array.au3>
#include <StaticConstants.au3>
#include <GUIScrollbars_Ex.au3>

Global $iIndex = 0
Global $aArray[40]
Global $idInput[40][3]
$iAperture = 500
$iDepth = 29

Global $Form1 = GUICreate("Form1", 500, $iAperture, -1, 100)

_GUIScrollbars_Generate($Form1, 0, 1000)

Global $Label1 = GUICtrlCreateLabel("Enter the Data for Each Field", 56, 16, 339, 33)

While $iIndex <= 30
    $idInput[$iIndex][0] = GUICtrlCreateInput("", 56, 56 + $iIndex * $iDepth, 400, 28, -1)
    ; Store handle of the input
    $idInput[$iIndex][1] = GUICtrlGetHandle($idInput[$iIndex][0])
    ; Calculate and store the page on which the input appears
    $idInput[$iIndex][2] = 1 + Int(((56 + $iDepth) + ($iIndex * $iDepth)) / $iAperture)
    $iIndex += 1
WEnd

GUISetState(@SW_SHOW)

; Variable to hold current input handle
$hPrev = 0

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; Find handle with focus
    $hWnd = _WinAPI_GetFocus()
    ; If changed then
    If $hWnd <> $hPrev Then
        ; Check it is an input
        For $i = 0 To UBound($idInput) - 1
            If $idInput[$i][1] = $hWnd Then
                ; Scroll to the relevant page
                _GUIScrollbars_Scroll_Page($Form1, 0, $idInput[$i][2])
                ; No point in looking further
                ExitLoop
            EndIf
        Next
        ; Save current input handle
        $hPrev = $hWnd
    EndIf

WEnd

The trick was getting the maths correct to calculate the required page - you might need to fettle that a bit in your full version.

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  

  • Recently Browsing   0 members

    No registered users viewing this page.

×
×
  • Create New...