Organize Includes in Scite for Autoit

Xenobiologist · July 27, 2008

Hi,

wow - thanks Jos for your comment.

Firstly, I try to answer your questions and then I will point out the problem of OI I see.

1. Does your script follow the exact standard for Include path search etc. I see you define "extra" includes in an INI? Are you also reading the same Registry entries as AutoIt3 does for finding extra includes?

OI reads the install path of Autoit from the registry and then adds the folder like this : $InstallPath & '\Include\'

$InstallPath is the return value of RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt', 'InstallDir')

If beta is installed it reads the information also for beta version.

You can define as many pathes to your udfs (in the includes.ini, section [uDF_Include_Pathes]) as you want to :

[uDF_Include_Pathes]

MyUDFPath1=

MyUDFPath2=

MyUDFPath3=

MyUDFPath4=

2. Do you support a commandline option to tell it to use Production or Beta includes?

Until now, there is no commandline option for that, but I shouldn't be that hard to implement. OI gets the starting options from the includes.ini.

ReleaseOrBeta=Release tells OI whether to start with Release or with Beta version.

OI prepares the ini only for one situation. If you switch, the scan starts again. The ini contains either Release status or Beta status.

Problems: OI does not check for includes in includes. So if you include a file where some other includes are set, then OI will still point out you need those includes.

Mega

@Tlem : I'll think about the language ini.

Jos · July 27, 2008

The Include logic I was referring to is how it is described in the helpfile (mk:@MSITStore:C:\Program%20Files\AutoIt3\AutoIt3.chm::/html/keywords/include.htm)

There is another Include directory value which is read by AutoIt3 which is used to define the location of the users own include files.

There is a special registry value that can be created at "HKEY_CURRENT_USER\Software\AutoIt v3\AutoIt" called "Include". It should be a REG_SZ (string) value. The contents of this value are a semi-colon delimited list of directories that should be searched for files when resolving #include's in addition to the standard locations.

Jos

Tlem · July 27, 2008

Mega
@Tlem : I'll think about the language ini.

Great.

Maybe if you take a look to run like Scite and Scite4autoIt With the file locale.properties it would be better.

Like this we can have a universal language file for each countries.

Xenobiologist · August 1, 2008

The Include logic I was referring to is how it is described in the helpfile (mk:@MSITStore:C:\Program%20Files\AutoIt3\AutoIt3.chm::/html/keywords/include.htm)
There is another Include directory value which is read by AutoIt3 which is used to define the location of the users own include files.
Jos

Hi,

okay, I knew that extra udf path, but I missed to implement that. That is why, I just added only one path to get my udfs found and also added this path manually to the includes.ini of OI.

I will implement a search for those located udf (folders) in the next version.

But I'm thinking of don't let OI search for includes in the ScriptDir, because I have sometimes > 3000 au3 files in my testing folder and then OI would have to check them all. The includes.ini will explode I also recommend to only saving really udfs into the folder which OI should anaylse.

So, what do you think? Is this difference to normal Scite behaviour okay, or should OI always analyse the ScriptDir, too? If yes, this will lead to another problem: The ini creation has to be done very often, cause the folders to look for change very often, if you use OI for different script located in different folders.

Tlem : I also started to implement multilingualism. This will also be included in the next version. (I can only do it for English and German) but it will be no problem to add other languages.

Mega

Jos · August 1, 2008

I think the UDF file search should follow the standard AutoIt3 logic to avoid confusion, how else would you be able to determine if a UDF is already in one of the #include(d) files?

I have written this script some time ago which has the standard AutoIt3 include logic in it including the user includes. The script should be located in the AutoIt3 directory. Maybe that helps you with your implementation.

