number of elements in 2d array

[Socrathes]

hello

 

Local $a = [[3,39],[2,36,37],[0,38],[1,40]]

 

is there a way to find out the number of elements of the 2d array.

with ubound i get number of rows but not number of elements in the 2 level.

thanks in advance

[jchd]

Reread help about UBound().

[Luke94]

UBound accepts an optional Dimension parameter.

Quote

Parameters

Variable

An array or map variable

Dimension

[optional] For an array - Which dimension size to return:     $UBOUND_DIMENSIONS (0) = Number of subscripts in the array     $UBOUND_ROWS (1) = Number of rows in the array (default)     $UBOUND_COLUMNS (2) = Number of columns in the array For arrays with more than 2 dimensions, just use the corresponding integer For a map - this parameter is ignored and the number of keys is returned Constants are defined in AutoItConstants.au3.

You can use $UBOUND_COLUMNS to return the number of columns.

Example:

#include <Array.au3>

Local $aArray1 = [[3,39],[2,36,37],[0,38],[1,40]]

$iRows = UBound($aArray1)
$iColumns = UBound($aArray1, $UBOUND_COLUMNS)

ConsoleWrite("Rows: " & $iRows & ", Columns: " & $iColumns & @CRLF)

 

[Socrathes]

thank you but that would only work if all rows had three columns?

but here three rows have two columns and the searched row has three columns.

this would also be only an example it could be that all columns have completely different lengths,

then I cannot work with the maximum value.

[TheXman]

52 minutes ago, Socrathes said:

that would only work if all rows had three columns?

All rows do have 3 columns.  All rows may not have values for all 3 columns, but 3 columns exist for each and every row.

52 minutes ago, Socrathes said:

this would also be only an example it could be that all columns have completely different lengths

All rows may have a different number of values, but not different dimension sizes.  Your sample array is $a[4][3] because it had to handle the maximum number of elements per dimension, which was 3 for the second dimension.  Just because you didn't specify values in your initialization string, that doesn't meat that the column doesn't exist.

 

---

 

The simple script below shows what your array looks like:

#include <Array.au3>

Global $a = [[3,39],[2,36,37],[0,38],[1,40]]
_ArrayDisplay($a)

Edited June 11, 2021 by TheXman

[Socrathes]

thanks for that of course that makes sense. now the only question would be whether there is a possibility with which one can query the exact number of entries, or must a function be written for that?

[Luke94]

20 minutes ago, Socrathes said:

thanks for that of course that makes sense. now the only question would be whether there is a possibility with which one can query the exact number of entries, or must a function be written for that?

You could use a 1D array instead - each entry containing a delimited string? Like so:

Global $aArray = [ "3,39", "2,36,37", "0,38", "1,40" ]

Global $iRows = UBound($aArray)

For $i = 0 To ($iRows - 1) Step 1
    $iColumns = UBound(StringSplit($aArray[$i], ","))
    ConsoleWrite("Row " & $i & " has " & ($iColumns - 1) & " columns" & @CRLF)
Next

Output:

Quote

Row 0 has 2 columns
Row 1 has 3 columns
Row 2 has 2 columns
Row 3 has 2 columns

 

Edited June 11, 2021 by Luke94

[Socrathes]

thx

[Musashi]

@Socrathes :

You can also stick with a 2D array, since this is what is returned by many functions. The number of elements that are not empty is reported as a 1D array.

Example :

#include <Array.au3>
Global $aArr = [[10, 11, 12], [20, 21], [30, '', 32], [], [50]]
Global $aRowEntries[UBound($aArr)]
_ArrayDisplay($aArr, "2-D Array - Example", Default, Default, Default, "Column 1|Column 2|Column 3")

_SetRowEntries($aArr)
_ArrayDisplay($aRowEntries, "RowEntries")

Func _SetRowEntries(ByRef $aArr)
    Local $iEntryCounter
    For $i = 0 To UBound($aArr) - 1
        $iEntryCounter = 0
        For $k = 0 To UBound($aArr, $UBOUND_COLUMNS) -1
            If $aArr[$i][$k] <> '' Then $iEntryCounter += 1
        Next
        $aRowEntries[$i] = $iEntryCounter
    Next
EndFunc