A customized button with image and label ?!?

[Armand]

how do i make a click-able button with a BG image set and place some text on it ?

[FireFox]

@Armand

you should search in help helpfile...

#include <GuiButton.au3>
$btn = GUICtrlCreateButton("", 5, 5, 26, 26, $BS_ICON)
_GUICtrlButton_SetImage($btn, 'shell32.ico', -3)

Cheers, FireFox.

[MrCreatoR]

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiButton.au3>
;

$hGUI   = GUICreate("Button With Icons + Text")

$btn1   = _GUICtrlCreateButton("Button1", 10, 10, 90, 25, -1, -1, "shell32.dll", 6, $BUTTON_IMAGELIST_ALIGN_LEFT)
$btn2   = _GUICtrlCreateButton("Button2", 10, 50, 90, 25, -1, -1, "shell32.dll", 21, $BUTTON_IMAGELIST_ALIGN_RIGHT)
$btn3   = _GUICtrlCreateButton("Button3", 10, 90, 50, 50, -1, -1, "shell32.dll", 32, $BUTTON_IMAGELIST_ALIGN_TOP)
$btn4   = _GUICtrlCreateButton("Button4", 10, 140, 50, 50, -1, -1, "shell32.dll", 14, $BUTTON_IMAGELIST_ALIGN_BOTTOM)

GUISetState()

While GUIGetMsg() <> $GUI_EVENT_CLOSE
WEnd

Exit

Func _GUICtrlCreateButton($sText,$iLeft,$iTop,$iWidth=-1,$iHeight=-1,$nStyle=-1,$nExStyle=-1,$sIconFile='', $nIconID=0, $nAlign=-1)
    Local $nID = GUICtrlCreateButton($sText, $iLeft, $iTop, $iWidth, $iHeight, $nStyle, $nExStyle)
    
    If $sIconFile = '' Then Return $nID
    
    Local $hIL = _GUIImageList_Create(16, 16, 5, BitOr($ILC_MASK, $ILC_COLOR32), 0, 1)
    
    _GUIImageList_AddIcon($hIL, $sIconFile, $nIconID)
    _GUICtrlButton_SetImageList($nID, $hIL)
    
    Return $nID
EndFunc

[MrCreatoR]

@Armand

you should search in help helpfile...

#include <GuiButton.au3>
$btn = GUICtrlCreateButton("", 5, 5, 26, 26, $BS_ICON)
_GUICtrlButton_SetImage($btn, 'shell32.ico', -3)

Cheers, FireFox.

And you should first read carefully what the OP is asking for, and check what you are posting

Your example will not work with text.

[FireFox]

@MrCreator

Yep, but working for picture... I dont care if its not what he wants. I just want to help him a little and if he isnt happy, he should search in helpfile...

Cheers, FireFox.

Edited January 18, 2009 by FireFox

[Armand]

Almost... but not quit what i wanted / needed...

well... I just wanted to set the background for the button and have different text shown OVER that bg whenever i want...

using that "_GUICtrlCreateButton" func only adds the image to the control... and yet it's Z-index is over the text....

[Melba23]

Armand,

I cannot help with text over picture, but I can offer you text AND image:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>

$mywin = GUICreate("Images amd Text on Buttons", 210, 440)

; Button 1 uses an icon - small version of 32x32 - replaces text
$btn1 = GUICtrlCreateButton("Test 1 - Test 1", 30, 30, 150, 64, $BS_ICON)
GUICtrlSetImage($btn1, "Test.ico", 1, 0)

; Button 2 uses an icon - large version of 32x32 - replaces text
$btn2 = GUICtrlCreateButton("Test 2 - Test 2", 30, 110, 150, 64, $BS_ICON)
GUICtrlSetImage($btn2, "Test.ico", 1, 1)

; Button 3 uses a bitmap - actual size - replaces text
$btn3 = GUICtrlCreateButton("Test 3 - Test 3", 30, 190, 150, 64, $BS_BITMAP)
GUICtrlSetImage($btn3, "Test.bmp")

; Buttons 4 & 5 use Valuater's UDF and place the icon where user requires - user chosen size - also shows text 
$btn4 = IconButton("Test 4 - Test 4", 30, 270, 150, 64, 16, "Test.ico")

$btn5 = IconButton("Test 5 - Test 5", 30, 350, 150, 64, 32, "Test.ico")