#include <file.au3>
Global $SourceFileName = FileOpenDialog("Specify the file to be expanded", @ScriptDir, "AutoIt3 Script (*.au3)", 3)
If @error Then Exit
FileChangeDir(@ScriptDir)
Global $OutPutFileName = StringReplace($SourceFileName, ".au3", "_extended.au3")
;
; Get Include Paths
;
Global $User_IncludeDirs = StringSplit(RegRead("HKCU\Software\AutoIt v3\Autoit", "Include"), ";")
Global $IncludeDirs[2 + UBound($User_IncludeDirs) - 1]
Global $IncludeFiles[500], $IncludeFilesCnt = 1
$IncludeFiles[$IncludeFilesCnt] = $SourceFileName
; First store the AutoIt3 directory to the search table
$IncludeDirs[0] = @ScriptDir & "\include"
Global $I_Cnt = 1
; Add User Include Directories to the table
For $x = 1 To $User_IncludeDirs[0]
    If StringStripWS($User_IncludeDirs[$x], 3) <> "" And FileExists($User_IncludeDirs[$x]) Then
        $IncludeDirs[$I_Cnt] = StringReplace($User_IncludeDirs[$x], '"', '')
        $I_Cnt += 1
    EndIf
Next
; Add the scriptpath as last entry to the table
Dim $szDrive, $szDir, $szFName, $szExt
_PathSplit($SourceFileName, $szDrive, $szDir, $szFName, $szExt)
$IncludeDirs[$I_Cnt] = _PathFull($szDrive & $szDir)
;
; Add \ at the end of the Include dirs in the search table
For $x = 0 To $I_Cnt
    If StringRight($IncludeDirs[$x], 1) <> "\" Then
        $IncludeDirs[$x] &= "\"
    EndIf
Next
; 
;  Process scriptfile
;
$H_Inp = FileOpen($SourceFileName, 0)
If @error Then
    MsgBox(0, "error", " Unable to open Sourcefile:" & $SourceFileName)
    Exit
EndIf
$H_Out = FileOpen($OutPutFileName, 2)
If @error Then
    MsgBox(0, "error", " Unable to open Ouputfile:" & $OutPutFileName)
    Exit
EndIf
;
While 1
    $TempRec = FileReadLine($H_Inp)
    If @error Then ExitLoop
    $t_TempRec = StringStripWS(StringLeft($TempRec, 50), 3)
    If @error Then ExitLoop
    If StringLeft($TempRec, 8) <> "#include" Then
        FileWriteLine($H_Out, $TempRec)
    Else
        If StringLeft($t_TempRec, 13) = "#include-once" Then
            $Include_Once = 1
        Else
            Add_Include($TempRec)
        EndIf
    EndIf
WEnd
FileClose($H_Inp)
FileClose($H_Out)
ConsoleWrite($OutPutFileName & " (1,1) :  Outputfile created." & @CRLF)

;=========================================================
; Add all #Include files to the outputfile - recursively
;=========================================================
Func Add_Include($Include_Rec, $source = "Main")
    Local $TempRec, $ChkInclude, $Include_Once = 0, $InIncludeCnt, $NeedsIncluded, $IncludeFile, $IncludeFileFound = 0
    Local $H_Incl
; Find the proper path
    $IncludeFile = StringMid(StringStripWS($Include_Rec, 3), 9)
    $IncludeFile = StringStripWS($IncludeFile, 3)
; Determine the Path sequence to scan for include files
    If StringLeft($IncludeFile, 1) = "<" Then
        $IncludeFile = StringReplace($IncludeFile, ">", "")
        $IncludeFile = StringReplace($IncludeFile, "<", "")
        $IncludeFile = StringStripWS($IncludeFile, 3)
        For $x = 0 To $I_Cnt
            If $IncludeDirs[$x] <> "" And FileExists($IncludeDirs[$x] & $IncludeFile) Then
                $IncludeFile = $IncludeDirs[$x] & $IncludeFile
                $IncludeFileFound = 1
                ExitLoop
            EndIf
        Next
    Else
        $IncludeFile = StringReplace($IncludeFile, "'", "")
        $IncludeFile = StringReplace($IncludeFile, '"', "")
        $IncludeFile = StringStripWS($IncludeFile, 3)
        For $x = $I_Cnt To 0 Step - 1
            If $IncludeDirs[$x] <> "" And FileExists($IncludeDirs[$x] & $IncludeFile) Then
                $IncludeFile = $IncludeDirs[$x] & $IncludeFile
                $IncludeFileFound = 1
                ExitLoop
            EndIf
        Next
    EndIf
