FileGetShortcut($variable)

[mjg 0]

Can anyone tell me why this doesn't seem to be working properly:

$search = FileFindFirstFile(@DesktopDir &"\CTMS*.lnk")
If $search = -1 Then
    $search = FileFindFirstFile(@DesktopCommonDir &"\CTMS*.lnk")
    If $search = -1 Then
        MsgBox(0,"Error","CTMS Does not appear to be installed")
        Exit
    EndIf
EndIf

$string1 = FileFindNextFile($search)
MsgBox(0,$string1,$string1) ; This displays the correct shortcut name
;FileClose($search);just tried this for testing

$string2 = FileGetShortcut($string1)
If @error Then
    MsgBox(0,"Error","Unknown Error")
    Exit
EndIf

MsgBox(0,$string2[1],$string2[1])

The only thing that doesn't seem to work is the FileGetShortCut with a variable. It errors out which gives me the unknown error message box.

I've searched around the forum, and found a few places where it seems as if FileGetShortcut will work with a variable, but I just can't figure out what is wrong; I

-mjg

[PsaltyDS 38]

You have to provide the FULL path, not just the filename:

$sPath = @DesktopDir
$search = FileFindFirstFile($sPath & "\CTMS*.lnk")
If $search = -1 Then
    $sPath = @DesktopCommonDir
    $search = FileFindFirstFile($sPath & "\CTMS*.lnk")
    If $search = -1 Then
        MsgBox(0, "Error", "CTMS Does not appear to be installed")
        Exit
    EndIf
EndIf

$string1 = $sPath & "\" & FileFindNextFile($search)
MsgBox(0, "Found", $string1)

$string2 = FileGetShortcut($string1)
If @error Then
    MsgBox(0, "Error", "@errot = " & @error)
    Exit
EndIf

MsgBox(0, $string2[1], $string2[1])

[mjg 0]

You have to provide the FULL path, not just the filename:

$sPath = @DesktopDir
$search = FileFindFirstFile($sPath & "\CTMS*.lnk")
If $search = -1 Then
    $sPath = @DesktopCommonDir
    $search = FileFindFirstFile($sPath & "\CTMS*.lnk")
    If $search = -1 Then
        MsgBox(0, "Error", "CTMS Does not appear to be installed")
        Exit
    EndIf
EndIf

$string1 = $sPath & "\" & FileFindNextFile($search)
MsgBox(0, "Found", $string1)

$string2 = FileGetShortcut($string1)
If @error Then
    MsgBox(0, "Error", "@errot = " & @error)
    Exit
EndIf

MsgBox(0, $string2[1], $string2[1])

Ok, I'll give that a try, makes sense now. Thanks a lot for your help.

-mjg