Clicking Label to Set Off An Event

[dcop]

I'm trying the fillowing to get a labels data to go into an input box. Is this possible to do by clicking on the label? It's not working this way.

$Label2 = GUICtrlCreateLabel("", 0, 40, 109, 17)

GUICtrlSetBkColor(-1, 0xC0C0C0)

GUISetOnEvent(-1, "putToInputForEditing")

Func putToInputForEditing()

$CtrlID = @GUI_CtrlId

Switch $CtrlID

Case $label2

$readLocLabel = GUICtrlRead($label2)

GUICtrlSetData($input1,$readLocLabel)

EndSwitch

EndFunc

[martin]

I'm trying the fillowing to get a labels data to go into an input box. Is this possible to do by clicking on the label? It's not working this way.

$Label2 = GUICtrlCreateLabel("", 0, 40, 109, 17)

GUICtrlSetBkColor(-1, 0xC0C0C0)

GUISetOnEvent(-1, "putToInputForEditing")

Func putToInputForEditing()

$CtrlID = @GUI_CtrlId

Switch $CtrlID

Case $label2

$readLocLabel = GUICtrlRead($label2)

GUICtrlSetData($input1,$readLocLabel)

EndSwitch

EndFunc

Yes I think you're right. If you use OnEvent then you do not detect the label being clicked. If you don't use on event then you can detect when it's clicked.

The help file says

"GUISetOnEvent

Defines a user function to be called when a system button is clicked."

so presumably it's limited to buttons, which includes check boxes and radio buttons which are special buttons.

[smashly]

Works for me

expandcollapse popup

#include <GUIConstants.au3>

Opt("GUIOnEventMode", 1)

Global $labels[6]

$y = 10

GuiCreate('Test')
For $i = 1 to 5
    $labels[$i] = GUICtrlCreateLabel("Test " & $i, 10, $y, 109, 17)
    GUICtrlSetOnEvent(-1, "putToInputForEditing")
    GUICtrlSetBkColor(-1, 0xC0C0C0)
    $y = $y + 20
Next
$input1 = GUICtrlCreateInput('', 10, $y, 100, 17)
$Button = GUICtrlCreateButton('Send Edit Back',10, $y + 20, 100, 20)
GUICtrlSetOnEvent(-1, "putToInputForEditing")
GUICtrlSetState(-1, $GUI_DISABLE)
GUISetOnEvent($GUI_EVENT_CLOSE, 'Close') 
GUISetState()

While 1
    Sleep(10)
WEnd

Func putToInputForEditing()
    For $x = 1 To 5
        Select
            Case @GUI_CTRLID = $labels[$x]
                $labels[0] = $labels[$x]
                GUICtrlSetData($input1, GUICtrlRead($labels[$x]))
                GUICtrlSetState($Button, $GUI_ENABLE)
        EndSelect
    Next
    Select
        Case @GUI_CTRLID = $Button
            GUICtrlSetData($labels[0], GUICtrlRead($input1))
            GUICtrlSetData($input1, '')
            GUICtrlSetState($Button, $GUI_DISABLE)
            $labels[0] = ''
    EndSelect       
EndFunc

Func Close()
    Exit
EndFunc

Cheers

Edited May 6, 2007 by smashly

[martin]

Works for me

Yes, now I see why the first post didn't work. Instead of GuiCtrlSetOnEvent there was GuiSetOnEvent. :">

[dcop]

Yes, now I see why the first post didn't work. Instead of GuiCtrlSetOnEvent there was GuiSetOnEvent. :">

Yes, Thanks so much to Smashly!!!!!!!!