How to add a control to a TabItem after its has been created and directly make it visible

[AlexIsProgramming]

Hey to all,

I would like to add a control to a TabItem later in the game and make it directly visible. But so far I'm obviously missing something...

In my example down below you will create no Button in tab 0 and a Button within tab 1 and tab 2 each time you press the "Create New" Button. Afterwards you stay on the previously selected tab. My script is indeed creating a button in tab 1 and 2 and will stay on the selected tab but will show everytime the last added button on the current selected tab. Only after switching between the TabItems everything will be shown correctly. What am I missing? Can somebody please help me with this one?

 

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTab.au3>

Global $aTab[3]
Global $_counter = 50

$hGUI = GUICreate("Add Ctrl to existing Tab", 300, 200)

$Tab = GUICtrlCreateTab(20, 10, 260, 150)

$aTab[0] = GUICtrlCreateTabItem("Tab 0")
$aTab[1] = GUICtrlCreateTabItem("Tab 1")
$aTab[2] = GUICtrlCreateTabItem("Tab 2")
GUICtrlCreateTabItem("")

$addButtonToTab1 = GUICtrlCreateButton("Create New", 20, 170, 80, 20)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
         Case $addButtonToTab1
            Local $_CurFocus = _GUICtrlTab_GetCurFocus ( $Tab )
            ConsoleWrite(_GUICtrlTab_GetCurFocus ( $Tab ))
            GUISwitch($hGUI, $aTab[1])
            GUICtrlCreateButton("Test1", $_counter, 50)
            GUICtrlCreateTabItem("")

            GUISwitch($hGUI, $aTab[2])
            GUICtrlCreateButton("Test2", $_counter, 50)
            $_counter += 50
            GUICtrlCreateTabItem("")

            _GUICtrlTab_SetCurSel($tab, $_CurFocus)
    EndSwitch
WEnd

 

[Subz]

Remove the 2 x "GUICtrlCreateTabItem("")"  within the Case $addButtonToTab1

[AlexIsProgramming]

6 hours ago, Subz said:

Remove the 2 x "GUICtrlCreateTabItem("")"  within the Case $addButtonToTab1

But than I still have to change between the taps to see the new button. I would like to add and display the new button directly.

[Melba23]

AlexisProgramming,

How about this:

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTab.au3>

Global $aTab[3]
Global $_counter = 50

$hGUI = GUICreate("Add Ctrl to existing Tab", 300, 200)

$Tab = GUICtrlCreateTab(20, 10, 260, 150)

$aTab[0] = GUICtrlCreateTabItem("Tab 0")
$aTab[1] = GUICtrlCreateTabItem("Tab 1")
$aTab[2] = GUICtrlCreateTabItem("Tab 2")
GUICtrlCreateTabItem("")

$addButtonToTab1 = GUICtrlCreateButton("Create New", 20, 170, 80, 20)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $addButtonToTab1
            $_CurFocus = GUICtrlRead($Tab)
            
            GUISwitch($hGUI, $aTab[1])
            GUICtrlCreateButton("Test1", $_counter, 50)
            GUICtrlCreateTabItem("")
            _GUICtrlTab_SetCurSel($Tab, 1)
            GUICtrlSetState($aTab[1], $GUI_SHOW)

            GUISwitch($hGUI, $aTab[2])
            GUICtrlCreateButton("Test2", $_counter, 50)
            $_counter += 50
            GUICtrlCreateTabItem("")
            _GUICtrlTab_SetCurSel($Tab, 2)
            GUICtrlSetState($aTab[2], $GUI_SHOW)

            GUISwitch($hGUI)

            GUICtrlSetState($aTab[$_CurFocus], $GUI_SHOW)

    EndSwitch
WEnd

M23

[AlexIsProgramming]

Perfect! That's exactly what I want. Thank you. I guess the main point is to GUISwitch to the main GUI after adding the Buttons.

 

Just for my understanding, couldn't I remove Part 1 and Part 2 in my code to clean it up?

 

;Part 1
GUICtrlCreateTabItem("")
_GUICtrlTab_SetCurSel($Tab, 1)
GUICtrlSetState($aTab[1], $GUI_SHOW)

;Part 2
_GUICtrlTab_SetCurSel($Tab, 2)
GUICtrlSetState($aTab[2], $GUI_SHOW)

 

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTab.au3>

Global $aTab[3]
Global $_counter = 50

$hGUI = GUICreate("Add Ctrl to existing Tab", 300, 200)

$Tab = GUICtrlCreateTab(20, 10, 260, 150)

$aTab[0] = GUICtrlCreateTabItem("Tab 0")
$aTab[1] = GUICtrlCreateTabItem("Tab 1")
$aTab[2] = GUICtrlCreateTabItem("Tab 2")
GUICtrlCreateTabItem("")

$addButtonToTab1 = GUICtrlCreateButton("Create New", 20, 170, 80, 20)

GUISetState()


While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $addButtonToTab1
            $_CurFocus = GUICtrlRead($Tab)

            GUISwitch($hGUI, $aTab[1])
            GUICtrlCreateButton("Test1", $_counter, 50)
;Part 1

            GUISwitch($hGUI, $aTab[2])
            GUICtrlCreateButton("Test2", $_counter, 50)
            $_counter += 50
            GUICtrlCreateTabItem("") ;stop adding future ctrl into tabitem 
;Part 2

            GUISwitch($hGUI)

            GUICtrlSetState($aTab[$_CurFocus], $GUI_SHOW)

    EndSwitch
WEnd

 

[Melba23]

AlexisProgramming,

I would leave in the first GUICtrlCreateTabItem("") - as far as I know it should be used on each tab once control creation is terminated:

Case $addButtonToTab1
    $_CurFocus = GUICtrlRead($Tab)

    GUISwitch($hGUI, $aTab[1])
    GUICtrlCreateButton("Test1", $_counter, 50)
    GUICtrlCreateTabItem("")

    GUISwitch($hGUI, $aTab[2])
    GUICtrlCreateButton("Test2", $_counter, 50)
    $_counter += 50
    GUICtrlCreateTabItem("")

    GUISwitch($hGUI)

    GUICtrlSetState($aTab[$_CurFocus], $GUI_SHOW)

M23