text file to unicode file

[erezlevi]

hi,

can anyone help we with converting a txt file from ANSI to UNICODE, what is the method on doing this ?

[PsaltyDS]

hi,

can anyone help we with converting a txt file from ANSI to UNICODE, what is the method on doing this ?

It's very deep and complicated, but if you want to wade into it:

$sFileA = "C:\Temp\ANSI_Test.txt"
$sFileU = "C:\Temp\UTF_Test.txt"
$hFile = FileOpen($sFileU, 2 + 32) ; 2 = overwrite, 32 = UTF16 Little Endian 
FileWrite($hFile, FileRead($sFileA))
FileClose($hFile)
MsgBox(64, "Done", "Ta Da!!!")

[dleigh]

Related/similar problem (yes I know this is an old thread, but perhaps putting them together makes sense for the next guy/gal searching):

I have a file that is produced with the DOS "sort" command and it's in codepage 850. No FileOpen choice seems to read it correctly. Does AutoIt have a way to deal with this or does someone else know a way to deal with either getting DOS (Windows 7 in this case) to output it differently or to convert it afterwards?

Thank you!

[Jury]

dleigh,

perhaps this will help:

or lok at this:

http://waterlan.home.xs4all.nl/dos2unix/dos2unix_beta.htm#conversion_modes

it has: Convert from DOS CP850 to Unix Latin-1

opensource: http://sourceforge.net/projects/dos2unix/

Edited April 15, 2012 by Jury

[jchd]

Can you try this and report success/failure?

; read old DOS CP850 file
Local $hdl = FileOpen("Dos850.txt", 16)  ; read in binary mode
Local $binText850 = FileRead($hdl)
FileClose($hdl)
Local $text = __CodepageStructToString($binText850)
; from there, $text is a genuine copy of the Dos file, but now using native AutoIt Unicode encoding.
ConsoleWrite($text & @LF)

Func __CodepageStructToString($tText)
Local $aResult = DllCall("kernel32.dll", "int", "MultiByteToWideChar", "uint", 850, "dword", 0, "struct*", $tText, "int", -1, _
   "ptr", 0, "int", 0)
If @error Then Return SetError(1, @error, "") ; Dllcall error
Local $tWstr = DllStructCreate("wchar[" & $aResult[0] & "]")
$aResult = DllCall("Kernel32.dll", "int", "MultiByteToWideChar", "uint", 850, "dword", 0, "struct*", $tText, "int", -1, _
   "struct*", $tWstr, "int", $aResult[0])
If @error Then Return SetError(2, @error, "") ; Dllcall error
Return DllStructGetData($tWstr, 1)
EndFunc

Edit: I saw the previous post after sending mine. My ad hoc function is equivalent to the WinAPI call.

Edited April 15, 2012 by jchd