Echo input to a label

[c.haslam]

I have an input box and a label (and lots of other stuff too). As the user types in the input box, I want the text to appear as the label caption. I suspect that the answer lies somewhere in:

• Using a combo box rather than an input box
• When creating the combo box, making the style $CBS_NOINTEGRALHEIGHT
• GUIRegisterMsg($WM_COMMAND, "WM_COMMAND") and writing a WM_COMMAND function
• calling _GUICtrlComboBox_GedEditText() to retrieve the entered text

but so far I am getting nowhere. Any suggestions?

...chris

[rasim]

Hi! Try this example:

#include <GuiConstants.au3>

$hGui = GuiCreate("Test GUI", 300, 180)

$hLabel = GUICtrlCreateLabel("", 50, 10, 200, 16)
GUICtrlSetBkColor(-1, 0xC0C0C0)

$hInput = GUICtrlCreateInput("", 50, 50, 200, 16)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $IdFrom, $iCode
    
    $IdFrom = BitAND($wParam, 0xFFFF)
    $iCode = BitShift($wParam, 16)
    
    Switch $IdFrom
    Case $hInput
        Switch $iCode
        Case $EN_UPDATE
            GUICtrlSetData($hLabel, GUICtrlRead($hInput))
        EndSwitch
    EndSwitch
    
    Return $GUI_RUNDEFMSG
EndFunc ;==>WM_COMMAND

[rasim]

I have an input box and a label (and lots of other stuff too). As the user types in the input box, I want the text to appear as the label caption. I suspect that the answer lies somewhere in:

• Using a combo box rather than an input box
• When creating the combo box, making the style $CBS_NOINTEGRALHEIGHT
• GUIRegisterMsg($WM_COMMAND, "WM_COMMAND") and writing a WM_COMMAND function
• calling _GUICtrlComboBox_GedEditText() to retrieve the entered text

but so far I am getting nowhere. Any suggestions?

...chris

Example:

#include <GuiConstantsEx.au3>
#include <GuiComboBox.au3>

$hGui = GuiCreate("Test GUI", 300, 180)

$hLabel = GUICtrlCreateLabel("", 50, 10, 200, 16)
GUICtrlSetBkColor(-1, 0xC0C0C0)

$hCombo = _GUICtrlComboBox_Create($hGui, "Combo", 50, 50, 200, 16, $CBS_NOINTEGRALHEIGHT)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $hWndFrom, $iCode, $iText
    
    $hWndFrom = $lParam
    $iCode = BitShift($wParam, 16)
    
    Switch $hWndFrom
    Case $hCombo
        Switch $iCode
        Case $CBN_EDITUPDATE
            $iText = _GUICtrlComboBox_GetEditText($hCombo)
            GUICtrlSetData($hLabel, $iText)
        EndSwitch
    EndSwitch
    
    Return $GUI_RUNDEFMSG
EndFunc ;==>WM_COMMAND

[GEOSoft]

Here is another simple one

$hGui = GuiCreate("Test GUI", 300, 180)

$hLabel = GUICtrlCreateLabel("", 50, 10, 200, 16)
GUICtrlSetBkColor(-1, 0xC0C0C0)

$hInput = GUICtrlCreateInput("", 50, 50, 200, 16)
GUISetState()
While 1
   $Msg = GUIGetMsg()
   If $Msg = -3 Then Exit
  ;; Check the contents before making changes to the label to avoid flickering
   If GUICtrlRead($hInput) <> GUICtrlRead($hLabel) Then GUICtrlSetData($hLabel, GUICtrlRead($hInput))
Wend

[c.haslam]

Many thanks to all of you for the help. I chose the simplest solution, and it works AOK.

...chris