how do i get the application window after using run command?

[carolvan]

i use run command to launch an application tool, for example, MSN.

and then how do i get this application tool name and other parameters in order to input username and password automatically by using autoit?

please help.

thanks a lot. guys.

[BrettF]

Do you mean like the following?

$PID = Run("");Path for aplication exe
$hWnd = _GetHwndFromPID ($PID)
WinWait ($hWnd)

$title = WinGetTitle ($hWnd)
$text = WinGetText ($hWnd)

MsgBox (0, "Window Info!", "PID = " & $PID & @CRLF & "HWND = " & $hWnd & @CRLF & "TITLE = " & $title & @CRLF & "TEXT = " & $text)

Func _GetHwndFromPID ($PID)
    $hWnd = 0
    $stPID = DllStructCreate("int")
    Do
        $winlist2 = WinList()
        For $i = 1 To $winlist2[0][0]
            If $winlist2[$i][0] <> "" Then
                DllCall("user32.dll", "int", "GetWindowThreadProcessId", "hwnd", $winlist2[$i][1], "ptr", DllStructGetPtr($stPID))
                If DllStructGetData($stPID, 1) = $PID Then
                    $hWnd = $winlist2[$i][1]
                    ExitLoop
                EndIf
            EndIf
        Next
        Sleep(100)
    Until $hWnd <> 0
    Return $hWnd
EndFunc

Cheers,

Brett