Question about "Taskbar and Start Menu"

[Achilles 1]

Is there a way I can open this (it's under the control panel)? I've been doing this before by creating a shortcut of it but I would rather just have direct access to it.

Any help appreciated!

[MHz 71]

This code may show you how...

_TaskBarProperties()

Func _TaskBarProperties()
    Local $opt_WinWaitDelay, $oShellApp, $title_taskbar
    $opt_WinWaitDelay = Opt('WinWaitDelay', 1)
    $title_taskbar = 'Taskbar and Start Menu Properties'
    $oShellApp = ObjCreate('Shell.Application')
    If Not @error Then
        $oShellApp.TrayProperties
        If WinWait($title_taskbar, '', 5) Then
            WinSetState($title_taskbar, '', @SW_HIDE); Hide the window
            Sleep(250)
            ControlCommand($title_taskbar, '', 'Button1', 'UnCheck'); UnLock the Taskbar
            ControlCommand($title_taskbar, '', 'Button2', 'Check'); Auto-hide the Taskbar
            ControlCommand($title_taskbar, '', 'Button5', 'Check'); Show Quick Launch
            ControlCommand($title_taskbar, '', 'Button1', 'Check'); Lock the Taskbar
            ControlClick($title_taskbar, '', 'Button13'); Apply the settings
            ControlClick($title_taskbar, '', 'Button11'); OK to finish
        EndIf
    EndIf
    Opt('WinWaitDelay', $opt_WinWaitDelay)
EndFunc

[Shevilie 1]

This is not pretty but it works You will have to change the two variables i set...

AutoItSetOption("WinTitleMatchMode", 2)

;Change those two
$controlpanel = "Kontrolpanel"
$procesline = "Proceslinje"

Run("explorer.exe ""C:""")
WinWait("(C:)")
$handle = WinGetHandle("(C:)")
ControlSetText($handle, "", "Edit1", $controlpanel)
ControlSend($handle, "", "Edit1", "{ENTER}")
WinWait($controlpanel)
WinActivate("Kontrolpanel")
ControlFocus($handle, "", "SysListView321")
Send($procesline & "{ENTER}")
WinClose("Kontrolpanel")

Edit: MHz's example is way better

Edited January 28, 2007 by Shevilie

[Achilles 1]

This code may show you how...

_TaskBarProperties() 

;...

Sweet, thanks again... I thought I would have to use some object thing but I haven't used those very much... But now that I think about it there isn't much point in me bringing up the options for the Windows Start menu when I'm making my own... Still, thanks, I need that for another program.