; If File is found then determine if it still needs to be included
    If $IncludeFileFound Then
    ; Check for #Include_once
        $TempRec = FileRead($IncludeFile)
        If StringInStr($TempRec, "#include-once") Then $Include_Once = 1
    ; check If include is already included
        $NeedsIncluded = 1
        If $Include_Once = 1 Then
            For $ChkInclude = 1 To $IncludeFilesCnt
                If $IncludeFiles[$ChkInclude] = $IncludeFile Then
                    $NeedsIncluded = 0
                    ExitLoop
                EndIf
            Next
        Else
        ;TraceLog("==> *** Needs to be included since no #include-once is found.")
        EndIf
    ;
        If $NeedsIncluded = 1 Then
            TraceLog("+ ==> IncludeOnce=" & $Include_Once & " Including:" & $IncludeFile & "   Include by:" & $source)
            FileWriteLine($H_Out, ";*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*")
            FileWriteLine($H_Out, ";* Start Include:" & $IncludeFile & "   Include by:" & $source)
            FileWriteLine($H_Out, ";*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*")
            $InIncludeCnt = 0
            $IncludeFilesCnt += 1
            $IncludeFiles[$IncludeFilesCnt] = $IncludeFile
            $H_Incl = FileOpen($IncludeFile, 0)
            While 1
                $TempRec = FileReadLine($H_Incl)
                If @error Then ExitLoop
                $t_TempRec = StringStripWS(StringLeft($TempRec, 50), 3)
                If StringLeft($TempRec, 8) <> "#include" Then
                    FileWriteLine($H_Out, $TempRec)
                Else
                    If StringLeft($t_TempRec, 13) <> "#include-once" Then
                        Add_Include($TempRec, $IncludeFile)
                    EndIf
                EndIf
            WEnd
            FileWriteLine($H_Out, ";*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*")
            FileWriteLine($H_Out, ";* End Include:" & $IncludeFile & "   Include by:" & $source)
            FileWriteLine($H_Out, ";*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*")
            FileClose($H_Incl)
        Else
            TraceLog("  ==> Skipped, Already included:" & $IncludeFile)
            $IncludeFile = ""
        EndIf
    Else
        TraceLog("!==> *** ERROR: include file not found :" & $Include_Rec)
    EndIf
EndFunc
;
Func TraceLog($text)
    ConsoleWrite($text & @CRLF)
EndFunc

Tolf · August 19, 2008

Hi,

Thanks for this very useful script (and for Tlem who has communicated for it in the french forum) !

I've a suggestion for the installation : instead of overwriting the SciTEUser.properties file :

FileInstall('.\SciTEUser.properties', @UserProfileDir & '\SciTEUser.properties', 1)

the installer should just add the modifications to it :

local $file = FileOpen(@UserProfileDir & '\SciTEUser.properties', 1)
FileWrite($file, FileRead('.\SciTEUser.properties'))
FileClose($file)

Xenobiologist · August 20, 2008

Hi,

Thanks for this very useful script (and for Tlem who has communicated for it in the french forum) !

I've a suggestion for the installation : instead of overwriting the SciTEUser.properties file :
FileInstall('.\SciTEUser.properties', @UserProfileDir & '\SciTEUser.properties', 1)
the installer should just add the modifications to it :
local $file = FileOpen(@UserProfileDir & '\SciTEUser.properties', 1)
 FileWrite($file, FileRead('.\SciTEUser.properties'))
 FileClose($file)

Hi,

thanks for that. I'll have a look at it.

Mega

ken82m · November 2, 2008

Bless you! lol

It drives me nuts sometimes looking up what to include.

Plus have a lot of my own UDF's this will come in handy for :mellow:

One tip don't know how many people would use it though.

The ability to use standard CTRL/SHIFT behavior to select individual includes you want to take action on.

Thanks again,

Kenny

ken82m · November 2, 2008

grrr...I just typed this and hit back space on my keyboard by accident lol

Anyway...

