stringregexp issue

[Champak]

 
I have a string to search for 4 different things, with four different results

                       $sText = StringReplace($sText2, "'", "")
                        $sText = StringReplace($sText, "/", "-")
                        $sText = StringReplace($sText, " ", "_")
                        $sText = StringReplace($sText, "&", "And")

Can all three be combined into one regexp? Thanks

Edited April 6, 2022 by Champak

[ad777]

maybe this what your looking for:

$st = './ '
$out = StringRegExpReplace($st, '(?m)..','-_',1)

 

[Jos]

@ad777 mmm not even close to what is asked! A shame the OP didn't post a runnable replicator script, but that was easy in this case:

$sText = " this is a test '  /   $ "
$sText = StringReplace($sText, "'", "")
$sText = StringReplace($sText, "/", "-")
$sText = StringReplace($sText, " ", "_")
$sText = StringReplace($sText, "&", "And")
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sText = ' & $sText & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

$sText = " this is a test '  /   $ "
$sText =  StringRegExpReplace($sText, '(?m)..','-_',1)
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sText = ' & $sText & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

@Champak,

I normally make  array that contains the from & to replacement and loop through the array doing a stringreplace()

Edited April 6, 2022 by Jos

[Champak]

Thanks.

However, neither work.

$sText = "Jack's birthday is 02/02/02 & Jill's is the same"
$sText =  StringRegExpReplace($sText, '(?m)..','-_',1)
ConsoleWrite($sText)

This is what the result should be: "Jacks_birthday_is_02-02-02_And_Jills_is_the_same"

Putting stringreplace in an array is a good idea, I never thought about that. I'll give it a try, but the reason I wanted it with stringregexp is I thought 1/ it would be faster, and 2/ I'd prefer it inline with the rest of this particular passage of code I have.

Edited April 6, 2022 by Champak

[Jos]

3 minutes ago, Champak said:

However, neither work.

Isn't that what I already stated? 

[mikell]

1 hour ago, Champak said:

2/ I'd prefer it inline with the rest

So just build a func (using Jos' method or not)

$txt = "Jack's birthday is 02/02/02 & Jill's is the same"
Msgbox(0,"", _Job($txt) )

;----------------------

Func _Job($sText)
    $sText = StringReplace($sText, "'", "")
    $sText = StringReplace($sText, "/", "-")
    $sText = StringReplace($sText, " ", "_")
    $sText = StringReplace($sText, "&", "And")
    Return $sText
EndFunc

Regex is magic but unfortunately it has limits
How frustrating

 

 

[pixelsearch]

This reminds me the old Foxpro days (with the following example just found in this link) where replacing several characters at a time was doable like this :

? CHRTRAN("ABCDE", "ACE", "XYZ")    && yields "XBYDZ"

Memories, memories...

[jchd]

When you have a fix translate table and need to use it  many times, you could make it this way:

Local $mXlate[]
$mXlate["A"] = "Z"
$mXlate["B"] = "Y"
$mXlate["C"] = "X"
$mXlate["D"] = "W"
$mXlate["E"] = "V"
$mXlate["F"] = "U"
$mXlate["U"] = "F"
$mXlate["V"] = "E"
$mXlate["W"] = "D"
$mXlate["X"] = "C"
$mXlate["Y"] = "B"
$mXlate["Z"] = "A"

Local $sOut = Execute("'" & StringRegExpReplace("ABCDEF...UVWXYZ", "([A-FU-Z])", "' & $mXlate['$1'] & '") & "'")
ConsoleWrite($sOut & @LF)

 

[Deye]

For kicks, One overall working example 

$txt = "Jack's birthday is 02/02/02 & Jill's is the same"

MsgBox(0, '', _Replace($txt, "'/ &" & @TAB & "|-|_|And"))

MsgBox(0, '', _Replace($txt, "'/ &02" & @TAB & "| \ |   |And|12|34"))

MsgBox(0, '', _Replace($txt, "/&20" & @TAB & "1|may be||"))

Func _Replace($sTxt, $sSplit)
    Local $aSplit = StringSplit($sSplit, @TAB)
    Local $a1 = StringSplit($aSplit[1], "")
    Local $a2 = StringSplit($aSplit[2], "|")
    Local $sda = ObjCreate("Scripting.Dictionary")
    For $i = 1 To UBound($a1) - 1
        $sda.item($a1[$i]) = $a2[$i]
    Next
    Return Execute('"' & StringRegExpReplace($sTxt, "([" & $aSplit[1] & "])", '" & $sda.Item("$1") & "') & '"')
EndFunc

 

Edited April 10, 2022 by Deye

[Champak]

@Deye, that's very cool. Been staring at it for 20 min and can't figure it out. I went with mikell's suggestion, I don't know why I forgot I could do that. Thanks all.

[Deye]

Updated the above to make it easier to work with + examples.

[rudi]

@jchd

This code looks very interesting, but I don't really get it ( local dimming an array without giving the arrays size, filling later on with index addressing using one-letter-strings)

 

Local $mXlate[]
$mXlate["A"] = "Z"
$mXlate["B"] = "Y"
$mXlate["C"] = "X"
$mXlate["D"] = "W"
$mXlate["E"] = "V"
$mXlate["F"] = "U"
$mXlate["U"] = "F"
$mXlate["V"] = "E"
$mXlate["W"] = "D"
$mXlate["X"] = "C"
$mXlate["Y"] = "B"
$mXlate["Z"] = "A"

Local $sOut = Execute("'" & StringRegExpReplace("ABCDEF...UVWXYZ", "([A-FU-Z])", "' & $mXlate['$1'] & '") & "'")
ConsoleWrite($sOut & @LF)

 

Could you pls. drop some explaining lines for it?

TIA, Rudi.

[jchd]

This is a Map datatype, not an array. More or less an equivalent to a Scripting.Dictionary object (an indexed key-value store), but Maps are built-in beta version of AutoIt. See beta help on Variables > Maps & Arrays > Maps.

[rudi]

I see, very interesting!

Is this an equivalent to the powershell hash table variable type? Especially the aspect of access speed? In powershell even very large hash tables return the test // value results literally instantly.

 

[jchd]

Exactly IIRC. Since in these type of containers the indexing is done and balanced on the fly as new entries are inserted, the access is O(log₂ N).

[Melba23]

8 hours ago, jchd said:

Maps are built-in beta version of AutoIt

Maps are now available in the latest release - 3.3.16.0.

M23

[jchd]

Ah yes, I always hesitate between beta and release. My bad.