Need help with child windows

w00dr0w · January 11, 2007

I'm making an automated installer thats conditional based (lots of if/then loops because of the program I'm automating doesn't use the same options after certain answers)

I have the main GUI window down pat, but id like to move some options on it to a child window that opens when the user checks a checkbox.

I'm extremely new to this whole scripting business (only "programing" i ever did was in BASIC 15+yrs ago) and would really like some help.

Here is my code, ignore the n00bish formating.

Basically what i want to happen is move the proxy information (in my code $Input8 - $Input12) into a child window that opens once $Input7 is checked, and closes with a close button.

I still have a lot of work to finish with this (clean up the GUI a lot) move some inputs/checkboxes and hopefully add a file browser for $Input1 so people don't need to search for it themselves, but any help would be appreciated before I release this to my friends.

CODE

#include <GUIConstants.au3>

Global $GUIWidth

Global $GUIHeight

$GUIWidth = 500

$GUIHeight = 800

$TextWidth = $GUIWidth - 20

$buttonheight = $GUIHeight - 40

$BtnW = $GUIWidth / 2 - 20

GUICreate("JD's convoluted F@H Installer", $GUIWidth, $GUIHeight)

GUICtrlCreateLabel("Directory of the client w/ client name (example C:\fah\FAH504-Console.exe)", 10, 10, $TextWidth)

$Input1 = GUICtrlCreateInput("", 10, 30, $TextWidth, 20)

GUICtrlCreateLabel("Username", 10, 55, $TextWidth)

$Input2 = GUICtrlCreateInput("", 10, 70, $TextWidth, 20)

GUICtrlCreateLabel("Team Number, Leave default for ClubOC", 10, 95, $TextWidth)

$Input3 = GUICtrlCreateInput("36597", 10, 110, $TextWidth, 20)

GUICtrlCreateLabel("Launch as a service", 10, 135, $TextWidth)

$Input4 = GUICtrlCreateCheckbox ( "Yes", $BtnW, 150)

GUICtrlCreateLabel("Ask before fetching/sending work (only click yes if you're on dialup)", 10, 175, $TextWidth)

$Input5 = GUICtrlCreateCheckbox ( "Yes", $BtnW, 190)

GUICtrlCreateLabel("Use IE settings (Ignore proxy if yes)", 10, 215, $TextWidth)

$Input6 = GUICtrlCreateCheckbox ( "Yes", $BtnW, 230)

GUICtrlCreateLabel("Use proxy", 10, 255, $TextWidth)

$Input7 = GUICtrlCreateCheckbox ( "Yes", $BtnW, 280)

GUICtrlCreateLabel("Proxy Name", 10, 300, $TextWidth)

$Input8 = GUICtrlCreateInput("", 10, 320, $TextWidth, 20)

GUICtrlCreateLabel("Port Number (change if not default)", 10, 345, $TextWidth)

$Input9 = GUICtrlCreateInput("8080", 10, 360, $TextWidth, 20)

GUICtrlCreateLabel("Use username and password for proxy? (ignore username and password if no)", 10, 385, $TextWidth)

$Input10 = GUICtrlCreateCheckbox("Yes", $BtnW, 400)

GUICtrlCreateLabel("Username", 10, 425, $TextWidth)

$Input11 = GUICtrlCreateInput ( "", 10, 440, $TextWidth, 20)

GUICtrlCreateLabel("Password", 10, 465, $TextWidth)

$Input12 = GUICtrlCreateInput ( "", 10, 480, $TextWidth, 20)

GUICtrlCreateLabel("Allow receipt of files greater then 5mb (only check if you have 1GB or more memory)", 10, 505, $TextWidth)

$Input13 = GUICtrlCreateCheckbox ( "Yes", $BtnW, 520)

GUICtrlCreateLabel("Change Advanced options", 10, 545, $TextWidth)

$Input14 = GUICtrlCreateCheckbox ( "Yes", $BtnW, 560)

GUICtrlCreateLabel("Core Priority", 10, 585, $TextWidth)

$Input15 = GuiCtrlCreateCombo("", 30, 600, 130, 21)

GuiCtrlSetData($Input15, "Idle|Low")

GuiCtrlCreateLabel("CPU usage requested (far right = 100)", 10, 625)

$Input16 = GuiCtrlCreateSlider(10, 640, $TextWidth, 30)

GuiCtrlSetData(1, 100)

