GUICtrlSetOnEvent on button press instead of release [SOLVED]

[autoitter]

Hi,

I'm writing a piece of software that controls a PTZ camera. One of the things I'm trying to achieve is that the camera moves while the users keeps a button pressed in the GUI. Movement should stop as soon as the user releases the button. I can check if the mouse key is pressed with the _IsPressed() function. But the GuiCtrlSetOnEvent function only gets called when the button is released. Is there any way to get an event as soon as the button is pressed down?

Best regards

[MrCreatoR]

8 minutes ago, autoitter said:

Is there any way to get an event as soon as the button is pressed down?

Yes:

#include <GUIConstantsEx.au3>
#include <WinAPISysWin.au3>
#include <WinAPIMisc.au3>

$hGUI = GUICreate('Test Script', 300, 200)
$iButton = GUICtrlCreateButton('Button', 20, 40, 60, 20)
GUISetState(@SW_SHOW, $hGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYDOWN
            $tPont = _WinAPI_GetMousePos()
            
            Switch _WinAPI_WindowFromPoint($tPont)
                Case GUICtrlGetHandle($iButton)
                    _Bttn_Event()
            EndSwitch
    EndSwitch
WEnd

Func _Bttn_Event()
    ConsoleWrite('Primary down' & @CRLF)
EndFunc

 

[MrCreatoR]

Or change the button:

 

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPISysWin.au3>
#include <WinAPIMisc.au3>

Opt('GUIOnEventMode', 1)

$hGUI = GUICreate('Test Script', 300, 200)

$iButton = _Button('Button', 20, 40, 70, 22)
GUICtrlSetOnEvent($iButton, '_Events')

GUISetOnEvent($GUI_EVENT_CLOSE, '_Events', $hGUI)
GUISetOnEvent($GUI_EVENT_PRIMARYUP, '_Events', $hGUI)
GUISetState(@SW_SHOW, $hGUI)

While 1
    Sleep(10)
WEnd

Func _Button($sText, $iL, $iT, $iW, $iH)
    Local $iID = GUICtrlCreateLabel($sText, $iL, $iT, $iW, $iH, BitOR($SS_CENTER, $SS_CENTERIMAGE), $WS_EX_DLGMODALFRAME)
    Return $iID
EndFunc

Func _Events()
    Switch @GUI_CtrlId
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYUP
            GUICtrlSetStyle($iButton, -1, $WS_EX_DLGMODALFRAME)
            ConsoleWrite('Primary up' & @CRLF)
        Case $iButton
            GUICtrlSetStyle($iButton, -1, $WS_EX_CLIENTEDGE)
            ConsoleWrite('Primary down' & @CRLF)
    EndSwitch
EndFunc

 

Edited April 24, 2020 by MrCreatoR

[autoitter]

Hi MrCreatoR,

I used your first suggestion. I use OnEvent mode in my script, but it was easy to convert.
Thanks for pointing me in the right direction!

Best regards