how to delete everything in a list

[NewBooty]

how do i do this? i tried

(made myself)

Func _GUICtrlListBox_DeleteAllStrings($_ListBox)

$Count = _GUICtrlListBox_GetCount($_ListBox)

_GUICtrlListBox_BeginUpdate($_ListBox)

MsgBox(0, "", $Count)

For $h=1 To $Count

_GUICtrlListBox_DeleteString($_ListBox, $h)

Next

_GUICtrlListBox_EndUpdate($_ListBox)

EndFunc

[MrCreatoR]

Hi and Wellcome!

Have you tried this:

GUICtrlSetData($List, "")

[NewBooty]

no i havnt that seems 2 simple to work . i will try it thx

[NewBooty]

it dont work sorry maam

[danielkza]

#include <GUIListBox.au3>
#include <GUIConstants.au3>

GuiCreate("",500,500)
$list = GuiCtrlCreateList("",0,0,500,400)
$del = GUICtrlCreateButton("Delete All",100,425,100,25)
$add = GUICtrlCreateButton("Add 50",300,425,100,25)
AddItems()

GUISetState()

While 1
    Switch GuiGetMsg()
        Case $del
            DelItems()
        Case $add
            AddItems()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func AddItems()
    _GUICtrlListBox_BeginUpdate(GUICtrlGetHandle($List))
    For $i = 1 To 50
        _GUICtrlListBox_AddString(GUICtrlGetHandle($List),"Item " & $i)
    Next
    _GUICtrlListBox_EndUpdate(GUICtrlGetHandle($List))
EndFunc

Func DelItems()
    _GUICtrlListBox_BeginUpdate(GUICtrlGetHandle($List))
    _GUICtrlListBox_ResetContent(GUICtrlGetHandle($List))
    _GUICtrlListBox_EndUpdate(GUICtrlGetHandle($List))
EndFunc

Edited May 2, 2008 by danielkza

[MrCreatoR]

it dont work sorry maam

It works with built-in function, and i am not a "maam"

#include <GuiConstants.au3>

$GUI = GUICreate("Test Script", 300, 200)

$ListBox = GUICtrlCreateList("", 20, 40, 260, 150)
GUICtrlSetData(-1, "Item1|Item2")

$Clear_Button = GUICtrlCreateButton("Clear List", 20, 10, 80, 20)

GUISetState(@SW_SHOW, $GUI)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Clear_Button
            GUICtrlSetData($ListBox, "")
    EndSwitch
WEnd

If you are using the «_GUICtrlListBox_Create($GUI)» UDF to create list box, then you can clear it with «_GUICtrlListBox_ResetContent($ListBox)» UDF.

[Kip]

@newbooty: you could read the helpfile

Edit: Whoops, you're already banned.

Edited May 2, 2008 by kip