IniToXML - how to?

[lsakizada]

How to convert INI file to XML file format.

Let say we have this INI:

[BSC1]
gatewayId=1
name=SiemensX25
[BSC2]
gatewayId=2
name=SiemnsTCPIP

How to convert it to:

<BSC1>
         <gatewayId>1</gatewayId>
         <name>SiemensX25</name>
</BSC1>
<BSC2>
         <gatewayId>2</gatewayId>
         <name>SiemnsTCPIP</name>
</BSC2>

Edited December 20, 2007 by lsakizada

[Monamo]

How to convert INI file to XML file format.

Let say we have this INI:

[BSC1]
gatewayId=1
name=SiemensX25
[BSC2]
gatewayId=2
name=SiemnsTCPIP

How to convert it to:

<BSC1>
         <gatewayId>1</gatewayId>
         <name>SiemensX25</name>
</BSC1>
<BSC2>
         <gatewayId>2</gatewayId>
         <name>SiemnsTCPIP</name>
</BSC2>

If that's the exact structure expected within the .INI files, personally, I'd just start with an IniReadSectionNames(). Then from that array, do a FileWriteLine() inside of a For... Next loop containing IniRead() based upon the results. There's also an XML UDF listed in the forums, but since it's already structured in an .INI file, I wouldn't make this one that complicated.

"Lightly" tested example:

CODE

$iniFile = @ScriptDir & "\convert.ini"

$xmlFile = @ScriptDir & "\convert.xml"

$writeFile = FileOpen($xmlFile,1)

$aNodes = IniReadSectionNames($iniFile)

For $i = 1 To $aNodes[0]

FileWriteLine($writeFile,"<" & $aNodes[$i] & ">")

FileWriteLine($writeFile," <gatewayID>" & IniRead($iniFile, $aNodes[$i],"gatewayID","") & "</gatewayID>")

FileWriteLine($writeFile," <name>" & IniRead($iniFile, $aNodes[$i],"name","") & "</name>")

FileWriteLine($writeFile,"</" & $aNodes[$i] & ">")

Next

FileClose($writeFile)

Edit: linked eltorro's "XML DOM wrapper" Edited December 20, 2007 by Monamo

[weaponx]

Thats exactly how I would do it. No external functions are needed unless you are reading back out or sorting in the same script.

[lsakizada]

If that's the exact structure expected within the .INI files, personally, I'd just start with an IniReadSectionNames(). Then from that array, do a FileWriteLine() inside of a For... Next loop containing IniRead() based upon the results. There's also an XML UDF listed in the forums, but since it's already structured in an .INI file, I wouldn't make this one that complicated.

"Lightly" tested example:

CODE

$iniFile = @ScriptDir & "\convert.ini"

$xmlFile = @ScriptDir & "\convert.xml"

$writeFile = FileOpen($xmlFile,1)

$aNodes = IniReadSectionNames($iniFile)

For $i = 1 To $aNodes[0]

FileWriteLine($writeFile,"<" & $aNodes[$i] & ">")

FileWriteLine($writeFile," <gatewayID>" & IniRead($iniFile, $aNodes[$i],"gatewayID","") & "</gatewayID>")

FileWriteLine($writeFile," <name>" & IniRead($iniFile, $aNodes[$i],"name","") & "</name>")

FileWriteLine($writeFile,"</" & $aNodes[$i] & ">")

Next

FileClose($writeFile)

Edit: linked eltorro's "XML DOM wrapper"

What amazing quick response!

Thank you guys, that's realy simple code and usefull that would help me much.

Thats exactly how I would do it. No external functions are needed unless you are reading back out or sorting in the same script.

Thanks to you too

[james3mg]

a bit belated to help you specifically on this problem, but in case you want to do this with ANY (valid) .ini file (not just those with only gatewayID and name in each section):

Global $iniFile=FileOpenDialog("Please select an .ini file:","","ini files (*.ini)",3)
If @error Then Exit
If NOT FileExists($iniFile) Then ExitMsg(".ini file not found!")
Global $xmlFile=FileSaveDialog("Save XML as:","","xml files (*.xml)",18)
If @error Then Exit
If NOT StringInStr(StringTrimLeft($xmlFile,StringInStr($xmlFile,"\",0,-1)),".") Then $xmlFile&=".xml"
$xmlFile=FileOpen($xmlFile,2)
If @error Then ExitMsg("There was a problem saving the XML file")

Global $iniSections=IniReadSectionNames($iniFile)
If @error Then ExitMsg("There was a problem reading the ini file's sections")
For $sectionName=1 To $iniSections[0]
    FileWriteLine($xmlFile,"<"&$iniSections[$sectionName]&">")
    Dim $sectionEntries=IniReadSection($iniFile,$iniSections[$sectionName])
    If NOT @error Then
        For $keyName=1 To $sectionEntries[0][0]
            FileWriteLine($xmlFile,@TAB&"<"&$sectionEntries[$keyName][0]&">"&$sectionEntries[$keyName][1]&"</"&$sectionEntries[$keyName][0]&">")
        Next
    EndIf
    FileWriteLine($xmlFile,"</"&$iniSections[$sectionName]&">")
Next
FileClose($xmlFile)
MsgBox(0,"Done","Conversion completed successfully")

Func ExitMsg($_ExitMsg)
    MsgBox(16,"Error",$_ExitMsg&@CRLF&@CRLF&"Exiting now.")
    Exit
EndFunc