Disable service in xp

[tinkythomas]

Hi,

I am trying to modify a vbscript for use in autoit. The code I have is as follows:

_DisableService("Alerter", "Disabled")

Func _DisableService($service, $State)
    
    Dim $objWMIService, $colServiceList, $objService, $errReturnCode
    Dim $strComputer
    
    $strComputer = "."
    $objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\cimv2")
    
    ;ConsoleWrite($objWMIService)

    $colServiceList = $objWMIService.ExecQuery _
            ("Select * from Win32_Service where Name = " & "'" & $service & "'" & '"')
    
    ;ConsoleWrite($colServiceList)

    For $objService In $colServiceList
        If $objService.State = "Running" Then
            $objService.StopService()
            Sleep(5000)
        EndIf
        $objService.ChangeStartMode($State)
    Next

EndFunc   ;==>_DisableService

But this doesn't work and I can't figure it out. Can anyone help me?

Thanks

[Jos]

Try:

_DisableService("Alerter", "Disabled")
Func _DisableService($service, $State)
    Dim $objWMIService, $colServiceList, $objService, $errReturnCode
    Dim $strComputer
    $strComputer = "."
    $objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\cimv2")
;ConsoleWrite($objWMIService)
    $colServiceList = $objWMIService.ExecQuery _
            ("Select * from Win32_Service where Name = '" & $service & "'")
;ConsoleWrite($colServiceList)
    For $objService In $colServiceList
        If $objService.State = "Running" Then
            $objService.StopService()
            Sleep(5000)
        EndIf
        $objService.ChangeStartMode($State)
    Next
EndFunc  ;==>_DisableService

Jos

[tinkythomas]

Thank you so much! I can never get literal strings right. I can never work out where to put a single or double quote

All is now working perfectly!