Sign in to follow this  
Followers 0
Emiel Wieldraaijer

TrayTip Problem

12 posts in this topic

Hi,

I was playing around with a fantastic script "Secure Delete" from MrBond007

and i thought why not add the progress to the tray while washing a drive

so i added the following code in the loop -> TrayTip("Progress", $String1 & " " & Round($spaceu2 / $calc * 100, 2) & " %", 1, 16) so the tray is updated..

- Tested it on Windows XP -> OK

- Tested it on Windows Vista -> OK

- Tested it on Windows 2000 -> Does not update

Is this a bug or is this the wrong way to update the traytip

;========================================================================================
; Description:      AU3-SD
; Author(s):        MrBond007
; Comments:            Kills sensitive data and makes it unrecoverable
;
;                    Credits also goes to the authors of GuiListView.au3 and File.au3
;                    Remember if you like AutoIt Donate to the AutoIt Project:
;                    http://www.autoitscript.com/donate.php
;========================================================================================
#include <GUIConstants.au3>
#include <GuiListView.au3>
#include <File.au3>
#RequireAdmin
Opt("TrayIconHide", 0)

GLobal $fop, $m, $i, $s, $r, $ra1, $ra2, $ra3, $contain, $siz, $tHandle, $Button[8], $gChr, $split
Global $WM_DROPFILES = 0x233
Global $gaDropFiles[1]

If StringInStr(@AutoItVersion, "3.2.2.") Or StringInStr(@AutoItVersion, "3.2.1.") Or StringInStr(@AutoItVersion, "3.1.") Then
    $tHandle = "2"
Else
    $tHandle = "18"
EndIf
$HomeDrive = @HomeDrive
If StringRight($HomeDrive, 1) == "\" Then $HomeDrive = StringLeft($HomeDrive, 2)
If $HomeDrive = "" Then $HomeDrive = StringLeft(@WindowsDir, 2)

HotKeySet("!x", "_Close")

$version = "AU3-SD [ One Fast File Shredder ]"
If WinExists($version) Then Exit
AutoItWinSetTitle($version)

$Gui_handle = GUICreate("AU3-SD [ One Fast File Shredder ]", 445, 450, -1, -1, -1, $WS_EX_ACCEPTFILES)
GUICtrlCreateGroup("Choose the File(s) + The Deletion Method", 5, 2, 435, 240)
GUICtrlSetBkColor(-1, 0x20B7FF)

$List_V = GUICtrlCreateListView("Name | Size", 10, 20, 325, 180)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
GUICtrlSendMsg($List_V, $LVM_SETEXTENDEDLISTVIEWSTYLE, $LVS_EX_GRIDLINES, $LVS_EX_GRIDLINES)
_GUICtrlListView_SetColumnWidth($List_V, 0, 240)
_GUICtrlListView_SetColumnWidth($List_V, 1, 60)
$List_handle = ControlGetHandle($gui_handle, "", $list_V)

$Button[0] = GUICtrlCreateButton("Choose", 340, 20, 95, 25)
$Button[1] = GUICtrlCreateButton("Remove From List", 340, 58, 95, 25)
$Button[2] = GUICtrlCreateButton("Remove All", 340, 97, 95, 25)
$Button[7] = GUICtrlCreateButton("Let's Rock", 340, 137, 95, 25)
$Button[3] = GUICtrlCreateButton("Clean Recycle Bin", 340, 175, 95, 25)

$Combo = GUICtrlCreateCombo("Zero", 10, 210, 150, 120, $CBS_DROPDOWNLIST)
GUICtrlSetData(-1, "Random Character")
GUICtrlSetData(-1, "Random-Chunk")

$inp2 = GUICtrlCreateInput("1", 170, 210, 40, 20, $ES_READONLY)
GUICtrlCreateLabel("X Loop Times", 215, 213, 80, 20)

$updown = GUICtrlSetLimit(GUICtrlCreateUpdown($inp2), 99, 1)
$Checkpl = GUICtrlCreateCheckbox("Scramble File Attributes", 305, 210)
GUICtrlCreateGroup("Wash Disk Empty Space", 5, 245, 435, 175)
GUICtrlSetBkColor(-1, 0x20B7FF)