okay I modified c:\Program Files\AutoIt3\SciTE\OrganizeIncludes\includes.ini

with MyUDFPath1=D:\Custom UDF's

After running your script I see ;StringCountOccurance; under [includePathes]

So it found the file. But the function _StringCountOccurance is not listed in the INI.

I tried hitting Renew INI and Refresh but it still didn't find it.

The GUI says StringCountOccurance.au3 is not needed.

Even though my script contains this line:

$Count[$Loop] = _StringCountOccurance($Lines[$Loop], '"url":"')

I've included the exact content of my UDF below.

I'd appreciate any help. Maybe it's just how I have something formatted.

Thanks,

Kenny

And here are the exact contents of the UDF:

I tried removing all the commends just in case but no help there.

#cs --------------------------------------------------------------------------------------
AutoIt Version: 3.2.13.9 (beta)
Source:      Copied from one of the SQL Lite examples.

Script Function:
This function will return how many times a query exists within a string

Syntax:
_StringCountOccurance($sSearchString,$sSubString,$fCaseSense = 0)

Parameters:
$sSearchString - String to be searched
$sSubString - String to search for
$fCaseSense - 0  Not case sensitive (default)
                     1  Case sensitive

Returns:
      Success: Returns the number of times the substring was found. 
      Failure: Returns 0 if substring not found.

#ce --------------------------------------------------------------------------------------

Func _StringCountOccurance($sSearchString,$sSubString,$fCaseSense = 0); Returns Number of $sSubString in $sSearchString
Local $iOccCnt = 1
Do
  If StringInStr($sSearchString,$sSubString,$fCaseSense,$iOccCnt) > 0 Then
   $iOccCnt += 1
  Else
   ExitLoop
  EndIf
Until 0
Return $iOccCnt - 1
EndFunc

Edited November 2, 2008 by ken82m

ken82m · November 3, 2008

Okay I figured it out. You have to have a trailing backslash when you add the directory to the ini.

To work around it I made one change to _addUDFsToArray

I changed:

For $i = 1 To $udfIncludesPathes_A[0][0]
   If FileExists($udfIncludesPathes_A[$i][1]) = 1 Then
    _ArrayAdd($includesPathes_A, $udfIncludesPathes_A[$i][1])

To:

For $i = 1 To $udfIncludesPathes_A[0][0]
   If FileExists($udfIncludesPathes_A[$i][1]) = 1 Then
    If StringLeft($udfIncludesPathes_A[$i][1], 1) <> "\" Then $udfIncludesPathes_A[$i][1] = $udfIncludesPathes_A[$i][1] & "\"
    _ArrayAdd($includesPathes_A, $udfIncludesPathes_A[$i][1])

It just adds a trailing backslash if it doesn't exist.

_________________________________________________

And just for looks:

I'm also attaching an improved logo for you :mellow:

And I added:

#include <EditConstants.au3>

And an additional parameter to your three input boxes at the top of the window

, $ES_READONLY

Thanks alot for the work on this again.

Its made my life much easier already designing a GUI for one of my scripts.

Thanks,

Kenny

EDIT: RARed image and re-uploaded. Needed some more space.

Edited November 18, 2008 by ken82m

Xenobiologist · November 3, 2008

Hi,

thanks for that. I did not work on the script for a long time. Maybe I can do it on X-Mas holiday.

This is the current ToDo-List:

; **************************************************************

; ToDo : Add includes from HKEY_CURRENT_USER\Software\AutoIt v3\AutoIt

; ToDo : Includes inside of includes

; ToDo : Better names for the language ObjNames

; ToDo : Implement GUI for chosing the language (saving to ini)

; ToDo : Start for Beta or Release with parameter (command line)

; ToDo : New installer

; ToDo : Change installer to add stuff to SciterUser.properties instead of replacing it

; ToDo : Bug --> Search for includes in the first and last line of code

; ToDo : If keyword not in code then throw message!

; **************************************************************

Jos also mentioned some things to change aswell, maybe I can change them too.

Mega

ken82m · November 3, 2008

Nice, can't wait :mellow:

I have a few UDF's with #includes so that'll be handy.