GuiCtrlCreateLabel("Disable highly optimised assembly code (NOT reccomended)", 10, 685)

$Input17 = GUICtrlCreateCheckbox ( "Yes", $BtnW, 700)

GuiCtrlCreateLabel("Disable core when on battery power (usefull for laptops)", 10, 725)

$Input18 = GUICtrlCreateCheckbox ( "Yes", $BtnW, 740)

$OK_Btn = GUICtrlCreateButton("OK", 105, $buttonheight, 70, 25)

$Cancel_Btn = GUICtrlCreateButton("Cancel", 215, $buttonheight, 70, 25)

GUISetState(@SW_SHOW)

While 1

$msg = GUIGetMsg()

Select

Case $msg = $GUI_EVENT_CLOSE

GUIDelete()

Exit

Case $msg = $OK_Btn

Dim $iMsgBoxAnswer

$iMsgBoxAnswer = MsgBox(49,"JD's convoluted F@H Installer","Click ok to run F@H and configure it. DO NOT TOUCH ANYTHING DURRING THIS PROCESS!")

Select

Case $iMsgBoxAnswer = 1 ;OK

Case $iMsgBoxAnswer = 2 ;Cancel

EndSelect

If $iMsgBoxAnswer = 1 Then

;$Dir = GUICtrlRead($Input1)

$Dir = "C:\fah\FAH504-Console4.exe"

$Username = GUICtrlRead($Input2)

$Teamnum = GUICtrlRead($Input3)

$Service = GUICtrlRead($Input4)

$Ask = GUICtrlRead($Input5)

$Ie = GUICtrlRead($Input6)

$Prox = GUICtrlRead($Input7)

$ProxName = GUICtrlRead($Input8)

$Port = GUICtrlRead($Input9)

$UsrPw = GUICtrlRead($Input10)

$ProxUsr = GUICtrlRead($Input11)

$ProxPw = GUICtrlRead($Input12)

$Big = GUICtrlRead($Input13)

$Advanced = GUICtrlRead($Input14)

$Core = GUICtrlRead($Input15)

$Cpu = GUICtrlRead($Input16)

$Ass = GUICtrlRead($Input17)

$Batt = GUICtrlRead($Input18)

;$Chk = GUICtrlRead($Input19)

;$Mem = GUICtrlRead($Input20)

;$Wrk = GUICtrlRead($Input21)

;$Avm = GUICtrlRead($Input22)

;$Ignore = GUICtrlRead($Input23)

;$Mach = GUICtrlRead($Input24)

Run("notepad.exe")

WinWaitActive("Untitled - Notepad")

;Run($Dir)

;WinWaitActive($Dir)

Send($Username)

Send("{enter}")

Send($Teamnum)

Send("{enter}")

If $Service = 1 Then

Send("y")

Else

Send("n")

EndIf

Send("{enter}")

If $Ask = 1 Then

Send("y")

Else

Send("n")

EndIf

Send("{enter}")

If $Ie = 1 Then

Send("y")

Else

Send("n")

Send("{enter}")

If $Prox = 1 Then

Send("y")

Send("{enter}")

Send($ProxName)

Send("{enter}")

Send($Port)

Send("{enter}")

If $UsrPw = 1 Then

Send("y")

Send("{enter}")

Send($Proxusr)

Send("{enter}")

Send($ProxPw)

Else

Send("n")

EndIf

Else

Send("n")

EndIf

Send("{enter}")

If $Big = 1 Then

Send("y")

Else

Send("n")

EndIf

Send("{enter}")

If $Advanced = 1 Then

Send("y")

Send("{enter}")

If $Core = "Idle" Then

Send("i")

Else

Send("l")

EndIf

Else

Send("n")

EndIf

Send("{enter}")

Send($Cpu)

Send("{enter}")

If $Ass = 1 Then

Send("y")

Else

Send("n")

EndIf

Send("{enter}")

If $Batt = 1 Then

Send("y")

Else

Send("n")

EndIf

Send("{enter}")

Else

MsgBox(64, "JD's convoluted F@H Installer", "you Cancelled Installitaion")

EndIf

Case $msg = $Cancel_Btn

GUIDelete()

Exit

EndSelect

WEnd

Danny35d · January 11, 2007

Basically what i want to happen is move the proxy information (in my code $Input8 - $Input12) into a child window that opens once $Input7 is checked

Welcome to AutoIt this is not a child windows as you want, but it is a different approach.

