Check if GUI Menu is open?

[BananaFredSoft]

Is it possible to check if a GUI menu is open? Thanks in advance.

[JustinReno]

A GUI Menu?

[BananaFredSoft]

A GUI Menu?

A GUI Menu.

$menu = GUICtrlCreateMenu("Menu")

Edited November 5, 2007 by BananaFredSoft

[JustinReno]

Oh, interesting. Thats a hard question..

[MrCreatoR]

Hi,

Try this:

#include <GuiConstants.au3>

Global Const $WM_ENTERMENULOOP = 0x0211
Global Const $WM_EXITMENULOOP = 0x0212

$Gui = GuiCreate("Test")

$Main_Menu = GUICtrlCreateMenu("Test")
GUICtrlCreateMenuItem("Item", $Main_Menu)

GUIRegisterMsg($WM_ENTERMENULOOP, "WM_ENTERMENULOOP")
GUIRegisterMsg($WM_EXITMENULOOP, "WM_EXITMENULOOP")

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
    EndSwitch
WEnd

Func WM_ENTERMENULOOP()
    ConsoleWrite("Menu Open")
EndFunc

Func WM_EXITMENULOOP()
    ConsoleWrite("Menu Closed")
EndFunc

[JustinReno]

Woah, how did you find those constants?

[JustinReno]

Oh, never mind, found them. Thats cool.

[MrCreatoR]

Or here is more advanced example:

expandcollapse popup

#include <GuiConstants.au3>

Global Const $WM_ENTERMENULOOP = 0x0211
Global Const $WM_EXITMENULOOP = 0x0212
Global Const $WM_MENUSELECT = 0x011F

$Gui = GuiCreate("Menu Handler Demo")
GUIRegisterMsg($WM_ENTERMENULOOP, "MENU_HANDLER")
GUIRegisterMsg($WM_EXITMENULOOP, "MENU_HANDLER")
GUIRegisterMsg($WM_MENUSELECT, "MENU_HANDLER")

$Main_Menu = GUICtrlCreateMenu("Test")
GUICtrlCreateMenuItem("Item 1", $Main_Menu)
GUICtrlCreateMenuItem("Item 2", $Main_Menu)
GUICtrlCreateMenuItem("Item 3", $Main_Menu)

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
    EndSwitch
WEnd

Func MENU_HANDLER($hWndGUI, $MsgID, $WParam, $LParam)
    Local $iItemID = BitAND($WParam, 0xFFFF)
    Local $iPrint_Data = ""
    
    Switch $MsgID
        Case $WM_ENTERMENULOOP
            $iPrint_Data = "Menu Open"
        Case $WM_EXITMENULOOP
            $iPrint_Data = "Menu Closed"
        Case $WM_MENUSELECT
            If $iItemID = 0 Then Return $GUI_RUNDEFMSG
            $iPrint_Data = "Menu Item Last Hovered: " & GUICtrlRead($iItemID, 1)
    EndSwitch
    
    PrintF($iPrint_Data)
    Return $GUI_RUNDEFMSG
EndFunc

Func PrintF($Str, $Line=@ScriptLineNumber)
    ConsoleWrite(@LF & "+======================================================" & @LF & _
                "--> Script Line (" & $Line & "):" & @LF & "!" & @TAB & $Str & @LF & _
                "+======================================================")
EndFunc

[JustinReno]

Thats cool.

[BananaFredSoft]

Thanks!