updown with step *2 increment

[phil11]

Hi,

is it possible to increment a updown control with *2 ; /2 ?

with setting limits For 2 To 64

2 , 4 , 8 , 16 , 32 , 64

or maybe some other control to use ?

Thank you

[MrCreatoR]

Hi,

I am not sure if there is a simple way to limit like that, but you can check the events of UpDown control, and set input data as you need... something like that:

#include <GuiConstants.au3>

Global $Last_Value = 2

$GUI = GUICreate("Test Script", 300, 200)

$Input = GUICtrlCreateInput(2, 20, 40, 80, 20, $ES_NUMBER+$ES_READONLY)
GUICtrlSetBkColor(-1, 0xFFFFFF)

$UpDown = GUICtrlCreateUpdown($Input)
GUICtrlSetLimit($UpDown, 64, 2)

GUISetState(@SW_SHOW, $GUI)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $UpDown
            Local $Input_Value = Number(GUICtrlRead($Input))
            
            If $Input_Value > $Last_Value Then
                $Last_Value = ($Input_Value - 1) * 2
            ElseIf $Input_Value < $Last_Value Then
                $Last_Value = ($Input_Value + 1) / 2
            EndIf
            
            GUICtrlSetData($Input, $Last_Value)
    EndSwitch
WEnd

[Swift]

@MS_CReator...ehh...that doubles it....so if you up 2...it goes to 4...then 8...16....32...64...and stops.

Edit: fixed it!

#include <GuiConstants.au3>

Global $Last_Value = 2

$GUI = GUICreate("Test Script", 300, 200)

$Input = GUICtrlCreateInput(2, 20, 40, 80, 20, $ES_NUMBER+$ES_READONLY)
GUICtrlSetBkColor(-1, 0xFFFFFF)

$UpDown = GUICtrlCreateUpdown($Input)
GUICtrlSetLimit($UpDown, 64, 2)

GUISetState(@SW_SHOW, $GUI)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $UpDown
            Local $Input_Value = Number(GUICtrlRead($Input))
            
            If $Input_Value > $Last_Value Then
                $Last_Value = ($Input_Value - 1) + 2
            ElseIf $Input_Value < $Last_Value Then
                $Last_Value = ($Input_Value + 1) - 2
            EndIf
            
            GUICtrlSetData($Input, $Last_Value)
    EndSwitch
WEnd

Edited January 28, 2008 by Swift

[phil11]

thanks for help

works great with *2 /2

[MrCreatoR]

@Swift

that doubles it....so if you up 2...it goes to 4...then 8...16....32...64...and stops

Thats exactly what phil11 asked.

thanks for help

works great with *2 /2

Your wellcome!