How do I force numeric comparison (Solved)

[rawkhopper]

While Number($LowVac) > Number(ControlGetText("Window", "", 2865)) And Number($HiVac) < Number(ControlGetText("Window", "", 2865))
      Sleep (1000)
      $BadPressTime = $BadPressTime +1
      GUICtrlSetData (4, $BadPressTime)
      GUICtrlSetData (6, "Please wait.")
      GetPress()
   WEnd

I finally figured out what is going on with my script and my programming skills but I am not sure how to overcome this.  Could someone please help?

I have a value in a GUI that I need to monitor.  If that value is within +- 10% of a target then I would like to start counting.  Once that value has been met for 5 seconds then I want to continue.  The value I am reading is a vacuum level.  If I write my script with exact numbers I don't have a problem because I can force a numeric comparison with == or <>.  But whenever I use > or < then autoit assumes my value is text and it fails.  So how can I force the comparison in a > or < situation?

I tried using Number as in the example but it failed.  Please help!

 

 

Edited August 27, 2019 by rawkhopper

[FrancescoDiMuro]

41 minutes ago, rawkhopper said:

If I write my script with exact numbers I don't have a problem because I can force a numeric comparison with ==

It doesn't make sense, since the == operator is used only to make a case-sensitive comparsion between strings.

By the way, we can't run your script, so, post a practical example

[rawkhopper]

According to https://www.autoitscript.com/autoit3/docs/intro/lang_operators.htm < or > can be compared lexicographically.  But I want it to be numerically.  How can you force it?  

 

The script I wrote will will not work independently of the window I am working with.  It would take a lot of effort to try to remove the dependencies on the program I am trying to read.

 

Can someone tell me how to force autoit to not compare a greater than or less than statement lexigraphically?

[FrancescoDiMuro]

17 minutes ago, rawkhopper said:

How can you force it?

You already do it with Number() function.

[jchd]

Your logic is flawed.  If I understand your context correctly, the value you're reading comes from the control id 2865 and you want to count 5 s starting from when the read value is within $LowVac and $HiVac.  Is that a correct description?

Your code tests $value < $low AND $value > $high which isn't possible, provided $low <= $high.

[Network_Guy]

you  need some debugging methods  (like consolewrite ) to track your code for exp :-
 

While 1
    $GUi_Value=ControlGetText("Window", "", 2865)

    $LowVac=number($LowVac)
    $HiVac=number($HiVac)
    $GUi_Value=number($GUi_Value)

    ConsoleWrite("variable LowVac = "&$LowVac&@CRLF)       ;For debug
    ConsoleWrite("variable HiVac = "&$HiVac&@CRLF)         ;for debug
    ConsoleWrite("variable GUi_Value = "&$GUi_Value&@CRLF) ;for debug

    if not ($LowVac > $GUi_Value and $HiVac < $GUi_Value) Then ExitLoop

      Sleep (1000)
      $BadPressTime = $BadPressTime +1
      GUICtrlSetData (4, $BadPressTime)
      GUICtrlSetData (6, "Please wait.")
      GetPress()
   WEnd

 

[jchd]

I believe the code you need is along this line:

Local $AllowedTime = 5 * 60 * 1000      ; 5 minute window to permit stable measure
Local $dt = 250                         ; 250 ms between acquisitions
Local $tMeasure                         ; stability duration timer
Local $tTotal = TimerInit()             ; allowable window timer

While 1
    If TimerDiff($tTotal) > $AllowedTime Then
        MsgBox(0, "Fatal", "Required vacuum level never reached")
        Exit                            ; terminate more or less gracefully (or take corrective action)
    EndIf
    While Not VacInRange() AND TimerDiff($tTotal) < $AllowedTime
        Sleep($dt)
    WEnd
    $tMeasure = TimerInit()
    Do
        Sleep($dt)
        If Not VacInRange() Then ExitLoop
    Until TimerDiff($tMeasure) >= 5000  ; pressure must remain within acceptable range for 5 s
    If TimerDiff($tMeasure) >= 5000 Then ExitLoop
WEnd

; more processing
; ...

Func VacInRange()
    Local $Vac = Number(ControlGetText("Window", "", 2865))
    Return $Vac >= $LowVac And $Vac =< $HiVac
EndFunc

 

Edited August 27, 2019 by jchd
Fix typos & thinkos & use better exit cond.

[rawkhopper]

OK I feel like an idiot now.  I worked hard all day focusing on the logic.  I was sure I had it all right. So then I started to look for other reasons it wasn't working and discovered Number() and so I thought for sure that would fix it... it did but between me fixing the logic and finding Number() I screwed up my logic and didn't realize I had fixed it because I got the same result but this time due to the logic.

Stupid copy and paste error.

Thanks for the help guys!  It didn't dawn on me that I had copied and pasted the logic from another portion of the script and thereby screwing up the logic.

 

Edited August 27, 2019 by rawkhopper