exclude windows from a list

[Influx]

Ok I have some Windows That i do not want to be counted and added to an array using the following code(usign the EXACT name)

Window names:
"Start[CL:102939]"
"Start"
"Desktop"
"Start Menu[CL:102938]"
"desktop[CL:102937]"
"Program Manager"

; Only display visble windows that have a title
    If $var[$i][0] <> "" And _WinAPI_IsWindowVisible($var[$i][1]) Then
            
                $b = $b + 1
    EndIf
Next
Dim $xyz[$b]
For $i = 1 To $var[0][0]

    ; Only display visble windows that have a title
    If $var[$i][0] <> "" And _WinAPI_IsWindowVisible($var[$i][1])  Then
        
        
        $xyz[$a] = $var[$i][0]
        $a = $a + 1

    EndIf
Next

How would I do this?

Thanks,

Influx.

[MrCreatoR]

#include <Array.au3>

$sExclude_List = "Start[CL:102939]|Start|Desktop|Start Menu[CL:102938]|desktop[CL:102937]|Program Manager"
$aWinList = _WinListEx(Default, Default, $sExclude_List)

_ArrayDisplay($aWinList)

Func _WinListEx($sTitle="", $sText="", $sExclude_List="")
    Local $aWinList, $aRetWinList
    $sExclude_List = "|" & $sExclude_List & "|"
    
    If $sTitle = -1 Or (IsKeyword($sTitle) And $sTitle = Default) Then
        $aWinList = WinList()
    Else
        $aWinList = WinList($sTitle, $sText)
    EndIf
    
    Dim $aRetWinList[$aWinList[0][0]+1]
    
    For $i = 1 To $aWinList[0][0]
        ;Only display visible windows that have a title
        If $aWinList[$i][0] = "" Or Not BitAND(WinGetState($aWinList[$i][1]), 2) Then ContinueLoop
        
        ;Add to array all win titles that is not in the exclude list
        If Not StringInStr($sExclude_List, "|" & $aWinList[$i][0] & "|") Then
            $aRetWinList[0] += 1
            $aRetWinList[$aRetWinList[0]] = $aWinList[$i][0]
        EndIf
    Next
    
    ReDim $aRetWinList[$aRetWinList[0]+1]
    Return $aRetWinList
EndFunc

[Influx]

thanks, how exactly would i intrgrate this to gts the number of windows, and have them all in an array, ad my above code does?

[MrCreatoR]

thanks, how exactly would i intrgrate this to gts the number of windows, and have them all in an array, ad my above code does?

$aWinList returned by _WinListEx() it's already array, and $aWinList[0] it's a total windows count .