WS_POPUP style - How to move the window?

[nf67]

Hello there,

I've created a very simple script that works like a live subtitle bar when I record my desktop.

So I just record and type my comment on what I'm doing in the bar ( which is basically a strechted inputbox ).

Because I only record 660x440 pixels I'd rather not waste any space, so I used the WS_POPUP style to remove the window-borders....

but now I can't seem to move the window..? What can I do?

My script

#include <GUIConstants.au3>

#Region ### START Koda GUI section ### Form=
$commentpile = GUICreate("commentpile", 650, 22, 193, 125, $WS_POPUP)
$zooi = GUICtrlCreateInput("zooi", 0, 0, 649, 21)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Thank you,

Chris

[MrCreatoR]

Hi, try this:

#include <GuiConstants.au3>

Global Const $WM_LBUTTONDOWN = 0x0201

$HWnd = GUICreate("DRAG GUI", 240, 180, -1, -1, $WS_POPUP+$WS_BORDER)
GUIRegisterMsg($WM_LBUTTONDOWN, "WM_LBUTTONDOWN")

GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func WM_LBUTTONDOWN($hWnd, $iMsg, $wParam, $lParam)
    If BitAND(WinGetState($hWnd), 32) Then Return $GUI_RUNDEFMSG
    DllCall("user32.dll", "long", "SendMessage", "hwnd", $hWnd, "int", $WM_SYSCOMMAND, "int", 0xF009, "int", 0)
EndFunc

[MrCreatoR]

but now I can't seem to move the window..? What can I do?

Well, you can not move the window only draging the input - you will need some kind of static control to move the parent...

#include <GuiConstants.au3>

#Region ### START Koda GUI section ### Form=
$commentpile = GUICreate("commentpile", 650, 32, 193, 125, $WS_POPUP+$WS_BORDER)

GUICtrlCreateLabel("Custom Title", 0, 0, 650, -1, $ES_CENTER, $GUI_WS_EX_PARENTDRAG)
GUICtrlSetFont(-1, 7)

$zooi = GUICtrlCreateInput("zooi", 0, 10, 649, 21)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

[nf67]

Love it! Just what I was looking for Thanks a lot

[slayerz]

Love it! Just what I was looking for Thanks a lot

@MsCreator

Thanks for the solution, this is what I'm looking for...

[rasim]

More examples:

#include <GuiConstants.au3>

;Global Const $HTCLIENT = 0x1
;Global Const $HTCAPTION = 0x2

$hGui = GUICreate("Test", 300, 200, -1, -1, $WS_POPUP + $WS_BORDER)

GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")

GUISetState()

Do
Until GUIGetMsg() = -3

Func WM_NCHITTEST($hWnd, $Msg, $wParam, $lParam)
    Local $iProc
    
    $iProc = DllCall("user32.dll", "int", "DefWindowProc", "hwnd", $hWnd, "int", $Msg, "wparam", $wParam, "lparam", $lParam)
    $iProc = $iProc[0]
    
    If $iProc = $HTCLIENT Then Return $HTCAPTION
    
    Return $GUI_RUNDEFMSG
EndFunc

Edited March 16, 2008 by rasim

[Zedna]

Another one:

#include <GuiConstants.au3>

Opt("GUICloseOnESC",1)
Opt("GUIOnEventMode",1)

$hGui = GUICreate("Test", 300, 200, -1, -1, $WS_POPUP + $WS_BORDER)
GUISetOnEvent ($GUI_EVENT_PRIMARYDOWN, "Drag" )
GUISetState()

While 1
      Sleep(10)
WEnd

Func Drag()
      dllcall("user32.dll","int","SendMessage","hWnd", $hGui,"int",$WM_NCLBUTTONDOWN,"int", $HTCAPTION,"int", 0)
EndFunc

[rover]

this thread is timely, so this is as good a place as any.

I noticed several days ago that the WM_NCHITTEST method of moving a Gui by it's form

no longer works in beta v3.2.11.1 and 3.2.11.2

use the WM_NCLBUTTONDOWN method

was working up to v3.2.10.0 (tested on 3.2.8.1 and 3.2.10.0)

tested on 2 machines running XP SP2 EN X86

AutoIt: beta v3.2.11.1 and v3.2.11.2

SciTE4AutoIt3: 8-3-2008

Edit: typos

test in beta

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
$hGui = GUICreate("Test", 300, 200, -1, -1)
GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")
GUISetState()

Do
    $msg = GUIGetMsg()
Until  $msg = -3

Func WM_NCHITTEST($hWnd, $Msg, $wParam, $lParam)
    Local $iProc
    $iProc = DllCall("user32.dll", "int", "DefWindowProc", _
    "hwnd", $hWnd, "int", $Msg, "int", $wParam, "int", $lParam)
    If @error Then SetError(@error, 0, 0)
    $iProc = $iProc[0]
    If $iProc = $HTCLIENT Then Return $HTCAPTION
    Return $GUI_RUNDEFMSG
EndFunc

Edited March 18, 2008 by rover

[ResNullius]

this thread is timely, so this is as good a place as any.

I noticed several days ago that the WM_NCHITTEST method of moving a Gui by it's form

no longer works in beta v3.2.11.1 and 3.2.11.2

use the WM_NCLBUTTONDOWN method

was working up to v3.2.10.0 (tested on 3.2.8.1 and 3.2.10.0)

tested on 2 machines running XP SP2 EN X86

AutoIt: beta v3.2.11.1 and v3.2.11.2

SciTE4AutoIt3: 8-3-2008

Edit: typos

test in beta

Verified also with beta 3.2.11.3, XP PRO SP2 EN x86

Time for a bug report?