$list = GUICtrlCreateListView("Drive | Used Space | Free Space | Type", 10, 265, 425, 95)
GUICtrlSendMsg($list, $LVM_SETEXTENDEDLISTVIEWSTYLE, $LVS_EX_GRIDLINES, $LVS_EX_GRIDLINES)
GUICtrlSendMsg($list, $LVM_SETEXTENDEDLISTVIEWSTYLE, $LVS_EX_CHECKBOXES, $LVS_EX_CHECKBOXES)
_GUICtrlListView_SetColumnWidth($list, 0, 100)
_GUICtrlListView_SetColumnWidth($list, 1, 125)
_GUICtrlListView_SetColumnWidth($list, 2, 125)
_GUICtrlListView_SetColumnWidth($list, 3, 70)
$List_hwnd = ControlGetHandle($gui_handle, "", $list)

$drives = DriveGetDrive("FIXED")
For $i = 1 To $drives[0]
    $totals = Round(DriveSpaceTotal($drives[$i]) / 1024, 1)
    $spacef = Round(DriveSpaceFree($drives[$i]) / 1024, 1)
    $spaceu = $totals - $spacef
    GUICtrlCreateListViewItem(StringUpper($drives[$i]) & "|" & $spaceu & " GB" & "|" & $spacef & " GB" & "|" & DriveGetFileSystem($drives[$i]), $list)
Next

$Button[4] = GUICtrlCreateButton("Wash", 175, 365, 100, 25)
$Checkp2 = GUICtrlCreateCheckbox("Shutdown PC when done washing", 10, 395)
$Button[5] = GUICtrlCreateButton("Exit", 335, 365, 100, 25)
$Button[6] = GUICtrlCreateButton("Refresh", 10, 365, 100, 25)
$prog = GUICtrlCreateProgress(6, 429, 250, 15)
$label = GUICtrlCreateLabel("", 115, 430, 35, 15)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$label2 = GUICtrlCreateLabel("", 300, 428, 150, 20)
$break = 1

GUISetState()
GUIRegisterMsg($WM_DROPFILES, "WM_DROPFILES_FUNC")

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $GUI_EVENT_DROPPED
            _FilesDropped()
        Case $msg = $Button[0]
            _Dialog()
        Case $msg = $Button[1]
            _GUICtrlListView_DeleteItemsSelected($List_handle)
        Case $msg = $Button[2]
            _GUICtrlListView_DeleteAllItems($List_handle)
        Case $msg = $Button[7]
            _StartShredding()
        Case $msg = $Button[3]
            _PrepareBin()
        Case $msg = $Button[4]
            ;hier
            Progress_On()
            _Wash()
            Progress_Off()
        Case $msg = $Button[5]
            _Close()
        Case $msg = $Button[6]
            _RefreshList()
    EndSelect
WEnd

Func _FilesDropped()
    For $i = 0 To UBound($gaDropFiles) - 1
        If StringInStr(FileGetAttrib($gaDropFiles[$i]), "D") Then
            ContinueLoop
        Else
            If _GUICtrlListView_FindText($List_V, $gaDropFiles[$i], -1, False, True) = -1 Then GUICtrlCreateListViewItem($gaDropFiles[$i] & "|" & Round(FileGetSize($gaDropFiles[$i]) / 1024, 2), $List_V)
        EndIf
    Next
EndFunc

