Display Msgbox but continue the script.

[ejbmail]

I need HELP on how to display a message box but the script will continue to finish with the message box still remaining on the Remote PC. I can not use a time out function because I want to leave the message box for the user to reboot when he can.

[Monamo]

  ejbmail said:

I need HELP on how to display a message box but the script will continue to finish with the message box still remaining on the Remote PC. I can not use a time out function because I want to leave the message box for the user to reboot when he can.

I believe what you're looking for is /AutoIt3ExecuteLine (check for it in the help file under "Search")

Here's an example:

#include <GUIConstants.au3>
GUICreate("Background process",500,500)
GUICtrlCreateLabel("Counter:",10,10,50,20)
$counter = GUICtrlCreateLabel("",10,25,50,20)

$start = 1
$stop = 10
GUICtrlSetData($counter,$start)
GUISetState()
While 1
    Do
    Sleep (1000)
    GUICtrlSetData($counter,GUICtrlRead($counter)+1)
    If GUICtrlRead($counter) = 3 Then
        Run(@AutoItExe & ' /AutoIt3ExecuteLine  "MsgBox(0, ''Notice:'', ''Note that the counter in the background GUI continues incrementing'')"')
    EndIf
Until GUICtrlRead($counter) = $stop
Exit
WEnd

[ejbmail]

A quick question.....

Do you mean that I should run my script exe with this run command or add this to my script as a command line for the message box.

  Monamo said:

I believe what you're looking for is /AutoIt3ExecuteLine (check for it in the help file under "Search")

Here's an example:

#include <GUIConstants.au3>
GUICreate("Background process",500,500)
GUICtrlCreateLabel("Counter:",10,10,50,20)
$counter = GUICtrlCreateLabel("",10,25,50,20)

$start = 1
$stop = 10
GUICtrlSetData($counter,$start)
GUISetState()
While 1
    Do
    Sleep (1000)
    GUICtrlSetData($counter,GUICtrlRead($counter)+1)
    If GUICtrlRead($counter) = 3 Then
        Run(@AutoItExe & ' /AutoIt3ExecuteLine  "MsgBox(0, ''Notice:'', ''Note that the counter in the background GUI continues incrementing'')"')
    EndIf
Until GUICtrlRead($counter) = $stop
Exit
WEnd

[weaponx]

This is the relevant part:

Run(@AutoItExe & ' /AutoIt3ExecuteLine  "MsgBox(0, ''Notice:'', ''Note that the counter in the background GUI continues incrementing'')"')

[ejbmail]

When I add this line into my script I receive this error:

Run(@AutoItExe & ' /AutoIt3ExecuteLine "MsgBox(4095, "Installation Completed", "**** Please reboot the PC ****")"')

  weaponx said:

This is the relevant part:

Run(@AutoItExe & ' /AutoIt3ExecuteLine  "MsgBox(0, ''Notice:'', ''Note that the counter in the background GUI continues incrementing'')"')

[Tlem]

This is the good way

Run(@AutoItExe & ' /AutoIt3ExecuteLine "MsgBox(4096, ''Installation Completed'', ''**** Please reboot the PC ****'')"')

[Valuater]

Maybe...

Run(@AutoItExe & ' /AutoIt3ExecuteLine  "If MsgBox(262209,''Ready to Re-Start'',''The Installation is completed and ready to re-start.     '' & @CRLF & @CRLF & ''Press OK to restart now.'' & @CRLF & @CRLF) = 1 Then Shutdown(6)"')

8)

[ejbmail]

That worked Great, Many thanks to all........

  Valuater said:

Maybe...

Run(@AutoItExe & ' /AutoIt3ExecuteLine  "If MsgBox(262209,''Ready to Re-Start'',''The Installation is completed and ready to re-start.     '' & @CRLF & @CRLF & ''Press OK to restart now.'' & @CRLF & @CRLF) = 1 Then Shutdown(6)"')

8)

[MrCreatoR]

This method is good for returning values:

$iCount = 0 ;Only for the example
AdlibEnable("SetData", 1000)

$iRet = _MsgBoxEx(36, "My Title", "Message")

MsgBox(64, "", "Returned Value is: " & $iRet)

Func SetData($sData)
    $iCount += 1
    ConsoleWrite("The script is not paused " & $iCount & " second(s)" & @LF)
EndFunc

Func _MsgBoxEx($iType, $sTitle, $sText, $iTimeOut=0)
    Local $sAu3Line = '"ConsoleWrite(MsgBox(' & $iType & ', ''' & $sTitle & ''', ''' &  $sText & ''', ' &  $iTimeOut & '))"'
    Local $iAu3PID = Run(@AutoItExe & ' /AutoIt3ExecuteLine ' & $sAu3Line, '', @SW_SHOW, 6)
    WinWait($sTitle, $sText)
    
    Local $iStdOutRead
    While ProcessExists($iAu3PID)
        $iStdOutRead = StdoutRead($iAu3PID, 5, True)
        If Number($iStdOutRead) Then Return $iStdOutRead
        Sleep(10)
    WEnd
    
    If Number($iStdOutRead) Then Return $iStdOutRead
    Return SetError(1, 0, -1)
EndFunc