How to remove duplicate elements from an array?

[sublimnl]

As the topic states, I need a way to remove duplicate elements from a single dimensional array. I am trying to populate a combo box using an ini file as my source. The layout of the section of the ini file in question is...

[sites]

172.16.4=HOUSTON

172.16.29=PERTH

172.16.25=UK

172.16.17=DELFT

172.16.20=KL

172.16.181=RIO

There is more to it than that as there is more than one subnet for each site. So in the code below, I read the entire "Sites" section to the array $inisites, and then use a For loop to move the site names into a single dimensional array called $sitearray. Now I need a way to yank out all the dupes. Have tried a few things (see the 2nd For Loop below), but keep winding up with dimension range errors in the middle of execution. Anyone have any ideas? I found UDF that claims to remove duplicates from an array, but that did nothing at all.

Thanks!

CODE

$inisites = IniReadSection("Ale.ini","Sites")

Dim $sitearray[$inisites[0][0]]

$sitearray[0] = $inisites[0][0]

For $i = 1 To $inisites[0][0]

$sitearray[$i] = $inisites[$i][1]

Next

For $j = 1 To $sitearray[0]

For $i = 1 To $sitearray[0]

MsgBox(4096,"","$i=" & $i & @CRLF & $sitearray[$j] & @CRLF & $sitearray[$i]) ; debugging purposes

If $sitearray[$j] = $sitearray[$i] Then

_ArrayDelete($sitearray,$i)

EndIf

Next

Next

$sitelist = _ArrayToString($sitearray,"|")

GUICtrlSetData($cmbsite,$sitelist)

[xcal]

#include <array.au3>

Global $array[16] = [15, 1, 2, 3, 3, 4, 5, 6, 6, 7, 8, 9, 9, 9, 9, 0]

$mynewarray = dupecheckerthingy($array)

_ArrayDisplay($mynewarray, '')

Func dupecheckerthingy($showmethearray)
    Local $tmparray[1] = ['']
    For $i = 1 To UBound($showmethearray) - 1
        _ArraySearch($tmparray, $showmethearray[$i])
        If @error Then _ArrayAdd($tmparray, $showmethearray[$i])
    Next
    $tmparray[0] = 'Number of elements = ' & UBound($tmparray) - 1
    Return $tmparray
EndFunc

[sublimnl]

you rock. thanks!

[MrCreatoR]

Here is my version, its not required any includes (Array.au3):

Func _ArrayDeleteClones($sArray)
    If Not IsArray($sArray) Then Return SetError(1)
    If UBound($sArray, 0) > 1 Then Return SetError(2)
    Local $NewArr[1], $IsFound=0, $NewArrCnt=0, $Extended=0
    For $i = 1 To UBound($sArray) - 1
        $IsFound = 0
        For $j = 1 To UBound($NewArr)-1
            If $sArray[$i] = $NewArr[$j] Then
                $IsFound = 1
                $Extended += 1
                ExitLoop
            EndIf
        Next
        If Not $IsFound Then
            $NewArrCnt += 1
            ReDim $NewArr[$NewArrCnt+1]
            $NewArr[$NewArrCnt] = $sArray[$i]
        EndIf
    Next
    $NewArr[0] = UBound($NewArr) - 1
    Return SetError(0, $Extended, $NewArr)
EndFunc

EDIT: A litle edit, now it's also return an @Extended that include number of duplicates that was removed from the array. And also a litle error checking returns.

Edited March 27, 2007 by MsCreatoR