#include <GUIConstants.au3>

#Region ### START Koda GUI section 
$Form1_1 = GUICreate("JD's Convoluted F@H Installer", 501, 466, 193, 115)
$Label1 = GUICtrlCreateLabel("Directory of the client w/ client name (example C:\fah\FAH504-Console.exe)", 8, 8, 360, 17)
$Input1 = GUICtrlCreateInput("", 8, 24, 449, 21)
$SelectPath_Btn = GUICtrlCreateButton("...", 464, 22, 27, 25, 0)
$Label2 = GUICtrlCreateLabel("Username", 8, 48, 52, 17)
$Input2 = GUICtrlCreateInput("", 8, 64, 449, 21)
$Label3 = GUICtrlCreateLabel("Team Number, Leave default for ClubOC", 8, 88, 196, 17)
$Input3 = GUICtrlCreateInput("36597", 8, 104, 449, 21)
$UseIE = GUICtrlCreateRadio("Use IE settings", 8, 128, 97, 17)
GUICtrlSetState(-1, $GUI_CHECKED)
$UseProxy = GUICtrlCreateRadio("Use proxy settings", 8, 152, 113, 17)
$Label5 = GUICtrlCreateLabel("Proxy Name", 128, 128, 61, 17)
GUICtrlSetState(-1, $GUI_DISABLE)
$Input4 = GUICtrlCreateInput("", 128, 144, 289, 21)
GUICtrlSetState(-1, $GUI_DISABLE)
$Label6 = GUICtrlCreateLabel("Proxy Number", 424, 128, 70, 17)
GUICtrlSetState(-1, $GUI_DISABLE)
$Input5 = GUICtrlCreateInput("8080", 424, 144, 65, 21, BitOR($ES_AUTOHSCROLL, $ES_NUMBER))
GUICtrlSetState(-1, $GUI_DISABLE)
$Label7 = GUICtrlCreateLabel("Proxy username (leave blank if not needed)", 24, 176, 208, 17)
GUICtrlSetState(-1, $GUI_DISABLE)
$Input6 = GUICtrlCreateInput("", 24, 192, 257, 21)
GUICtrlSetState(-1, $GUI_DISABLE)
$Label8 = GUICtrlCreateLabel("Proxy password (leave blank if not needed)", 288, 176, 207, 17)
GUICtrlSetState(-1, $GUI_DISABLE)
$Input7 = GUICtrlCreateInput("", 288, 192, 201, 21, BitOR($ES_PASSWORD, $ES_AUTOHSCROLL))
GUICtrlSetState(-1, $GUI_DISABLE)
$Checkbox1 = GUICtrlCreateCheckbox("Launch as a service", 8, 218, 121, 17)
$Checkbox2 = GUICtrlCreateCheckbox("Ask before fetching/sending work (only click yes if you're on dialup)", 8, 240, 337, 17)
$Checkbox3 = GUICtrlCreateCheckbox("Allow receipt of files greater 5mb (only check if you have 1GB or more of RAM memory", 8, 264, 425, 17)
$Checkbox4 = GUICtrlCreateCheckbox("Change Advanced options", 8, 288, 145, 17)
$Label11 = GUICtrlCreateLabel("Core Priority", 280, 290, 60, 17)
$Combo1 = GUICtrlCreateCombo("", 344, 288, 145, 25)
GUICtrlSetData(-1, "Idle|Low")
$Label12 = GUICtrlCreateLabel("CPU usage requested (far right = 100)", 8, 312, 182, 17)
$Slider1 = GUICtrlCreateSlider(8, 336, 486, 29)
GUICtrlSetLimit(-1, 100, 0)
$Checkbox5 = GUICtrlCreateCheckbox("Disable highly optimised assembly code (NOT recomended)", 8, 376, 297, 17)
$Checkbox6 = GUICtrlCreateCheckbox("Disable core when on battery power (usefull for laptops)", 8, 400, 281, 17)
$OK_Btn = GUICtrlCreateButton("OK", 152, 432, 75, 25, 0)
$Cancel_Btn = GUICtrlCreateButton("Cancel", 272, 432, 75, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE, $Cancel_Btn
            Exit
        Case $SelectPath_Btn
            $Path = FileSelectFolder('Select client directory', '')
            If $Path = '' Or @error = 1 Then ContinueLoop
            GUICtrlSetData($Input1, $Path)
            
        Case $UseIE
            GUICtrlSetState($Label5, $GUI_DISABLE)
            GUICtrlSetState($Input4, $GUI_DISABLE)
            GUICtrlSetData($Input4, '')
            GUICtrlSetState($Label6, $GUI_DISABLE)
            GUICtrlSetState($Input5, $GUI_DISABLE)
            GUICtrlSetData($Input5, '8080')
            GUICtrlSetState($Label7, $GUI_DISABLE)
            GUICtrlSetState($Input6, $GUI_DISABLE)
            GUICtrlSetData($Input6, '')
            GUICtrlSetState($Label8, $GUI_DISABLE)
            GUICtrlSetState($Input7, $GUI_DISABLE)
            GUICtrlSetData($Input7, '')
        Case $UseProxy
            GUICtrlSetState($Label5, $GUI_ENABLE)
            GUICtrlSetState($Input4, $GUI_ENABLE)
            GUICtrlSetState($Label6, $GUI_ENABLE)
            GUICtrlSetState($Input5, $GUI_ENABLE)
            GUICtrlSetState($Label7, $GUI_ENABLE)
            GUICtrlSetState($Input6, $GUI_ENABLE)
            GUICtrlSetState($Label8, $GUI_ENABLE)
            GUICtrlSetState($Input7, $GUI_ENABLE)
        Case $OK_Btn
            Dim $iMsgBoxAnswer
            $iMsgBoxAnswer = MsgBox(49, "JD's convoluted F@H Installer", "Click ok to run F@H and configure it. DO NOT TOUCH ANYTHING DURRING THIS PROCESS!")
            Select
                Case $iMsgBoxAnswer = 1 ;OK
                    If GUICtrlRead($Input1) = '' Then
                        $Dir = "C:\fah\FAH504-Console4.exe"
                    Else
                        $Dir = GUICtrlRead($Input1)
                    EndIf
                    $Username = GUICtrlRead($Input2)
                    $Teamnum = GUICtrlRead($Input3)
                    $Service = GUICtrlRead($Checkbox1)
                    $Ask = GUICtrlRead($Checkbox2)
                    $Ie = GUICtrlRead($UseIE)
                    $Prox = GUICtrlRead($UseProxy)
                    $ProxName = GUICtrlRead($Input4)
                    $Port = GUICtrlRead($Input5)
                    ;$UsrPw = GUICtrlRead($Input2)
                    $ProxUsr = GUICtrlRead($Input6)
                    $ProxPw = GUICtrlRead($Input7)
                    $Big = GUICtrlRead($Checkbox3)
                    $Advanced = GUICtrlRead($Checkbox4)
                    $Core = GUICtrlRead($Combo1)
                    $Cpu = GUICtrlRead($Slider1)
                    $Ass = GUICtrlRead($Checkbox5)
                    $Batt = GUICtrlRead($Checkbox6)
                    ;$Chk = GUICtrlRead($Input19)
                    ;$Mem = GUICtrlRead($Input20)
                    ;$Wrk = GUICtrlRead($Input21)
                    ;$Avm = GUICtrlRead($Input22)
                    ;$Ignore = GUICtrlRead($Input23)
                    ;$Mach = GUICtrlRead($Input24)
                    Run("notepad.exe")
                    WinWaitActive("Untitled - Notepad")
                    ;Run($Dir)
                    ;WinWaitActive($Dir)
                    Send($Username)
                    Send("{enter}")
                    Send($Teamnum)
                    Send("{enter}")
                    If $Service = 1 Then
                        Send("y")
                    Else
                        Send("n")
                    EndIf
                    Send("{enter}")
                    If $Ask = 1 Then
                        Send("y")
                    Else
                        Send("n")
                    EndIf
                    Send("{enter}")
                    If $Ie = 1 Then
                        Send("y")
                    Else
                        Send("n")
                        Send("{enter}")
                        If $Prox = 1 And $ProxName <> '' Then
                            Send("y")
                            Send("{enter}")
                            Send($ProxName)
                            Send("{enter}")
                            Send($Port)
                            Send("{enter}")
                            If $ProxUsr <> '' And $ProxPw <> '' Then
                                Send("y")
                                Send("{enter}")
                                Send($ProxUsr)
                                Send("{enter}")
                                Send($ProxPw)
                            Else
                                Send("n")
                            EndIf
                        Else
                            Send("n")
                        EndIf
                    EndIf
                    Send("{enter}")
                    If $Big = 1 Then
                        Send("y")
                    Else
                        Send("n")
                    EndIf
                    Send("{enter}")
                    If $Advanced = 1 Then
                        Send("y")
                        Send("{enter}")
                        If $Core = "Idle" Then
                            Send("i")
                        Else
                            Send("l")
                        EndIf
                    Else
                        Send("n")
                    EndIf
                    Send("{enter}")
                    Send($Cpu)
                    Send("{enter}")                 
                    If $Ass = 1 Then
                        Send("y")
                    Else
                        Send("n")
                    EndIf
                    Send("{enter}")                 
                    If $Batt = 1 Then
                        Send("y")
                    Else
                        Send("n")
                    EndIf
                    Send("{enter}")

                Case $iMsgBoxAnswer = 2 ;Cancel
                    MsgBox(64, "JD's convoluted F@H Installer", "you Cancelled Installitaion")
            EndSelect
            
    EndSwitch
WEnd

Edited January 11, 2007 by Danny35d

w00dr0w · January 11, 2007

Welcome to AutoIt this is not a child windows as you want, but it is a different approach.

Thanks, you solved another question i was going to ask at a later date (how to disable certain inputs when others are pushed)

Really appreciated

I have a new question though, when you added the filebrowser, is there a way to point it to a specific file inside the folder instead of only pointing to the folder?

I'm use that information to both open the program and call it active (when the window opens it's name is the same as the path+filename), so if it only points to the folder i have to add another Input for the filename.