Achilles · November 4, 2008

Any chance on getting 64bit (Vista) support?

I just tried it and it doesn't acknowledge AutoIt or scite as being installed even though they are... I'll see if I can find the problems and then I'll post them.

ken82m · November 4, 2008

Found a little bug:

If a needed include is commented out with a ; it will still show up as green.

But at the same time un-needed includes with a ; are not picked up.

So it sounds like you have the logic already on the un-needed side of things just not on the needed side.

I didn't test #cs/#ce but I don't think anyone cares about that myself included lol

Thanks,

Kenny

Edited November 4, 2008 by ken82m

Xenobiologist · November 4, 2008

Hi,

thanks for testing!!! Seems the topic gets some activity again. Nice. :mellow:

That motivates me to have a look at the script again.

For some reason which I do not remember I explicitly implement the behaviour with commented includes. Anyhow I can change it back I guess.

For 64 Bit Support which I cannot test cause I do not have 64 Bit or Vista :-). Maybe you regkey is different to this.

; ReleaseVersion
Global $InstallPath = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt', 'InstallDir')
Global $InstallVersion = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt', 'Version')
; BetaVersion
Global $betaInstallPath = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt', 'betaInstallDir')
Global $betaInstallVersion = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt', 'betaVersion')

Mega

Achilles · November 4, 2008

Yeah, I figured that out and changed this part:

If @OSArch = 'X64' then 
        $installDir = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\AutoIt v3\AutoIt', 'InstallDir')
    Else 
        $installDir = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt', 'InstallDir')
    EndIf
    If $installDir = '' Then Return -1
    If @AutoItVersion < '3.2.12.0' Then Return -1
    Return 1

Then it installed right... But now it won't run on beta.. I'm still trying to find out why.

Edit: Oh wait, I'll try changing that in the OrganiceIncludes4.3au3 file...

Edited November 4, 2008 by Achilles

Achilles · November 4, 2008

Ok, if you replace the part you showed me in your post with this:

If @OSArch = 'X64' then 
    $InstallPath = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\AutoIt v3\AutoIt', 'InstallDir')
    $InstallVersion = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\AutoIt v3\AutoIt', 'Version')
    
    $betaInstallPath = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\AutoIt v3\AutoIt', 'betaInstallDir')
    $betaInstallVersion = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\AutoIt v3\AutoIt', 'betaVersion')    
Else 
    $InstallPath = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt', 'InstallDir')
    $InstallVersion = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt', 'Version')
    
    $betaInstallPath = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt', 'betaInstallDir')
    $betaInstallVersion = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt', 'betaVersion')    
EndIf

That works if you run the script in beta (Alt + F5) but not normally. It doesn't work either way when you press Ctrl Alt Shift I or whatever it is.

ken82m · November 4, 2008

I did find this comment this morning around 390:

; @@@ Change 4.1 includes comments again rausnehmen (problem if needed and even out yet!)

have a copy of 4.0 you can send me? lol :mellow:

ken82m · November 6, 2008

Here's what I've done so far:

Added improved logo

Added Insert After Initial Comments function to At Top Option to GUI/INI

Added update INI file when user closes window using the X / Updated Exit button ToolTip

AutoIT Prod/Beta Version and File Name input fields changed to Read Only

Added Detect commented #includes option to to GUI/INI

Add au3betadir to au3.properties during install

Set SciTE.properties action to use au3beta dir if beta is active during install

Setup to automatically add trailing \ if missing from MyUDFPath ini and registry UDF path entries

IN PROGRESS: Read includes from registry, merge with ini entries and extract unique ones

I've kept notes on everything I've done and where I put it so I'll send it to you with the source code when

I'm done and you can use what you want :mellow:

-Kenny

Xenobiologist · November 6, 2008

WOW, thanks!

I'll will of course have a look at what you've done.

Unfortunately, I will not be able to work on the script before december. So, do not hurry. :mellow:

Thanks again!

Mega

Organize Includes in Scite for Autoit

Recommended Posts

Link to comment

Share on other sites

Top Posters In This Topic

Top Posters In This Topic

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members