PutDir on FTP

[Scriptor]

I have the UDF "FTP.au3". Now I search a functions for "PutDir on FTP". I have a dir and now I will put this dir on my FTP-Server.

[FuryCell]

What about this function? It is included in FTP.au3

;===============================================================================
;
; Function Name:    _FTPMakeDir()
; Description:      Makes an Directory on an FTP server.
; Parameter(s):     $l_FTPSession   - The Long from _FTPConnect()
;                   $s_Remote       - The file name to be deleted.
; Requirement(s):   DllCall, wininet.dll
; Return Value(s):  On Success - 1
;                   On Failure - 0
; Author(s):        Wouter van Kesteren
;
;===============================================================================

Func _FTPMakeDir($l_FTPSession, $s_Remote)
    
    Local $ai_FTPMakeDir = DllCall('wininet.dll', 'int', 'FtpCreateDirectory', 'long', $l_FTPSession, 'str', $s_Remote)
    If @error OR $ai_FTPMakeDir[0] = 0 Then
        SetError(-1)
        Return 0
    EndIf
    
    Return $ai_FTPMakeDir[0]
    
EndFunc ;==> _FTPMakeDir()

Edited December 18, 2006 by SolidSnake

[Scriptor]

Yes. But i need a function like _FTPPutDir. In the File "FTP.au3" is a function name of the function is _FTPPutFile

[FuryCell]

Yes. But i need a function like _FTPPutDir. In the File "FTP.au3" is a function name of the function is _FTPPutFile

If your trying to upload a dir why not use a workaround like the following.

Create the dir and then upload each file contained in the dir in a loop.

[martin]

If your trying to upload a dir why not use a workaround like the following.

Create the dir and then upload each file contained in the dir in a loop.

This has been done by Stumpi

expandcollapse popup

;===================================================================================================

;
; Function Name:    _FTPPutFolderContents()
; Description:      Puts an folder on an FTP server. Recursivley if selected
; Parameter(s):     $l_InternetSession    - The Long from _FTPConnect()
;                   $s_LocalFolder     - The local folder i.e. "c:\temp".
;                   $s_RemoteFolder - The remote folder i.e. '/website/home'.
;                   $b_RecursivePut - Recurse through sub-dirs. 0=Non recursive, 1=Recursive
; Requirement(s):   DllCall, wininet.dll
; Author(s):        Stumpii
;
;===================================================================================================

Func _FTPPutFolderContents($l_InternetSession, $s_LocalFolder, $s_RemoteFolder, $b_RecursivePut)

    ; Shows the filenames of all files in the current directory.
    $search = FileFindFirstFile($s_LocalFolder & "\*.*")

    ; Check if the search was successful
    If $search = -1 Then
        MsgBox(0, "Error", "No files/directories matched the search pattern")
        Exit
    EndIf

    While 1
        $file = FileFindNextFile($search)
        If @error Then ExitLoop
        If StringInStr(FileGetAttrib($s_LocalFolder & "\" & $file), "D") Then
            _FTPMakeDir($l_InternetSession, $s_RemoteFolder & "/" & $file)
            If $b_RecursivePut Then
                _FTPPutFolderContents($l_InternetSession, $s_LocalFolder & "\" & $file, $s_RemoteFolder & "/" & $file, $b_RecursivePut)
            EndIf
        Else
            _FTPPutFile($l_InternetSession, $s_LocalFolder & "\" & $file, $s_RemoteFolder & "/" & $file, 0, 0)
        EndIf
    WEnd

    ; Close the search handle
    FileClose($search)

EndFunc ;==>_FTPPutFolderContents

[Scriptor]

Thanks

[martin]

Thanks

OK

If you get to try using InternetGetLastResponseInfo and succeed please tell me how you do it. I've tried for a long time and no progress.

[erikson]

there is a function _FTPGetFolder?