Edited January 11, 2007 by w00dr0w

Danny35d · January 12, 2007

Thanks, you solved another question i was going to ask at a later date (how to disable certain inputs when others are pushed)
Really appreciated
I have a new question though, when you added the filebrowser, is there a way to point it to a specific file inside the folder instead of only pointing to the folder?
I'm use that information to both open the program and call it active (when the window opens it's name is the same as the path+filename), so if it only points to the folder i have to add another Input for the filename.

Your welcome, change FileSelectFolder() for FileOpenDialog()

w00dr0w · January 12, 2007

Thank you again, i got it working just fine now (if i didn't get help here I'd have gone with a tabbed interface, which would probably be as convoluted at my initial iteration.)

w00dr0w · January 12, 2007

Ok, im probably getting annoying here but...

I want to make the Use adanced methods a radio like you did with IE/proxy, but whenever i click one of the radio buttons to change it the 2 default ones uncheck themselves (and from thereon out the only radio button that is clicks remains clicked)

i hope you understand what im talking about. Code to follow in a few as i need to head out for a few

Danny35d · January 12, 2007

Ok, im probably getting annoying here but...
I want to make the Use adanced methods a radio like you did with IE/proxy, but whenever i click one of the radio buttons to change it the 2 default ones uncheck themselves (and from thereon out the only radio button that is clicks remains clicked)
i hope you understand what im talking about. Code to follow in a few as i need to head out for a few

