GUI => Close child without closing parent

[DarkBoost]

I have a simple GUI Parent and Child however when I close the Child it also closes the Parent

#Include <GuiConstantsEx.au3>

Opt("MustDeclareVars",1)

Dim $guimain, $guichild, $guibutton, $msg

$guimain = GUICreate("",400,400)
$guibutton = GUICtrlCreateButton("child",165,180,60,20)

GUISetState(@SW_SHOW, $guimain)

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $guibutton
            $guichild = GUICreate("",200,200)
            GUISetState(@SW_SHOW, $guichild)
        
        Case $msg = $GUI_EVENT_CLOSE
            Exit
    EndSelect
WEnd

[Melba23]

DarkBoost,

Use the "advanced" parameter of GUIGetMsg to determine which window is sending the $GUI_EVENT_CLOSE:

#Include <GuiConstantsEx.au3>

Opt("MustDeclareVars",1)

Dim $guimain, $guichild, $guibutton, $array_msg

$guimain = GUICreate("",400,400)
$guibutton = GUICtrlCreateButton("child",165,180,60,20)

GUISetState(@SW_SHOW, $guimain)

While 1
    $array_msg = GUIGetMsg(1)
    Switch $array_msg[0]
        Case $guibutton
            $guichild = GUICreate("",200,200)
            GUISetState(@SW_SHOW, $guichild)
        Case $GUI_EVENT_CLOSE
            Switch $array_msg[1]
                Case $guichild
                    GUISetState(@SW_HIDE, $guichild)
                Case $guimain
                    Exit
            EndSwitch
    EndSwitch
WEnd

M23

[DarkBoost]

@Melba23: That makes sense, thank you very much!

[CodyBarrett]

OR you could just Hide the child.... but what ever you want

[DarkBoost]

I originally tried using Hide the child but was unable to show it again when clicking the button a second time.

[Melba23]

DarkBoost,

If you want the window to be created once, hidden on exit and then shown again each time you press the button, use this:

#Include <GuiConstantsEx.au3>

Opt("MustDeclareVars",1)

Dim $guimain, $guichild, $guibutton, $array_msg

$guimain = GUICreate("",400,400)
$guibutton = GUICtrlCreateButton("child",165,180,60,20)

GUISetState(@SW_SHOW, $guimain)

$guichild = GUICreate("",200,200)
GUISetState(@SW_HIDE, $guichild)

While 1
    $array_msg = GUIGetMsg(1)
    Switch $array_msg[0]
        Case $guibutton
            GUISetState(@SW_SHOW, $guichild)
        Case $GUI_EVENT_CLOSE
            Switch $array_msg[1]
                Case $guichild
                    GUISetState(@SW_HIDE, $guichild)
                Case $guimain
                    Exit
            EndSwitch
    EndSwitch
WEnd

M23

[DarkBoost]

Thank you very much Melba23 both examples have been very helpful.

New question, where do I put my code to control a button on the child window?

[Malkey]

Thank you very much Melba23 both examples have been very helpful.

New question, where do I put my code to control a button on the child window?

This way works.

#include <GuiConstantsEx.au3>

Opt("MustDeclareVars", 1)

Dim $guimain, $guichild, $guibutton, $array_msg, $guichildbutton

$guimain = GUICreate("", 400, 400)
$guibutton = GUICtrlCreateButton("child", 165, 180, 60, 20)

GUISetState(@SW_SHOW, $guimain)

$guichild = GUICreate("", 200, 200)
$guichildbutton = GUICtrlCreateButton("Button on child", 60, 90, 80, 20)
GUISetState(@SW_HIDE, $guichild)

While 1
    $array_msg = GUIGetMsg(1)
    Switch $array_msg[0]
        Case $guibutton
            GUISetState(@SW_SHOW, $guichild)
        Case $guichildbutton
            MsgBox(0, "", "Button on Child")
        Case $GUI_EVENT_CLOSE
            Switch $array_msg[1]
                Case $guichild
                    GUISetState(@SW_HIDE, $guichild)
                Case $guimain
                    Exit
            EndSwitch
    EndSwitch
WEnd