How input control shows/hides dynamically passwords

[jlorenz1]

Hallo.

I've got following problem:

I want an input control, which changes dynamically the password plain or in ****

depending on the state of checkbox. How does it works? Thanks in advance

Ich habe folgendes Problem:

Ich möchte ein Inputsteuerelement, das dynmaisch entweder das Passwort blank oder in ***

je nach dem Status der Checkbox. Wie geht es nur? Vielen Dank im voraus!

Johannes from Germany

#include <GUIConstants.au3>

GUICreate("Hide/unhide password", 320,120, @DesktopWidth/2-160, @DesktopHeight/2-45, -1, 0x00000018); WS_EX_ACCEPTFILES

GUICtrlCreatelabel ( "Give me your password", 10, 5, 300, 20)

$checkbox = GUICtrlCreateCheckbox ( "Hide password", 10, 25, 300, 20)

GUICtrlSetState ( -1, $GUI_CHECKED)

$input = GUICtrlCreateInput ("Password", 10, 55, 300, 20)

$btn = GUICtrlCreateButton ("Ok", 250, 85, 60, 20)

GUISetState ()

$msg = 0

While $msg <> $GUI_EVENT_CLOSE

$msg = GUIGetMsg()

Select

Case $msg = $checkbox

$i = GUICtrlRead($checkbox)

Select

Case $i = 1

MsgBox(4096,"Does it works?","Password with *****",2)

GUICtrlSetState ($input, $ES_PASSWORD)

Case $i = 4

MsgBox(4096,"Does it works?","Password plain",2)

GUICtrlSetState ($input, 0)

EndSelect

Case $msg = $btn

exitloop

Case else

EndSelect

Wend

[Valuater]

the answer would be GUICtrlSetStyle() instead of GUICtrlSetState ()...

#include <GUIConstants.au3>

GUICreate("Hide/unhide password", 320, 120, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1, 0x00000018); WS_EX_ACCEPTFILES
GUICtrlCreateLabel("Give me your password", 10, 5, 300, 20)
$checkbox = GUICtrlCreateCheckbox("Hide password", 10, 25, 300, 20)
GUICtrlSetState(-1, $GUI_CHECKED)

$input = GUICtrlCreateInput("", 10, 55, 300, 20)
GUICtrlSetStyle($input, $ES_PASSWORD)
GUICtrlSetData( $input, "password")
$btn = GUICtrlCreateButton("Ok", 250, 85, 60, 20)

GUISetState()

$msg = 0
While $msg <> $GUI_EVENT_CLOSE
    $msg = GUIGetMsg()
WEnd

however according to help, some styles are not availables with GUICtrlSetStyle()

Remarks

Some styles cannot be changed dynamically, check MSDN documentation. $CBS_UPPERCASE combo style is one example

8)

[jlorenz1]

I tried it without sucess. If the checkbox is activated, the content of the input control should be expressed in *********. If the checkbox isn't activated, the content of the input control should be show blank.

Sorry, but with your script the content of the input control is always shown as blank/plain .... Johannes Perhaps you have another idea or works it only with the newest beta version?

[Valuater]

as stated above

the answer would be GUICtrlSetStyle() instead of GUICtrlSetState ()...

however according to help, some styles are not availables with GUICtrlSetStyle()

8)

Edited November 23, 2006 by Valuater

[Jos]

try this:

Const $EM_SETPASSWORDCHAR = 0xCC



        Case $msg = $checkbox
            $i = GUICtrlRead($checkbox)
            Select
                Case $i = 1
                    $Res = GUICtrlSendMsg($input, $EM_SETPASSWORDCHAR, 149, 0)
                Case $i = 4
                    $Res = GUICtrlSendMsg($input, $EM_SETPASSWORDCHAR, 0, 0)
            EndSelect

Edited November 23, 2006 by JdeB

[Valuater]

that works.

8)

[jlorenz1]

i tried this without success.

[Valuater]

post your new code

8)

[Jos]

i tried this without success.

You need to click on the Password field to refresh it ....

[jlorenz1]

This works, but isn't a 100% solution. Johannes

#include <GUIConstants.au3>

Const $EM_SETPASSWORDCHAR = 0xCC

GUICreate("Show/hide password", 320,120, @DesktopWidth/2-160, @DesktopHeight/2-45, -1, 0x00000018)

GUICtrlCreatelabel ( "Give me your password", 10, 5, 300, 20)

$checkbox = GUICtrlCreateCheckbox ( "Hide password", 10, 25, 300, 20)

GUICtrlSetState ( -1, $GUI_CHECKED)

$inputWithAsterisk = GUICtrlCreateInput ("Password", 10, 55, 300, 20, $ES_PASSWORD)

$inputPasswordPlain = GUICtrlCreateInput ("Password", 10, 55, 300, 20)

GUICtrlSetState(-1, $GUI_HIDE)

$btn = GUICtrlCreateButton ("Ok", 250, 85, 60, 20)

GUISetState ()

$msg = 0

While $msg <> $GUI_EVENT_CLOSE

$msg = GUIGetMsg()

Select

Case $msg = $checkbox

$i = GUICtrlRead($checkbox)

Select

Case $i = 4

MsgBox(4096,'Action','Show password plain')

$sInputWAContent = GUICtrlRead($inputWithAsterisk)

GUICtrlSetData($inputPasswordPlain,$sInputWAContent)

GUICtrlSetState($inputWithAsterisk, $GUI_HIDE)

GUICtrlSetState($inputPasswordPlain, $GUI_SHOW)

Case $i = 1

MsgBox(4096,'Action','Hide password')

$sInputPPContent = GUICtrlRead($inputPasswordPlain)

GUICtrlSetData($inputWithAsterisk,$sInputPPContent)

GUICtrlSetState($inputPasswordPlain, $GUI_HIDE)

GUICtrlSetState($inputWithAsterisk, $GUI_SHOW)

EndSelect

Case $msg = $btn

exitloop

Case else

EndSelect

Wend