GUISetState()

While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then Exit
WEnd

GUIDelete()
    
Exit

; Valuater's UDF

Func IconButton($BItext, $BIleft, $BItop, $BIwidth, $BIheight, $BIconSize, $BIDLL, $BIconNum = -1)
    GUICtrlCreateIcon($BIDLL, $BIconNum, $BIleft + 5, $BItop + (($BIheight - $BIconSize) / 2), $BIconSize, $BIconSize)
    GUICtrlSetState( -1, $GUI_DISABLE)
    $XS_btnx = GUICtrlCreateButton($BItext, $BIleft, $BItop, $BIwidth, $BIheight, $WS_CLIPSIBLINGS)
    Return $XS_btnx
EndFunc

And again full credit to Valuater for the UDF.

All you need to do is have a .bmp and a .ico file in the same folder as this script and it will show you how the different codings work.

M23

[Robjong]

hey,

think this is what you need

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>


Global $hMainGUI = GUICreate('PicButton')
Global $ahPicButton1 = _GUICtrlCreatePicButton("Button1", "picbtn.jpg", 10, 10, 75, 25) ; create our picbutton
GUICtrlSetCursor($ahPicButton1[0], 0) ; set the cursor to handpoint
GUISetState(@SW_SHOW, $hMainGUI)


While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $ahPicButton1[0], $ahPicButton1[1] ; check if either the label or pic was clicked
            MsgBox(64, "ImageButton", "You clicked on image button 1")
    EndSwitch

    Sleep(25)
WEnd


;================================================================================
; Function Name....: _GUICtrlCreatePicButton
; Description......: Create a pic as background with an overlaying label for the text
; Syntax...........: _GUICtrlCreatePicButton($sText, $sImg, $iLeft, $iTop[, $iWidth = Default[, $iHeight = Default]])
; Parameter(s).....: $sText - The text to write in the label of the button
;                    $sImg - The path to the image to use as the background of the button
;                    $iLeft - Distance from the left side of the gui.
;                    $iTop - Distance from the top side of the gui.
;                    $iWidth - [optional] The width of the control.
;                    $iHeight - [optional] The width of the control.
; Return Value(s)..: (Array) $aArray[0] = handle to the Pic, $aArray[1] = handle to the Label
; Requirement(s)...: -
; Related..........: - 
; Limitation(s)....: - 
; Comment(s).......: Does not work over other pic etc.
; Author(s)........: Robjong
; Modified.........: -
;================================================================================
Func _GUICtrlCreatePicButton($sText, $sImg, $iLeft, $iTop, $iWidth = Default, $iHeight = Default)
    If Not $iWidth Or $iWidth < 0 Or $iWidth == Default Then $iWidth = 75
    If Not $iHeight Or $iHeight < 0 Or $iHeight == Default Then $iHeight = 25
    
    Local $hCtrls[2] ; define an array for the controls
    $hCtrls[0] = GUICtrlCreatePic($sImg, $iLeft, $iTop, $iWidth, $iHeight, BitOR($SS_NOTIFY, $WS_GROUP, $WS_CLIPSIBLINGS)) ; create bg pic
    $hCtrls[1] = GUICtrlCreateLabel($sText, $iLeft, $iTop, $iWidth, $iHeight, BitOR($SS_NOTIFY, $SS_CENTER, $SS_CENTERIMAGE)) ; create text label ontop of the pic
    
    GUICtrlSetBkColor($hCtrls[0], $GUI_BKCOLOR_TRANSPARENT) ; set Pic bkclolor to transparent
    GUICtrlSetBkColor($hCtrls[1], $GUI_BKCOLOR_TRANSPARENT) ; set Label bkclolor to transparent
    
    Return $hCtrls ; return array with control handles
EndFunc   ;==>_GUICtrlCreatePicButton

Edit: comments + func header

Edited January 18, 2009 by Robjong

[FireFox]

@Armand

GuiCtrlSetTip on picture ?

Cheers, FireFox.

Edited January 18, 2009 by FireFox

[Valuater]

_ButtonHover()... demo included

http://www.autoitscript.com/forum/index.ph...amp;showfile=33

8)

[Robjong]

_ButtonHover()... demo included

http://www.autoitscript.com/forum/index.ph...amp;showfile=33

8)

think thats your best bet