WinList

[Hello Me You]

I want to make a script that hides windows.

I did this but I want and something else..

HotKeySet("^!h", "_hide")
HotKeySet("^!u", "_unhide")
HotKeySet("^!#x", "_exit")

While 1
WEnd

Func _hide()
    $in_hide = InputBox("Hide Window", "Enter window title:")
    If @error Then Return
    WinSetState($in_hide, "", @SW_HIDE)
EndFunc

Func _unhide()
    $in_unhide = InputBox("Unhide Window", "Enter window title:")
    WinSetState($in_unhide, "", @SW_SHOW)
EndFunc

Func _exit()
    $msg = MsgBox(1, "Exit Script", "Are you sure?")
    If $msg = 1 Then
        Exit
    EndIf
EndFunc

It shows windows in a MsgBox, not in a list.

[SmOke_N]

A little search never hurt:

http://www.autoitscript.com/forum/index.ph...st&p=190682

http://www.autoitscript.com/forum/index.ph...;hl=hide+window

http://www.autoitscript.com/forum/index.ph...;hl=hide+window

[Paulie]

I want to make a script that hides windows.

I did this but I want and something else..

As you see to hide a window you have to type its title. Can I do it to show a window list?

GuiCtrlCreateTreeView() (Use the $LVS_CHECKBOXES style)(I think its something like that)

GUICtrlCreateTreeViewItem()

[MrCreatoR]

Hi to all!

Here is basic example to Win Hidder GUI:

expandcollapse popup

Opt("GuiOnEventMode", 1)
Opt("WinTitleMatchMode", 4)

$WinHidderTitle = "Windows Hidder"
$GUI = GUICreate($WinHidderTitle, 300, 150)
GUISetOnEvent(-3, "Quit")

GUICtrlCreateLabel("Choose a window that you like to Hide/Show:", 50, 20)

$WinListCombo = GUICtrlCreateCombo("", 20, 100, 260)
GUICtrlSetData(-1, _WinListToString())
GUICtrlSetOnEvent(-1, "ComboSelect")

$HideUnHideButton = GUICtrlCreateButton("Hide/Show", 100, 50, 100, 20)
GUICtrlSetOnEvent(-1, "HideShow")

GUISetState()

While 1
    Sleep(100)
WEnd

Func ComboSelect()
    If WinExists(GUICtrlRead($WinListCombo)) Then
        If _IsVisible(GUICtrlRead($WinListCombo)) Then
            GUICtrlSetData($HideUnHideButton, "Hide")
        Else
            GUICtrlSetData($HideUnHideButton, "Show")
        EndIf
    Else
        GUICtrlSetData($HideUnHideButton, "Hide/Show")
    EndIf
EndFunc

Func HideShow()
    $WinTitle = GUICtrlRead($WinListCombo)
    If WinExists($WinTitle) Then
        If _IsVisible($WinTitle) Then
            WinSetState($WinTitle, "", @SW_HIDE)
            GUICtrlSetData($HideUnHideButton, "Show")
        Else
            WinSetState($WinTitle, "", @SW_SHOW)
            GUICtrlSetData($HideUnHideButton, "Hide")
        EndIf
    Else
        GUICtrlSetData($HideUnHideButton, "Hide/Show")
    EndIf
EndFunc

Func _WinListToString()
    Local $WinListArr = WinList(), $WinListString
    For $i = 1 To $WinListArr[0][0]
        If $WinListArr[$i][0] <> "" And $WinListArr[$i][0] <> $WinHidderTitle Then $WinListString &= $WinListArr[$i][0] & "|"
    Next
    Return $WinListString
EndFunc

Func _IsVisible($handle)
    Return BitAnd(WinGetState($handle), 2)
EndFunc

Func Quit()
    Exit
EndFunc