How to save file via TCP?

[MrCreatoR]

Hi all,

I am trying to get source of some file, and save it to hard drive, but it seems that i need some sort of converting (to/from binary?)...

Here is what i am trying:

expandcollapse popup

Global Const $HTTPUSERAGENT = "Mozilla/5.0 (Windows; U; Windows NT 5.1; en-US; rv:1.8.1) Gecko/20061010 Firefox/2.0"
Global Const $HTTP_TCP_PORT = 80

$sFileContent = _HTTPGetSource("creator-lab.ucoz.ru", "/avatar/Scorpion_animated_64X64.gif")
$sFileContent = StringStripWS(StringTrimLeft($sFileContent, StringInStr($sFileContent, @CRLF & @CRLF)), 1)

$hFile = FileOpen(@ScriptDir & "\Scorpion_animated_64X64.gif", 2)
FileWrite($hFile, $sFileContent)
FileClose($hFile)

Func _HTTPGetSource($sHost, $sPage)
    Local $sRecv = '', $sCurrentLine
    Local $iSocket = _HTTPConnect($sHost)
    
    _HTTPGet($sHost, $sPage, $iSocket)
    If @error Then Return SetError(1, 0, '')
    
    While 1
        $sCurrentLine = TCPRecv($iSocket, 1024)
        If @error <> 0 Then ExitLoop
        If $sCurrentLine <> '' Then $sRecv &= $sCurrentLine
    WEnd
    
    TCPCloseSocket($iSocket)
    TCPShutdown()
    
    Return $sRecv
EndFunc

Func _HTTPConnect($sHost)
    TCPStartup()
    
    Local $sName_To_IP = TCPNameToIP($sHost)
    Local $iSocket = TCPConnect($sName_To_IP, $HTTP_TCP_PORT)
    
    If $iSocket = -1 Then
        TCPCloseSocket($iSocket)
        Return SetError(1, 0, "")
    EndIf
    
    Return $iSocket
EndFunc

Func _HTTPGet($sHost, $sPage, $iSocket)
    Local $sCommand = "GET " & $sPage & " HTTP/1.1" & @CRLF
    $sCommand &= "Host: " & $sHost & @CRLF
    $sCommand &= "User-Agent: " & $HTTPUSERAGENT & @CRLF
    $sCommand &= "Connection: close" & @CRLF & @CRLF
    
    Local $iBytesSent = TCPSend($iSocket, $sCommand)
    If $iBytesSent = 0 Then Return SetError(1, @error, 0)
    Return $iBytesSent
EndFunc

If i do the same with text file, all ok, the file include correct data, but with files such as images/executables, i get unworking file.

And also i wondernig, is there a way to get source without the header? i mean using TCP...

P.S

And where i can read about "commands" (data parameter) that can be sent via TCPSend?

Thanks.

[The Kandie Man]

Took me a while to get it to work because the _HexToString function continued to error out and return an incorrect value. It turns out, the hex string has 9 "0x" prefixes located in the hex string in what seems to be random locations for absolutely no apparent reason other than to throw an error in the _HexToString function. I say this because there should only be a "0x" prefix at the very beginning of the hex string. After finding this, I had the hex string completely stripped of all "0x" prefixes. I don't know what the other 8 prefixes were doing in the middle of the hex string, but they were there.

In addition to that, you also need to open the file for binary write using the 2+16 flag. 2 for erase previous contents file write and 16 for binary mode.

expandcollapse popup

#include <String.au3>
Global Const $HTTPUSERAGENT = "Mozilla/5.0 (Windows; U; Windows NT 5.1; en-US; rv:1.8.1) Gecko/20061010 Firefox/2.0"
Global Const $HTTP_TCP_PORT = 80

$sFileContent = _HTTPGetSource("creator-lab.ucoz.ru", "/avatar/Scorpion_animated_64X64.gif")
$sFileContent = StringStripWS(StringTrimLeft($sFileContent, StringInStr($sFileContent, @CRLF & @CRLF)), 1)

$sFileContent = StringReplace($sFileContent,"0x","");Remove all the 0x hex prefixes from the string
ConsoleWrite("Number of replacements="&@extended&@LF);Report how many prefixes were removed from the string

$hFile = FileOpen(@ScriptDir & "\Scorpion_animated_64X64.gif", 2 + 16); Open for erase previous contents writing and binary
FileWrite($hFile, _HexToString($sFileContent));Convert the hex to a string and then write it to file
FileClose($hFile)

Func _HTTPGetSource($sHost, $sPage)
    Local $sRecv = '', $sCurrentLine
    Local $iSocket = _HTTPConnect($sHost)
   
    _HTTPGet($sHost, $sPage, $iSocket)
    If @error Then Return SetError(1, 0, '')
   
    While 1
        $sCurrentLine = TCPRecv($iSocket, 1024)
        If @error <> 0 Then ExitLoop
        If $sCurrentLine <> '' Then $sRecv &= $sCurrentLine
    WEnd
   
    TCPCloseSocket($iSocket)
    TCPShutdown()
   
    Return $sRecv
EndFunc

Func _HTTPConnect($sHost)
    TCPStartup()
   
    Local $sName_To_IP = TCPNameToIP($sHost)
    Local $iSocket = TCPConnect($sName_To_IP, $HTTP_TCP_PORT)
   
    If $iSocket = -1 Then
        TCPCloseSocket($iSocket)
        Return SetError(1, 0, "")
    EndIf
   
    Return $iSocket
EndFunc

Func _HTTPGet($sHost, $sPage, $iSocket)
    Local $sCommand = "GET " & $sPage & " HTTP/1.1" & @CRLF
    $sCommand &= "Host: " & $sHost & @CRLF
    $sCommand &= "User-Agent: " & $HTTPUSERAGENT & @CRLF
    $sCommand &= "Connection: close" & @CRLF & @CRLF
   
    Local $iBytesSent = TCPSend($iSocket, $sCommand)
    If $iBytesSent = 0 Then Return SetError(1, @error, 0)
    Return $iBytesSent
EndFunc

Once those changes were made, the image was written to the file successfully.

- The Kandie Man ;-)

[MrCreatoR]

It works! thanks!

But with executable still not working ... here is what i am testing:

http://creator-lab.ucoz.ru/Testing_Zone/Tester_Exe.exe

http://creator-lab.ucoz.ru/Testing_Zone/Tester_zip.zip

http://creator-lab.ucoz.ru/Testing_Zone/Tester_au3.au3

Only zip file is saved correctly, exe and au3 include incorrect data...

I think there is need to find a universal way to convert... but i have no idea in what direction i need to search

[ptrex]

@all

An other handy way to deal with this is to use the "stream" object, for reading and writing binary format.

$inStream=ObjCreate("ADODB.Stream")

Regards

ptrex

[slaughter]

Look here http://www.autoitscript.com/forum/index.php?showtopic=54601