Func _Dialog()
    $diag = FileOpenDialog("choose the file(s)", "", "(*.*)", 4)
    If $diag <> "" Then
        If StringInStr($diag, "|") > 0 Then
            $strip = StringSplit($diag, "|")
            For $i = 2 To $strip[0]
                If StringRight($strip[1], 1) == "\" Then
                    If _GUICtrlListView_FindText($List_V, $strip[1] & $strip[$i], -1, False, True) = -1 Then GUICtrlCreateListViewItem($strip[1] & $strip[$i] & "|" & Round(FileGetSize($strip[1] & $strip[$i]) / 1024, 1) & " KB", $List_V)
                Else
                    If _GUICtrlListView_FindText($List_V, $strip[1] & "\" & $strip[$i], -1, False, True) = -1 Then GUICtrlCreateListViewItem($strip[1] & "\" & $strip[$i] & "|" & Round(FileGetSize($strip[1] & "\" & $strip[$i]) / 1024, 1) & " KB", $List_V)
                EndIf
            Next
        Else
            If _GUICtrlListView_FindText($List_V, $diag, -1, False, True) = -1 Then GUICtrlCreateListViewItem($diag & "|" & Round(FileGetSize($diag) / 1024, 1) & "KB", $List_V)
        EndIf
    EndIf
EndFunc

Func _StartShredding()
    GUICtrlSetData($label, "")
    GUICtrlSetData($prog, 0)
    GUICtrlSetState($Button[4], $GUI_DISABLE)
    GUICtrlSetData($Button[7], "Stop")
    Progress_On()
    GetChr()

    $begin = TimerInit()
    Opt("GUIOnEventMode", 1)
    GUICtrlSetOnEvent($Button[7], "_Stpp")
    Local $loop = 0

    $oriG = _GUICtrlListView_GetItemCount($List_handle)
    If $oriG >= 1 Then
        For $z = 0 To _GUICtrlListView_GetItemCount($List_handle)
            If $oriG > 1 Then
                $loop += 1
                GUICtrlSetData($prog, $loop * 100 / $oriG)
                GUICtrlSetData($label, Round($loop * 100 / $oriG) & "%")
                GUICtrlSetData($label2, "Killing File " & $loop)
            EndIf
            $split = StringSplit(_GUICtrlListView_GetItemText($List_handle, $z), "|")
            If FileGetSize($split[1]) <= 1000 Then
                $siz = 1
            Else
                $siz = Round(FileGetSize($split[1]) / 1000)
            EndIf
            For $m = 1 To GUICtrlRead($inp2)
                If $oriG = 1 Then
                    GUICtrlSetData($prog, Round($m * 100 / GUICtrlRead($inp2)))
                    GUICtrlSetData($label, Round($m * 100 / GUICtrlRead($inp2)) & "%")
                    GUICtrlSetData($label2, "Killing File(s)")
                EndIf
                $fop = FileOpen($split[1], $tHandle)
                For $x = 1 To $siz
                    FileWrite($fop, $gChr)
                    If $break = 2 Then
                        FileClose($fop)
                        ExitLoop
                    EndIf
                Next
                FileClose($fop)
                If GUICtrlRead($Checkpl) = $GUI_CHECKED Then momo()
                If $break = 2 Then
                    $z = _GUICtrlListView_GetItemCount($List_handle) + 1
                    $m = 0
                    $break = 3
                    ExitLoop
                EndIf
                Next
                If $break = 1 Then
                    $split = StringSplit(_GUICtrlListView_GetItemText($List_handle, $z), "|")
                    FileDelete($split[1])
                    _GUICtrlListView_DeleteItem($List_handle, $z)
                    $z = $z - 1
                    If _GUICtrlListView_GetItemCount($List_handle) = 0 Then ExitLoop
                EndIf
            Next
        EndIf
    $break = 1
    Opt("GUIOnEventMode", 0)
    GUICtrlSetData($Button[7], "Let's Rock")
    $dif = Round(TimerDiff($begin) / 1000)
    GUICtrlSetData($label2, "Done In " & $dif & " seconds :)")
    Progress_Off()
EndFunc

Func GetChr()
    $gChr = ""
    $ReadComb = GUICtrlRead($Combo)
    If $ReadComb = "Zero" Then
        For $x = 0 To 1024
            $gChr = $gChr & Chr(48)
        Next
    ElseIf $ReadComb = "Random Character" Then
        $rChr = Random(0, 255, 1)
        For $x = 0 To 1024
            $gChr &= Chr($rChr)
        Next
    ElseIf $ReadComb = "Random-Chunk" Then
        $rChr = Random(0, 255, 1)
        For $x = 0 To 1024
            $gChr &= Chr(Random(0, 255, 1))
        Next
    EndIf
    Return $gChr
EndFunc

Func mom()
    $ra1 = Random(1960, 2070, 1)
    $ra2 = Random(1, 12, 1)
    $ra3 = Random(1, 31, 1)
    If $ra2 < 10 Then $ra2 = "0" & $ra2
    If $ra3 < 10 Then $ra3 = "0" & $ra3
EndFunc

Func momo()
    $o = 0
    $t = 0
    For $o = 0 To 20
        For $t = 0 To 2
            mom()
            FileSetTime($split[1], $ra1 & $ra2 & $ra3, $t)
        Next
    Next
EndFunc

Func _PrepareBin()
    Progress_On()
    If @OSVersion == "WIN_VISTA" Then
        If StringInStr(FileGetAttrib($HomeDrive & "\$RECYCLE.BIN"), "D") Then $contain = "\$RECYCLE.BIN"
    Else
        If StringInStr(FileGetAttrib($HomeDrive & "\recycler"), "D") Then
            $contain = "\recycler"
        ElseIf StringInStr(FileGetAttrib($HomeDrive & "\recycled"), "D") Then
            $contain = "\recycled"
        EndIf
    EndIf
    If $contain <> "" Then
        _ShredBin()
        Progress_Off()
    EndIf
EndFunc

Func _Wash()
    GUICtrlSetData($Button[4], "Stop Washing")
    GUICtrlSetState($Button[4], $GUI_ENABLE)
    GUICtrlSetState($Button[7], $GUI_DISABLE)
    If StringInStr(@AutoItVersion, "3.2.2.") Or StringInStr(@AutoItVersion, "3.2.1.") Or StringInStr(@AutoItVersion, "3.1.") Then
        $ver = "0"
    Else
        $ver = "16"
    EndIf
    $fname = "\temp"
    If @Compiled = 0 Then
        $fJunk = FileOpen(@AutoItExe, $ver)
    Else
        $fJunk = FileOpen(@ScriptFullPath, $ver)
    EndIf
    $readshot = FileRead($fJunk)
    GUICtrlSetData($label2, "Washing Drive")
    For $p = 0 To $drives[0] - 1
        $drvindx = _GUICtrlListView_GetItemChecked($List_hwnd, $p)
        If $drvindx = 1 Then
            $string1 = _GUICtrlListView_GetItemText($List_hwnd, $p);C: F:
            If DriveGetFileSystem($string1) = "FAT32" Then
                $fop = FileOpen($string1 & $fname & ".txt", $tHandle)
                $spaceu = Round(DriveSpaceTotal($string1), 1) - Round(DriveSpaceFree($string1), 1)
                $calc = Round(DriveSpaceFree($string1))
                Opt("GUIOnEventMode", 1)
                GUICtrlSetOnEvent($Button[4], "_Stpp")
                Local $rt = "", $yy = ""
                While Round(DriveSpaceFree($string1)) >= 10
                    $rt = $rt + 1
                    FileWrite($string1 & $fname & ".txt", $readshot)
                    If $rt = 8000 Then
                        $yy = $yy + 1
                        $fname &= $yy
                        $rt = ""
                    EndIf
                    If Round(DriveSpaceFree($string1)) >= 10 Then
                        $spaceu2 = (Round(DriveSpaceTotal($string1), 1) - Round(DriveSpaceFree($string1), 1)) - Round($spaceu)
                        GUICtrlSetData($prog, ($spaceu2 / $calc * 100))
                        GUICtrlSetData($label, Round($spaceu2 / $calc * 100, 2) & "%")
                        TrayTip("Progress", $String1 & " " & Round($spaceu2 / $calc * 100, 2) & " %", 1, 16)
                    Else
                        GUICtrlSetData($prog, 100)
                        GUICtrlSetData($label, "100%")
                        TrayTip("Progress", "100 %", 5)
                        ExitLoop
                    EndIf
                    If $break = 2 Then
                        $break = 1
                        GUICtrlSetData($label, "")
                        $p = $drives[0] + 1
                        ExitLoop
                    EndIf
                WEnd
                FileClose($fop)
                Opt("GUIOnEventMode", 0)
                _KillTemp()
            Else
                $fop = FileOpen($string1 & $fname & ".txt", $tHandle)
                $spaceu = Round(DriveSpaceTotal($string1), 1) - Round(DriveSpaceFree($string1), 1)
                $calc = Round(DriveSpaceFree($string1))
                Opt("GUIOnEventMode", 1)
                GUICtrlSetOnEvent($Button[4], "_Stpp")
                Local $rt = "", $yy = ""
                While Round(DriveSpaceFree($string1)) >= 10
                    FileWrite($string1 & $fname & ".txt", $readshot)
                    If Round(DriveSpaceFree($string1)) >= 10 Then
                        $spaceu2 = (Round(DriveSpaceTotal($string1), 1) - Round(DriveSpaceFree($string1), 1)) - Round($spaceu)
                        GUICtrlSetData($prog, ($spaceu2 / $calc * 100))
                        GUICtrlSetData($label, Round($spaceu2 / $calc * 100, 2) & "%")
                        TrayTip("Progress", $String1 & " " & Round($spaceu2 / $calc * 100, 2) & " %", 1, 16)
                    Else
                        GUICtrlSetData($prog, 100)
                        GUICtrlSetData($label, "100%")
                        TrayTip("Progress", "100 %", 5)
                        ExitLoop
                    EndIf
                    If $break = 2 Then
                        $break = 1
                        GUICtrlSetData($label, "")
                        $p = $drives[0] + 1
                        ExitLoop
                    EndIf
                WEnd
                FileClose($fop)
                Opt("GUIOnEventMode", 0)
                _KillTemp()
            EndIf
        EndIf
    Next
    FileClose($fJunk)
    GUICtrlSetData($label2, "")
    GUICtrlSetData($Button[4], "Wash")
    GUICtrlSetState($Button[7], $GUI_ENABLE)
    If GUICtrlRead($Checkp2) = $GUI_CHECKED And StringInStr(GUICtrlRead($label), "100%") Then
        Shutdown(9)
    Else
        GUICtrlSetData($label, "")
    EndIf
EndFunc

Func _KillTemp()
    For $p = 1 To $drives[0]
        FileDelete($drives[$p] & "\temp*.*")
    Next
EndFunc

Func _ShredBin()
    $begin = TimerInit()
    GUICtrlSetState($Button[7], $GUI_DISABLE)
    GUICtrlSetState($Button[4], $GUI_DISABLE)
    GUICtrlSetData($prog, 0)
    GUICtrlSetData($label2, "Shredding Recycle Bin")
    RunWait('"' & @ComSpec & '" /c dir /a /b /s "' & $HomeDrive & $contain & '"\*.* > temp.txt"', '', @SW_HIDE)
    For $i = 0 To _FileCountLines("temp.txt")
        $s = 0
        $t = 0
        Local $gChr = ""
        $sRead = FileReadLine("temp.txt", $i)
        If FileGetSize($sRead) <= 1000 Then
            $siz = 1
        Else
            $siz = Round(FileGetSize($sRead) / 1000)
        EndIf
        FileSetAttrib($sRead, "-RSH")
        $sOpen = FileOpen($sRead, $tHandle)
        For $x = 0 To 1024
            $gChr = $gChr & Chr(Random(0, 255, 1))
        Next
        For $s = 1 To Round($siz)
            FileWrite($sOpen, $gChr)
        Next
        FileClose($sOpen)
        GUICtrlSetData($prog, Round($i / _FileCountLines("temp.txt") * 100))
        GUICtrlSetData($label, Round($i / _FileCountLines("temp.txt") * 100) & "%")
    Next
    FileRecycleEmpty($HomeDrive)
    FileDelete("temp.txt")
    $dif = Round(TimerDiff($begin) / 1000)
    GUICtrlSetData($label2, "Done In " & $dif & " seconds :)")
    GUICtrlSetState($Button[7], $GUI_ENABLE)
    GUICtrlSetState($Button[4], $GUI_ENABLE)
EndFunc

Func Progress_On()
    For $i = 0 To UBound($Button)-2
        GUICtrlSetState($Button[$i], $GUI_DISABLE)
    Next
EndFunc

Func Progress_Off()
    For $i = 0 To UBound($Button)-1
        GUICtrlSetState($Button[$i], $GUI_ENABLE)
    Next
EndFunc

Func WM_DROPFILES_FUNC($hWnd, $msgID, $wParam, $lParam)
    Local $nSize, $pFileName
    Local $nAmt = DllCall("shell32.dll", "int", "DragQueryFile", "hwnd", $wParam, "int", 0xFFFFFFFF, "ptr", 0, "int", 255)
    For $i = 0 To $nAmt[0] - 1
        $nSize = DllCall("shell32.dll", "int", "DragQueryFile", "hwnd", $wParam, "int", $i, "ptr", 0, "int", 0)
        $nSize = $nSize[0] + 1
        $pFileName = DllStructCreate("char[" & $nSize & "]")
        DllCall("shell32.dll", "int", "DragQueryFile", "hwnd", $wParam, "int", $i, "ptr", DllStructGetPtr($pFileName), "int", $nSize)
        ReDim $gaDropFiles[$i + 1]
        $gaDropFiles[$i] = DllStructGetData($pFileName, 1)
        $pFileName = 0
    Next
EndFunc

Func _RefreshList()
    _GUICtrlListView_DeleteAllItems($List_hwnd)
    $drives = DriveGetDrive("Fixed")
    For $i = 1 To $drives[0]
        $totals = Round(DriveSpaceTotal($drives[$i]) / 1024, 1)
        $spacef = Round(DriveSpaceFree($drives[$i]) / 1024, 1)
        $spaceu = $totals - $spacef
        GUICtrlCreateListViewItem(StringUpper($drives[$i]) & "|" & $spaceu & " GB" & "|" & $spacef & " GB" & "|" & DriveGetFileSystem($drives[$i]), $list)
    Next
EndFunc

Func _Stpp()
    Opt("GUIOnEventMode", 0)
    $break = 2
EndFunc

Func _Close()
    If WinActive($version) Then
        FileClose($fop)
        _KillTemp()
        Exit
    EndIf
EndFunc

Thnx

Emiel


Best regards,Emiel Wieldraaijer

Share this post


Link to post
Share on other sites



Is AutoIt meant to run with Windows 2000? (That should answer your question)

Share this post


Link to post
Share on other sites

ehhh .. do you want me to give you a real anwser ??? or just ignore you

Off course AutoIt can be run on Windows 2000 if you look in the help for TrayTip

Remarks

TrayTip works for only Windows 2000/XP or better.


Best regards,Emiel Wieldraaijer

Share this post


Link to post
Share on other sites

ehhh .. do you want me to give you a real anwser ??? or just ignore you

Off course AutoIt can be run on Windows 2000 if you look in the help for TrayTip

AutoIt is not really meant to be ran on a 2000 enviorment. It works best on XP.

Share this post


Link to post
Share on other sites

#5 ·  Posted (edited)

AutoIt is not really meant to be ran on a 2000 enviorment. It works best on XP.

Where did you get that from?? I have never heard anything like that, even win 9x is supposed to work!! Edited by AdmiralAlkex

Share this post


Link to post
Share on other sites

AutoIt is not really meant to be ran on a 2000 enviorment. It works best on XP.

You don't know what you are talking about, again. Several of the people working with AutoIt do their developing on 2000 and TrayTip should behave the same for 2000 as it does for XP and Vista.

@AdmiralAlkex

MOST of AutoIt will (currently) work on the 9x platforms. There are exceptions and TrayTip is one of those.


George

Question about decompiling code? Read the decompiling FAQ and don't bother posting the question in the forums.

Be sure to read and follow the forum rules. -AKA the AutoIt Reading and Comprehension Skills test.***

The PCRE (Regular Expression) ToolKit for AutoIT - (Updated Oct 20, 2011 ver:3.0.1.13) - Please update your current version before filing any bug reports. The installer now includes both 32 and 64 bit versions. No change in version number.

Visit my Blog .. currently not active but it will soon be resplendent with news and views. Also please remove any links you may have to my website. it is soon to be closed and replaced with something else.

"Old age and treachery will always overcome youth and skill!"

Share this post


Link to post
Share on other sites

@AdmiralAlkex

MOST of AutoIt will (currently) work on the 9x platforms. There are exceptions and TrayTip is one of those.

My meaning was that 9x was supported generally as an answer to R6V2 ridiculous answer that AutoIt is built for XP.

Share this post


Link to post
Share on other sites

My meaning was that 9x was supported generally as an answer to R6V2 ridiculous answer that AutoIt is built for XP.

I thought that I read somewhere, that AutoIt worked best, and more effieciently, on XP.

Share this post


Link to post
Share on other sites

I thought that I read somewhere, that AutoIt worked best, and more effieciently, on XP.

IIRC a tremendous amount of AutoIt development was accomplished on systems using XP. Remember that not all the devs even had XP from it's first release. AutoIt v2 was developed primarily for 9x support. AutoIt 3 continued the 9x support and gradually added functions that were not available in 9x systems. There are also some of the functions that require a a certain (or newer) version of IE. Just check some of these things before you go making totaly false statements like you did in this thread.

George

Question about decompiling code? Read the decompiling FAQ and don't bother posting the question in the forums.

Be sure to read and follow the forum rules. -AKA the AutoIt Reading and Comprehension Skills test.***

The PCRE (Regular Expression) ToolKit for AutoIT - (Updated Oct 20, 2011 ver:3.0.1.13) - Please update your current version before filing any bug reports. The installer now includes both 32 and 64 bit versions. No change in version number.

Visit my Blog .. currently not active but it will soon be resplendent with news and views. Also please remove any links you may have to my website. it is soon to be closed and replaced with something else.

"Old age and treachery will always overcome youth and skill!"

Share this post


Link to post
Share on other sites

IIRC a tremendous amount of AutoIt development was accomplished on systems using XP. Remember that not all the devs even had XP from it's first release. AutoIt v2 was developed primarily for 9x support. AutoIt 3 continued the 9x support and gradually added functions that were not available in 9x systems. There are also some of the functions that require a a certain (or newer) version of IE. Just check some of these things before you go making totaly false statements like you did in this thread.

Sorry Geosoft, I thought I was correct on that. Anyhow, good luck on that traytip problem!

Share this post


Link to post
Share on other sites

R6V2, you and "thinking" do not go together. Every time you "think" you're really about to say something idiotic - so don't post. And if you do "think" you read something, verify it and post a link. Quite honestly, you are too stupid to be believed without proof so stop doing a disservice to the community by posting bullshit as truth.

Emiel, that's way too much code. How do you know something else isn't hanging or preventing the code from working how you think? Does this simple loop fail to update?

For $i = 1 To 10
    TrayTip("Loop: " & $i, $i, 5, 16)
    Sleep(1000)
Next
If all else fails, try calling TrayTip("", "") before you try to update it and that should clear it and allow a new one to be displayed.

Share this post


Link to post
Share on other sites

#12 ·  Posted (edited)

Hi Valik,

thnx

TrayTip("", "",0) did the trick .. however

Your test code works 100% on Vista and Windows XP but not perfect on Windows 2000..

For $i = 1 To 10
    TrayTip("Loop: " & $i, $i, 5, 16)
    Sleep(1000)
Next

It looks like Windows 2000 does not update the tray every second .. but just random .. for example

three times on a row every second.. then every 3 seconds etc etc

Best regards,

Emiel

Edited by Emiel Wieldraaijer

Best regards,Emiel Wieldraaijer

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0