Winsettrans on all open windows

[lafafmentvotre]

Hello

Is it possible to do a "winsetrans" for all active windows during the time of my autoit script like.

I see the same when i change the theme of my windows XP.

I test with winsettrans but i want this effect on all windows opened in the computer (relly like change themes on windows) during my gui is open.

Is it possible with autoit ?

Thanks for help and sorry for my bad english

[PsaltyDS]

Just for giggles:

expandcollapse popup

#include <array.au3>

; List visible windows
Global $avWinList = WinList()
Global $avVisibleList[1] = [0]
For $w = 1 To $avWinList[0][0]
    If BitAND(WinGetState($avWinList[$w][1]), 2) Then _ArrayAdd($avVisibleList, $avWinList[$w][1])
Next
$avVisibleList[0] = UBound($avVisibleList) - 1

HotKeySet("{ESC}", "_Quit")

; Fade them in and out
Global $iFadeStart = 254, $iFadeEnd = 0, $iStep = -10
While 1
    ; Fade all windows in/out
    For $f = $iFadeStart To $iFadeEnd Step $iStep
        For $w = 1 To $avVisibleList[0]
            WinSetTrans($avVisibleList[$w], "", $f)
        Next
    Next
    ; Toggle the fade
    If $iStep = -10 Then
        $iFadeStart = 1
        $iFadeEnd = 255
        $iStep = 10
    Else
        $iFadeStart = 254
        $iFadeEnd = 0
        $iStep = -10
    EndIf
WEnd

Func _Quit()
    For $w = 1 To $avVisibleList[0]
        WinSetTrans($avVisibleList[$w], "", 255)
    Next
    Exit
EndFunc   ;==>_Quit