GUI Resizing method

[AlanR]

In VB I am able to resize a window without having the controls resize or reposition. I use this to effectively exclude controls in certain views. For instance, a "More" button might increase the GUI window height, revealing controls that are "cropped off" in normal view. Then the same button, now labelled "Less" will restore the window to its original size and hide those extra controls.

I can't for the life of me achieve the same effect in AutoIt. I need to first capture the GUI metrics, since the user might have dragged it. Can anybody help please?

Alan

[MrCreatoR]

Look in help file for GUICtrlSetResizing.

[AlanR]

OK, I've tried using 802 as the GUICtrlSetResizing parameter. I guess I have to do this on a per control basis. It seems to have the right effect, but there's something screwy with the resizing:

#include <GUIConstants.au3>
; == GUI generated with Koda ==
$frmTest = GUICreate("frmTest", 377, 143, 192, 125);whlt

$Button1 = GUICtrlCreateButton("Smaller", 16, 16, 57, 25)
GUICtrlSetResizing($Button1, 802)

GUICtrlCreateLabel("ALabel1", 104, 48, 43, 17)

$Input1 = GUICtrlCreateInput("AInput1", 104, 80, 201, 21, -1, $WS_EX_CLIENTEDGE)
GUICtrlSetResizing($Input1, 802)
GUISetState(@SW_SHOW)

$big=0
While 1
    $msg = GuiGetMsg()
    Select
    Case $msg = $Button1
        if $big = 0 Then
            WinMove($frmTest, 192, 125, 377, 143);xywh
            $big = 1
            GUICtrlSetData($Button1, "Smaller")
        Else
            WinMove($frmTest, 192, 125, 98, 55)
            $big = 0
            GUICtrlSetData($Button1, "Bigger")
        EndIf
    
    Case $msg = $GUI_EVENT_CLOSE
        ExitLoop
    Case Else
    ;;;;;;;
    EndSelect
WEnd
Exit

The top left is meant to stay put but it doesn't and the resizing is not what it looked like in Koda. I must be doing something wrong with WinMove, but can't figure out what.

Alan

[midlander]

I'm having the same problem. I wan't my GUI to behave like most Windows programs seem to - that the user can resize the main window without the individual controls moving or resizing.

I've tried using 802 as the GUICtrlSetResizing parameter as well. And 870. And most other combinations.

I'm sure I've missed something...

[smashly]

  Quote

The top left is meant to stay put but it doesn't and the resizing is not what it looked like in Koda. I must be doing something wrong with WinMove, but can't figure out what.

Hi,

Yep GUICtrlSetResizing() is needed for each control as you said.

You've left out a parameter in the winmove() function, if your not needing the window text parameter then null it with ""

WinMove($frmTest, "", 192, 125, 377, 143)

Cheers

[Zedna]

As smashly said.

Here is corrected example:

#include <GUIConstants.au3>

$frmTest = GUICreate("frmTest", 377, 143);whlt
$Button1 = GUICtrlCreateButton("Smaller", 16, 16, 57, 25)
GUICtrlSetResizing(-1, $GUI_DOCKALL)
GUICtrlCreateLabel("ALabel1", 104, 48, 43, 17)
GUICtrlSetResizing(-1, $GUI_DOCKALL)
$Input1 = GUICtrlCreateInput("AInput1", 104, 80, 201, 21, -1, $WS_EX_CLIENTEDGE)
GUICtrlSetResizing(-1, $GUI_DOCKALL)
GUISetState(@SW_SHOW)

$big=1
While 1
    $msg = GuiGetMsg()
    Select
    Case $msg = $Button1
        if $big = 0 Then
            WinMove($frmTest, '', Default, Default, 377, 143);xywh
            $big = 1
            GUICtrlSetData($Button1, "Smaller")
        Else
            WinMove($frmTest, '', Default, Default, 192, 125)
            $big = 0
            GUICtrlSetData($Button1, "Bigger")
        EndIf
    
    Case $msg = $GUI_EVENT_CLOSE
        ExitLoop
    EndSelect
WEnd