Switch between tray and gui

[Walls192]

How would I switch between tray and gui?

For example I have a script that sits in the tray but when I press an option i want a a gui to come up to change settings.

[Xenobiologist]

Hi,

GuiSetState

So long,

Mega

[Nahuel]

Example:

expandcollapse popup

#include <GUiconstants.au3>
#include <Constants.au3>

Opt("TrayMenuMode",1)
Opt("TrayAutoPause",0)
TraySetClick(16)

$min=False
$Main=GUICreate("")
GUISetState()
;Tray Menu
$Show=TrayCreateItem("Show/Hide")
TrayItemSetState(-1,$TRAY_DEFAULT)
$Quit=TrayCreateItem("Quit")

While 1
    $gMsg=GUIGetMsg()
    Switch $gMsg
    Case $GUI_EVENT_CLOSE
        _Hide_Show()
    EndSwitch
    $tMsg=TrayGetMsg()
    Switch $tMsg
    Case $Show
        _Hide_Show()
    Case $Quit
        Exit
    EndSwitch
WEnd
    

Func _Hide_Show()
    If $min Then
        GUISetState(@SW_SHOW,$Main)
        $min=False
    Else
        GUISetState(@SW_HIDE,$Main)
        $min=True
    EndIf
EndFunc;==>Hide_Show

Double click tray icon to show/hide GUI