If I understood correctly you won't be able to use radio for advanced method. The reason is because that how radios work, you can only select one. I use radio for IE/proxy because you need either one or the other one, no both.

Hopefully you will understand what I mean.

w00dr0w · January 12, 2007

If I understood correctly you won't be able to use radio for advanced method. The reason is because that how radios work, you can only select one. I use radio for IE/proxy because you need either one or the other one, no both.
Hopefully you will understand what I mean.

I do. Can i use a checkbox for the advanced options (using the same type code you did to disable the proxy) to disable the advanced features?

i'll give it a go anyways and see what i come up with, but Id still like to see what you have to say.

See, anything under $Input14 in my original code doesn't apply if they don't use the advanced checkbox, and i think it would look pretty fancy if thats blanked out if they don't.

Danny35d · January 12, 2007

I do. Can i use a checkbox for the advanced options (using the same type code you did to disable the proxy) to disable the advanced features?
i'll give it a go anyways and see what i come up with, but Id still like to see what you have to say.

See, anything under $Input14 in my original code doesn't apply if they don't use the advanced checkbox, and i think it would look pretty fancy if thats blanked out if they don't.

You will need to add GUICtrlSetState(-1, $GUI_DISABLE) 6 times right bellow the following controls:

$Label11 then another below $Combo1 and below $Label12, $Slider1, $Checkbox5 and $Checkbox6

Then add the following code to Switch section:

