GUICtrlRead

[Vladi243]

I created a simple GUI with inputbox and button.

The problem is that the value that I put in the inputbox isn't read.

I tried 2 scripts.

#include <GUIConstants.au3>

Opt("GUIOnEventMode", 1); Change to OnEvent mode

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 293, 117, 301, 284)
$Input1 = GUICtrlCreateInput("", 67, 24, 150, 21)
$Button1 = GUICtrlCreateButton("OK", 104, 72, 81, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

;Events
GUICtrlSetOnEvent($Button1, "clicked")
GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func clicked()
    GUIDelete()
    Run ("C:\Program Files\Mozilla Firefox\firefox.exe")
    Sleep (5000)
    Send ("{TAB 2}")
    $ReadInput1=GUICtrlRead ($Input1) 
    Send ($ReadInput1);Its not working. Sending only the number "0".
EndFunc

#include <GUIConstants.au3>

Opt("GUIOnEventMode", 1); Change to OnEvent mode

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 293, 117, 301, 284)
$Input1 = GUICtrlCreateInput("", 67, 24, 150, 21)
$Button1 = GUICtrlCreateButton("OK", 104, 72, 81, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

;Events
GUICtrlSetOnEvent($Button1, "clicked")
GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func clicked()
    GUIDelete()
    Run ("C:\Program Files\Mozilla Firefox\firefox.exe")
    Sleep (5000)
    Send ("{TAB 2}")
    Send (GUICtrlRead ($Input1));Its not working. Sending only the number "0".
EndFunc

What's wrong with my script.

[Kyme]

you can read gui if youre Form1 it's close....make it to don't close when you press "Ok" or use IniWrite/IniRead

hope to help you

[Vladi243]

OK, I'll try it later.

Thank you.

[TnTProductions]

sorry i found even more errors but now its fixed so here is finished code

#include <GUIConstants.au3>

Opt("GUIOnEventMode", 1); Change to OnEvent mode

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 293, 117, 301, 284)
$Input1 = GUICtrlCreateInput("", 67, 24, 150, 21)
$Button1 = GUICtrlCreateButton("OK", 104, 72, 81, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Select 
        Case $nMsg = $GUI_EVENT_CLOSE
            ExitLoop

    GUIDelete()
    Run ("C:\Program Files\Mozilla Firefox\firefox.exe")
    Sleep (5000)
    Send ("{TAB 2}")
    Case $nMsg = $button1
    $ReadInput1 = GUICtrlRead($Input1)
    Send($ReadInput1);Its not working. Sending only the number "0".
EndSelect
WEnd

P.S add an exit functions its real annoying not being able to exit your script!!!

Edited May 25, 2008 by TnTProductions

[Vladi243]

This script isn't working. When I press on OK button there are no reaction. I want that after pressing on OK, it will continue the script.

[sandin]

what does Send ("{TAB 2}") means?

what are you trying to achieve with your script?

[Vladi243]

I'm trying to create a bot that writing and sending commands in the browser instead of me.

The script above is just a simple example, so I can learn how to use with GUICtrlRead(). As I've already said, this function doesn't working for me.

[sandin]

...anywayz, this will send your input:

#include <GUIConstants.au3>

Opt("GUIOnEventMode", 1); Change to OnEvent mode

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 293, 117, 301, 284)
$Input1 = GUICtrlCreateInput("", 67, 24, 150, 21)
$Button1 = GUICtrlCreateButton("OK", 104, 72, 81, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

;Events
GUICtrlSetOnEvent($Button1, "clicked")
GUISetOnEvent($GUI_EVENT_CLOSE, "_exit")
GUISetState()

While 1
  Sleep(10)
WEnd

func _exit()
    Exit
EndFunc

Func clicked()
    Local $ReadInput1 = GUICtrlRead($Input1)
    GUIDelete($Form1)
    Run ("C:\Program Files\Mozilla Firefox\firefox.exe")
    Sleep (5000)
    Send ("{TAB 2}")
    Send ($ReadInput1)
    Exit
EndFunc

[enaiman]

IMO, your problem is that you're deleting the GUI first and try to read from it after ... and that can't work.

What you can do is: read the value prior to deleting.

#include <GUIConstants.au3>

Opt("GUIOnEventMode", 1); Change to OnEvent mode
Dim $StringToSend
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 293, 117, 301, 284)
GUISetOnEvent($GUI_EVENT_CLOSE, "ExitFunc")
$Input1 = GUICtrlCreateInput("", 67, 24, 150, 21)
$Button1 = GUICtrlCreateButton("OK", 104, 72, 81, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

;Events
GUICtrlSetOnEvent($Button1, "clicked")
GUISetState()

While 1
    Sleep(200)
WEnd

Func clicked()
    $StringToSend = GUICtrlRead ($Input1)
    MsgBox(0, "Sending to Firefox", $StringToSend)
    GUIDelete()
    Run ("C:\Program Files\Mozilla Firefox\firefox.exe")
    Sleep (5000)
    Send ("{TAB 2}")
    Send ($StringToSend);Its not working. Sending only the number "0".
EndFunc

Func ExitFunc()
    Exit
EndFunc

[Vladi243]

Thanks guys!!!

The both scripts is sending my input:).

[rasim]

Vladi243

Don`t mix GUIOnEventMode with GUIGetMsg.

[Vladi243]

Vladi243

Don`t mix GUIOnEventMode with GUIGetMsg.

OK, but why???

[sandin]

cause only one of them can work, it's either GuiGetMsg, or GuiOnEventMode.