help creating silent installer

[xpwhittyx]

Hello after watching a video tutorial on how to compile a silent installer I tried it myself. First when I opened the compiled exe it would just continue to open over and over again so I then added a script to stop that, but when I open the exe the autoit icon appears in the tray and nothing happens. Here is what I've got

expandcollapse popup

;Script to silently install TTPack
$SF_1 = "TTPack.exe"

If WinExists ( $SF_1 ) Then Exit
AutoItWinSetTitle ( $SF_1)

Run("TTpack.exe")

; Welcome
WinWaitActive  ("TTPack Setup" , "Welcome")
ControlClick   ("TTPack Setup" , "Button2")

; Components
WinWaitActive  ("TTPack Setup" , "Components")
Send           ("{SPACE}") 
Send           ("{DOWN}") 
Send           ("{SPACE}") 
Send           ("{DOWN}") 
Send           ("{SPACE}") 
Send           ("{DOWN}")
Send           ("{DOWN}")
Send           ("{DOWN}")
Send           ("{DOWN}")
Send           ("{DOWN}")
Send           ("{DOWN}")
Send           ("{DOWN}")
Send           ("{SPACE}")
ControlClick   ("TTPack Setup" , "Button2")

; Destination Location
WinWaitActive  ("TTPack Setup" , "Destination Location")
Send           ( @ProgramFilesDir & "\TTPack" )  
ControlClick   ("TTPack Setup" , "Button2")

; RealLite Options
WinWaitActive  ("TTPack Setup" , "RealLite Options")
Send          ("C:\Program Files\Media Player Classic\mplayerc.exe")
ControlClick   ("TTPack Setup" , "Button2")

; Browser Options
WinWaitActive  ("TTPack Setup" , "Browser Options")
ControlClick   ("TTPack Setup" , "Button2")

; Start Menu
WinWaitActive  ("TTPack Setup" , "Start Menu Options")
Send           ("{TAB}") 
Send           ("{TAB}") 
Send           ("{SPACE}") 
ControlClick   ("TTPack Setup" , "Button2")

; Installation Complete
WinWaitActive  ("TTPack Setup" , "Installation Complete")
ControlClick   ("TTPack Setup" , "Button2")

; Completing Setup
WinWaitActive  ("TTPack Setup" , "Completing Setup")
ControlClick   ("TTPack Setup" , "Button2")

Can anyone help me?

[MHz]

Welcome xpwhittyx,

By what I can understand, your script justs installs QuickTime Alternative Lite and Real Alternative Lite. Both of these are available as single installers and use Inno Setup so use the switch of /verysilent will install both silent without hassle. That is the method I opt for.

Many issues I noticed within your script and this script is based on TTPack v2.2.0.3. I noticed a setup.ini mentioned on the website of TTPack and could be an easier method to handle the installer perhaps.

expandcollapse popup

;Script to silently install TTPack v2.2.0.3
$SF_1 = "TTPack.exe"

If WinExists ($SF_1) Then Exit
AutoItWinSetTitle ($SF_1)

Opt('TrayIconDebug', 1)
$pid = Run ($SF_1)
AdlibEnable ('_Adlib')

; Welcome
WinWait        ("TTPack Setup" , "Welcome to the TTPack Setup Wizard")
ControlClick   ("TTPack Setup" , "Welcome to the TTPack Setup Wizard" , "Button2")

AdlibDisable ()

; Components
WinWait        ("TTPack Setup" , "Choose Components")
ControlFocus   ("TTPack Setup" , "Choose Components" , "SysTreeView321")
ControlSend    ("TTPack Setup" , "Choose Components" , "SysTreeView321" , "{SPACE}{DOWN}{SPACE}{DOWN}{SPACE}{DOWN 7}{SPACE}")
ControlClick   ("TTPack Setup" , "Choose Components" , "Button2")

; Destination Location
WinWait        ("TTPack Setup" , "Choose Install Location")
ControlSetText ("TTPack Setup" , "Choose Install Location" , 'Edit1' , @ProgramFilesDir & "\TTPack") 
ControlClick   ("TTPack Setup" , "Choose Install Location" , "Button2")

; RealLite Options
WinWait        ("TTPack Setup" , "ReaLite's Options")
ControlSetText ("TTPack Setup" , "ReaLite's Options" , 'Edit1' , @ProgramFilesDir & "\Media Player Classic\mplayerc.exe")
ControlClick   ("TTPack Setup" , "ReaLite's Options" , "Button2")

; Browser Options
WinWait        ("TTPack Setup" , "Alternative Browsers' Options")
ControlClick   ("TTPack Setup" , "Alternative Browsers' Options" , "Button2")

; Start Menu
WinWaitActive  ("TTPack Setup" , "Choose Start Menu Folder")
ControlClick   ("TTPack Setup" , "Choose Start Menu Folder" , "Button4")
ControlClick   ("TTPack Setup" , "Choose Start Menu Folder" , "Button2")

; Installation Complete
WinWait        ("TTPack Setup" , "Installation Complete")
ControlClick   ("TTPack Setup" , "Installation Complete" , "Button2")

; Completing Setup
WinWait        ("TTPack Setup" , "Completing the TTPack Setup Wizard")
ControlClick   ("TTPack Setup" , "Completing the TTPack Setup Wizard" , "Button2")

ProcessWaitClose ($pid, 10)

Exit

Func _Adlib ()
    If WinExists ('Installer Language' , 'Please select') Then
        ControlClick ('Installer Language' , 'Please select', 'Button1')
    EndIf
EndFunc

Try it and see if it helps.