how can i get variable path to mozilla firefox cache?

[nobbe]

so far i got this

how to get second part ??

$firefox_cache_dir = @UserProfileDir & "\Lokale Einstellungen\Anwendungsdaten\Mozilla\Firefox\Profiles\"; german version

does anyone know more?

thanks

Edited June 9, 2008 by nobbe

[d4rk]

There are folders contain cache in the Temporary folder

[nobbe]

yes but there must be an easier way than scanning the complete directory pathes structure for "firefox " and "cache" ??

[d4rk]

Look at Temporary Looker at my sign , it contains code finding those folder

[gcue]

read the profiles.ini

$ini=(@userprofiledir & "\application data\mozilla\firefox\profiles.ini")

$prof_path=iniread($ini, "Profile0", "path", "default")

$fx_prof=StringSplit($prof_path, "/")

msgbox (0, "", $fx_prof[2])

[nobbe]

Look at Temporary Looker at my sign , it contains code finding those folder

ok i tried it - it works nicely, but only for internet explorer - i still have no clue on the firefox part :-(

here is a result from the log file

C:\Dokumente und Einstellungen\me\Lokale Einstellungen\Temporary Internet Files\Content.IE5\09C70JSZ\82

[nobbe]

thanks , but now the "MIDDLE" is missing :-(

my profiles is in

"c:\Dokumente und Einstellungen\me\Anwendungsdaten\Mozilla\Firefox\profiles.ini"

and contains

[General]

StartWithLastProfile=1

[Profile0]

Name=default

IsRelative=1

Path=Profiles/aob8m812.default

but i need to find the full path to

$firefox_cache_dir = "c:\Dokumente und Einstellungen\me\Lokale Einstellungen\Anwendungsdaten\Mozilla\Firefox\Profiles\aob8m812.default\Cache\";

so

$firefox_cache_dir = @UserProfileDir & "\Lokale Einstellungen\Anwendungsdaten\Mozilla\Firefox\Profiles\"; german

and i need a substitute for ""\Lokale Einstellungen\Anwendungsdaten\"

[TicTaC]

$fSearch = FileFindFirstFile(@AppDataDir & "\Mozilla\Firefox\Profiles\*")
$fprofile = @UserProfileDir & "\Local Settings\Application Data\Mozilla\Firefox\Profiles\" & FileFindNextFile($fSearch)
$fCache = $fProfile & "\Cache"
MsgBox(0, "", $fCache)

[ProgAndy]

You could try:

@AppDataCommonDir

@AppDataDir

RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders","Local AppData")

( [ User\Local Settings\Application Data ] , not as macro yet)

for me, @AppDataDir fits, but mine is in User\Application Data

and not User\Local Settings\Application Data

[nobbe]

i found something now

expandcollapse popup

; Constants for Special Folders in Windows

Const $Internet_Explorer                   = 0x1
Const $Programs                          = 0x2
Const $Control_Panel                            = 0x3
Const $Printers_and_Faxes             = 0x4
Const $My_Documents      = 0x5
Const $Favorites                      = 0x6
Const $Startup        = 0x7
Const $My_Recent_Documents            = 0x8
Const $SendTo               = 0x9
Const $Recycle_Bin        = 0xa
Const $Start_Menu               = 0xb
Const $My_Music                          = 0xd
Const $My_Videos                            = 0xe
Const $Desktop              = 0x10
Const $My_Computer              = 0x11
Const $My_Network_Places                        = 0x12
Const $NetHood              = 0x13
Const $Fonts                            = 0x14
Const $Templates                            = 0x15
Const $All_Users_Start_Menu      = 0x16
Const $All_Users_Programs                  = 0x17
Const $All_Users_Startup                        = 0x18
Const $All_Users_Desktop                        = 0x19
Const $Application_Data      = 0x1a
Const $PrintHood                            = 0x1b
Const $Local_Settings_Application_Data      = 0x1c
Const $All_Users_Favorites            = 0x19
Const $Local_Settings_Temporary_Internet_Files  = 0x20
Const $Cookies              = 0x21
Const $Local_Settings_History               = 0x22
Const $All_Users_Application_Data            = 0x23
Const $Windows              = 0x24
Const $System32       = 0x25
Const $Program_Files                            = 0x26
Const $My_Pictures              = 0x27
Const $User_Profile       = 0x28
Const $Common_Files      = 0x2b
Const $All_Users_Templates            = 0x2e
Const $Administrative_Tools      = 0x2f
Const $Network_Connections            = 0x31
Const $CD_Burning_Folder                        = 0x003b


Func _Special_Folders ($Folder)
local $f1 
local $objShell = ObjCreate("Shell.Application")
;
;$objShell.open($objShell.NameSpace($Folder))   
;$f1 = $objShell.NameSpace($Folder).Self.Name; name only of folder 
$f1 = $objShell.NameSpace($Folder).Self.Path; !!!!!

return $f1 

EndFunc


; full path without substitutes
;$firefox_cache_dir = "c:\Dokumente und Einstellungen\me\Lokale Einstellungen\Anwendungsdaten\Mozilla\Firefox\Profiles\";

;;; !! now path to fire fox full 
$firefox_cache_dir = _Special_Folders($Local_Settings_Application_Data) & "\Mozilla\Firefox\Profiles\"; german

[nobbe]

$fSearch = FileFindFirstFile(@AppDataDir & "\Mozilla\Firefox\Profiles\*")
$fprofile = @UserProfileDir & "\Local Settings\Application Data\Mozilla\Firefox\Profiles\" & FileFindNextFile($fSearch)
$fCache = $fProfile & "\Cache"
MsgBox(0, "", $fCache)

thanks but i needed also to substitute "\Local Settings\" - because i cannot hardcode this !

[ProgAndy]

No need for Objects !

The Special Folders are all in "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"

$ff = @AppDataDir & "\Mozilla\Firefox\profiles.ini"
$prof_path=iniread($ff, "Profile0", "path", "default")
;~ MsgBox(0, '', $prof_path)
$localAppdata = RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders","Local AppData")
$cache_Path = $localAppdata & "\Mozilla\Firefox\" & $prof_path & "\Cache"
If Not FileExists($cache_Path) Then $cache_Path = @AppDataDir & "\Mozilla\Firefox\" & $prof_path & "\Cache"
If Not FileExists($cache_Path) Then Exit MsgBox(0, 'Error', "No Firefox Cache found")
MsgBox(0, 'Cache Path:', $cache_Path)

[nobbe]

@progandy :

thanks alot, this works now (was quite tricky and i couldnt find the appropriate registry settings - because i was searching for firefox in the registry)