_ConvertKeyboardLayout

[ioa747]

_ConvertKeyboardLayout

 many times i start typing without having watched the keyboard to the language i'm typing in,  and when I look to see what I've typed I see gibberish.
 Function to convert "gibberish" text (e.g., "kalhmera se oloyw") into correct text (e.g., "καλημερα σε ολους")
 and vice versa  (e.g., "Γοοδ μορνινγ εωερυονε") into correct text (e.g., "Good morning everyone")

(you will need to adapt it to your language)  😁
 
StringProper.au3

expandcollapse popup

; https://www.autoitscript.com/forum/topic/213301-_convertkeyboardlayout/
;----------------------------------------------------------------------------------------
; Title...........: _ConvertKeyboardLayout.au3
; Description.....: Convert the currently selected text from gibberish to the appropriate language
; AutoIt Version..: 3.3.18.0   Author: ioa747           Script Version: 0.1
; Note............: Testet in Windows 11 Pro 24H2       Date:4/11/2025
;----------------------------------------------------------------------------------------
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

; Hotkey to trigger the conversion
HotKeySet("+^q", "_ConvertKeyboardLayout") ; <<--(Shift+Ctrl+Q)--<<


; Main loop to keep the script running
While 1
    Sleep(300)
WEnd

;--------------------------------------------------------------------------------------------------------------------------------
; many times i start typing without having watched the keyboard to the language i'm typing in,
; and when I look to see what I've typed I see gibberish.
; Function to convert "gibberish" text (e.g., "kalhmera se oloyw") into correct text (e.g., "καλημερα σε ολους")
; and vice versa  (e.g., "Γοοδ μορνινγ εωερυονε") into correct text (e.g., "Good morning everyone")
;--------------------------------------------------------------------------------------------------------------------------------
Func _ConvertKeyboardLayout()

    Local $hWnd = WinGetHandle("[ACTIVE]") ; Get the handle of the active window
    Local Static $mEN[]
    Local Static $mGR[]

    If UBound($mEN) = 0 Then
        Local Const $sEN = "qwertyuiopasdfghjklzxcvbnmQWERTYUIOPASDFGHJKLZXCVBNM"
        Local Const $sGR = ";ςερτυθιοπασδφγηξκλζχψωβνμ:΅ΕΡΤΥΘΙΟΠΑΣΔΦΓΗΞΚΛΖΧΨΩΒΝΜ"
        For $i = 1 To StringLen($sEN)
            $mEN[StringMid($sGR, $i, 1)] = StringMid($sEN, $i, 1)
            $mGR[StringMid($sEN, $i, 1)] = StringMid($sGR, $i, 1)
        Next
    EndIf

    ; Local $hTimer = TimerInit()
    Local Const $CHANGE_THE_KEYBOARD = 1  ; constant if you want to send key for change the keyboard too
    Local Const $iTimeout = 1000          ; Max wait time for clipboard (1 second)
    Local $sOriginalClipboard = ClipGet() ; Backup original clipboard content
    Local $sInputText = ""

    ClipPut("") ; Clear clipboard to detect new content
    Send("{CTRLDOWN}")
    Send("c")   ; Copy selected text to clipboard
    Send("{CTRLUP}")

    ; Wait for clipboard content to be updated
    Local $iStartTime = TimerInit()
    While TimerDiff($iStartTime) < $iTimeout
        $sInputText = ClipGet()
        If $sInputText <> "" Then ; Check if new content arrived
            ExitLoop
        EndIf
        Sleep(50)
    WEnd

    If $sInputText = "" Then
        ConsoleWrite("! No text copied to clipboard or clipboard timed out." & @CRLF)
        ClipPut($sOriginalClipboard) ; Restore clipboard
        Return SetError(1, 0, 0)
    EndIf

    ; Determine conversion direction (English to Greek or Greek to English)
    ; check if the input text contains English or Greek characters
    Local $sChar, $bEnglishTxt = False
    $sChar = StringLeft($sInputText, 1)
    If Not MapExists($mEN, $sChar) Then $bEnglishTxt = True

    Local $sOutputText = ""

    If $bEnglishTxt Then
        ; converted to Greek
        For $i = 1 To StringLen($sInputText)
            $sChar = StringMid($sInputText, $i, 1)
            If MapExists($mGR, $sChar) Then
                $sOutputText &= $mGR[$sChar]
            Else
                $sOutputText &= $sChar
            EndIf
        Next
    Else
        ; converted to English
        For $i = 1 To StringLen($sInputText)
            $sChar = StringMid($sInputText, $i, 1)
            If MapExists($mEN, $sChar) Then
                $sOutputText &= $mEN[$sChar]
            Else
                $sOutputText &= $sChar
            EndIf
        Next
    EndIf

    ClipPut($sOutputText) ; Put the converted text back to clipboard
    WinActivate($hWnd)    ; Re-activate the window where text was copied from
    Sleep(50)             ; Give a small delay

    ; Paste the converted text
    Send("{CTRLDOWN}")
    Send("v")
    Send("{CTRLUP}")

    If $CHANGE_THE_KEYBOARD Then Send("# ") ; Win + space, if you want to change the keyboard
    ClipPut($sOriginalClipboard)            ; Restore the original clipboard content
    ; ConsoleWrite("Original Clipboard Restored. Processed in: " & Round(TimerDiff($hTimer) / 1000, 3) & " seconds" & @CRLF)
EndFunc   ;==>_ConvertKeyboardLayout

 

Please, every comment is appreciated!
leave your comments and experiences here!
Thank you very much 

 

Edited 2 hours ago by ioa747
more appropriate name

[jchd]

The name you choose is a misnomer. "proper case" refers to capitalizing the first letter of each word in a sentence, like this: "Proper Case" Refers To Capitalizing The First Letter Of Each Word In A Sentence