Ghost border on _GDIPlus_GraphicsDrawImageRectRect

[TommyDDR]

Hello,

When i use _GDIPlus_GraphicsDrawImageRectRect to scale up an image, my rendered image is shifted up / left and filled with blank bottom right.

There is an exemple :

#include <GDIPlus.au3>
#include <GDIPlusConstants.au3>

_GDIPlus_Startup()

Local $fileName = @ScriptDir & "\test_gdi_zoom.png"
Local $origFileName = @ScriptDir & "\test_gdi.png"

Local $hBmp = _GDIPlus_BitmapCreateFromFile($origFileName)
Local $w = _GDIPlus_ImageGetWidth($hBmp)
Local $h = _GDIPlus_ImageGetHeight($hBmp)
Local $zoom = 7

Local $hBmpRender = _GDIPlus_BitmapCreateFromScan0($w * $zoom, $h * $zoom)
Local $hGraphics = _GDIPlus_ImageGetGraphicsContext($hBmpRender)

_GDIPlus_GraphicsSetInterpolationMode($hGraphics, $GDIP_INTERPOLATIONMODE_NearestNeighbor)
_GDIPlus_GraphicsDrawImageRectRect($hGraphics, $hBmp, 0, 0, $w, $h, 0, 0, $w * $zoom, $h * $zoom)
;~ _GDIPlus_GraphicsDrawImageRectRect($hGraphics, $hBmp, -1, -1, $w+1, $h+1, -1 * Ceiling($zoom / 2), -1 * Ceiling($zoom / 2), ($w + 1) * $zoom, ($h + 1) * $zoom)
_GDIPlus_GraphicsDispose($hGraphics)

_GDIPlus_ImageSaveToFile($hBmpRender, $fileName)

_GDIPlus_BitmapDispose($hBmpRender)
_GDIPlus_BitmapDispose($hBmp)

_GDIPlus_Shutdown()

Put the test_gdi.png in same directory than script and run it, it will create test_gdi_zoom.png

The commented line is the workaround i use to counter it (but very annoying)

Does this is known or do i have to create a ticket ?

 

Thanks !

Edit : I know that this bug was fixed for _GDIPlus_ImageResize() -> https://www.autoitscript.com/trac/autoit/ticket/3647
But i think it also should be done in _GDIPlus_GraphicsDrawImageRectRect

[Andreik]

Add this line before drawing:

_GDIPlus_GraphicsSetPixelOffsetMode ($hGraphics, 2)

 

[TommyDDR]

Perfect ! Thank you
 

(But is it a bug anyway ?)

[Andreik]

I don't think so, it's the way GDI+ does things behind the scene.

[TommyDDR]

ok, thanks