Help with 2D array

[HeyTom]

Hello,

I have a 2D array with made in this way

number-name-surname-address-etc

I need to check for:

• Duplicate, but only for the name-surname field
• Unique value.

Assuming this is the name surname field:

AA (avoid)

AA (take this, last duplicate)

BB (take this)

CC (take this)

DD (avoid)

DD (avoid)

DD (take this)

EE (take this)

ecc

I need to get always the last in case of duplicate and the unique value, mading another array. I'll hope i was clear enought. Some help with this? I have try to check but is complicated for me. Thanks

[Melba23]

HeyTom,

Welcome to the AutoIt forums.

Something like this should do the trick:

#include <Array.au3>

Global $aArray[][] = [["AA", "-"], _
                      ["AA", "+"], _
                      ["BB", "+"], _
                      ["CC", "+"], _
                      ["DD", "-"], _
                      ["DD", "-"], _
                      ["DD", "+"], _
                      ["EE", "+"]]

For $i = UBound($aArray) - 1 To 1 Step -1
    ; Read line
    $sCurrent = $aArray[$i][0]
    ; Look for earlier duplicates
    For $j = $i - 1 To 0 Step -1
        If $aArray[$j][0] == $sCurrent Then
            ; Clear the line - many options to do this for the real array
            $aArray[$j][0] = ""
        Else
            ; Stop looking
            ExitLoop
        EndIf
    Next
    $i = $j + 1

    ;Just for testing
    ;_ArrayDisplay($aArray, $i & " - " & $j, Default, 8)

Next

; Now you have the values you need and can rewrite the array as necessary
_ArrayDisplay($aArray, "Ended", Default, 8)

Please ask if you have any questions.

M23

[HeyTom]

Thanks Melba, just a little note maybe i was't clear:

[["A", "A", "-"]

Two separate field for name and surname. Is the same code or i'll change something? Thanks again

[Melba23]

HeyTom,

A couple of changes needed:

#include <Array.au3>

Global $aArray[][] = [["Tom", "AA", "-"], _
                      ["Tom", "AA", "+"], _
                      ["Tom", "BB", "+"], _
                      ["Tom", "CC", "+"], _
                      ["Tom", "DD", "-"], _
                      ["Tom", "DD", "-"], _
                      ["Tom", "DD", "+"], _
                      ["Tom", "EE", "+"]]

For $i = UBound($aArray) - 1 To 1 Step -1
    ; Read line
    $sCurrent = $aArray[$i][1]
    ; Look for earlier duplicates
    For $j = $i - 1 To 0 Step -1
        If $aArray[$j][1] == $sCurrent Then
            $aArray[$j][1] = ""
        Else
            ExitLoop
        EndIf
    Next
    $i = $j + 1

    ;_ArrayDisplay($aArray, $i & " - " & $j, Default, 8)

Next

_ArrayDisplay($aArray, "Ended", Default, 8)

Over to you to spot the differences!

M23

[HeyTom]

I'll study it, thanks again