Case $Checkbox4
            If BitAND(GUICtrlRead($Checkbox4), $GUI_CHECKED) Then
                GUICtrlSetState($Label11, $GUI_ENABLE)
                GUICtrlSetState($Combo1, $GUI_ENABLE)
                GUICtrlSetState($Label12, $GUI_ENABLE)
                GUICtrlSetState($Slider1, $GUI_ENABLE)
                GUICtrlSetState($Checkbox5, $GUI_ENABLE)
                GUICtrlSetState($Checkbox6, $GUI_ENABLE)
            Else
                GUICtrlSetState($Label11, $GUI_DISABLE)
                GUICtrlSetState($Combo1, $GUI_DISABLE)
                GUICtrlSetState($Label12, $GUI_DISABLE)
                GUICtrlSetState($Slider1, $GUI_DISABLE)
                GUICtrlSetState($Checkbox5, $GUI_DISABLE)
                GUICtrlSetState($Checkbox6, $GUI_DISABLE)
            EndIf

w00dr0w · January 12, 2007

hehe my n00bish code reigns stupid again, this is what i added to try and make it work (though it didn't)

$GUIAdv = GUICtrlRead($Checkbox4)
           If $GUIAdv = 1 Then
               GUICtrlSetState($Label11, $GUI_ENABLE)
               GUICtrlSetState($Combo1, $GUI_ENABLE)
               GUICtrlSetState($Label12, $GUI_ENABLE)
               GUICtrlSetState($Slider1, $GUI_ENABLE)
               GUICtrlSetState($Checkbox5, $GUI_ENABLE)
               GUICtrlSetState($Checkbox6, $GUI_ENABLE)
           Else
               GUICtrlSetState($Label11, $GUI_DISABLE)
               GUICtrlSetState($Combo1, $GUI_DISABLE)
               GUICtrlSetState($Label12, $GUI_DISABLE)
               GUICtrlSetState($Slider1, $GUI_DISABLE)
               GUICtrlSetState($Checkbox5, $GUI_DISABLE)
               GUICtrlSetState($Checkbox6, $GUI_DISABLE)
           EndIf

]

I'll add your code and see what happens (btw i did add the setstate under Label11-Checkbox6 before using my code)

*edit* sweet, thanks for all the help.

worked like a charm

Edited January 12, 2007 by w00dr0w

w00dr0w · January 12, 2007

yet another question

Why isn't this returning an integer between 3 and 30 (keeps returning 31 no matter the position)

$Label13 = GUICtrlCreateLabel("Interval, in minutes, between checkpoints", 8, 420, 200, 24)
$Slider2 = GUICtrlCreateSlider(8, 444, 486, 29)
GUICtrlSetLimit(27, 30, 3)

Danny35d · January 12, 2007

yet another question
Why isn't this returning an integer between 3 and 30 (keeps returning 31 no matter the position)
$Label13 = GUICtrlCreateLabel("Interval, in minutes, between checkpoints", 8, 420, 200, 24)
$Slider2 = GUICtrlCreateSlider(8, 444, 486, 29)
GUICtrlSetLimit(27, 30, 3)

I don't know if you using GUICtrlRead($Slider2) to read the value of $Slider2, but GUICtrlSetLimit() should be

GUICtrlSetLimit(-1, 30, 3) or GUICtrlSetLimit($Slider2, 30, 3)

w00dr0w · January 12, 2007

I am using GUICtrlRead($Slider2) (its how i know it's returning 31)

I dunno why i put 27 in the first field

*EDIT*

ok, i figured it out

Stupid me was trying to Send($Slider2) and instead of Send($Chk) (where $Chk = GUICtrlRead($Slider2)

w00dr0w · January 12, 2007

Out of the frying pan into the fire here...

Is there a way to read the physical memory a PC has (mine has 1gb, so it would be 1024mb memory)

Id like to change a textbox to a slider that automatically detects the users physical memory and allows them to use a slider to select how much of it they want to allocate.

If not I guess i can use a simple textbox for them to enter it in...

Danny35d · January 12, 2007

It is called MemGetStats()

Sign In

Need help with child windows

Recommended Posts

w00dr0w

Danny35d

w00dr0w

Danny35d

w00dr0w

w00dr0w

Danny35d

w00dr0w

Danny35d

w00dr0w

w00dr0w

Danny35d

w00dr0w

w00dr0w

Danny35d

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

Browse

AutoIt Resources

Release

Beta