Jump to content
Sign in to follow this  
DarkBoost

GUI => Close child without closing parent

Recommended Posts

DarkBoost

I have a simple GUI Parent and Child however when I close the Child it also closes the Parent :)

#Include <GuiConstantsEx.au3>

Opt("MustDeclareVars",1)

Dim $guimain, $guichild, $guibutton, $msg

$guimain = GUICreate("",400,400)
$guibutton = GUICtrlCreateButton("child",165,180,60,20)

GUISetState(@SW_SHOW, $guimain)

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $guibutton
            $guichild = GUICreate("",200,200)
            GUISetState(@SW_SHOW, $guichild)
        
        Case $msg = $GUI_EVENT_CLOSE
            Exit
    EndSelect
WEnd

Share this post


Link to post
Share on other sites
Melba23

DarkBoost,

Use the "advanced" parameter of GUIGetMsg to determine which window is sending the $GUI_EVENT_CLOSE:

#Include <GuiConstantsEx.au3>

Opt("MustDeclareVars",1)

Dim $guimain, $guichild, $guibutton, $array_msg

$guimain = GUICreate("",400,400)
$guibutton = GUICtrlCreateButton("child",165,180,60,20)

GUISetState(@SW_SHOW, $guimain)

While 1
    $array_msg = GUIGetMsg(1)
    Switch $array_msg[0]
        Case $guibutton
            $guichild = GUICreate("",200,200)
            GUISetState(@SW_SHOW, $guichild)
        Case $GUI_EVENT_CLOSE
            Switch $array_msg[1]
                Case $guichild
                    GUISetState(@SW_HIDE, $guichild)
                Case $guimain
                    Exit
            EndSwitch
    EndSwitch
WEnd

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
DarkBoost

@Melba23: That makes sense, thank you very much!

Share this post


Link to post
Share on other sites
CodyBarrett

OR you could just Hide the child.... but what ever you want

Share this post


Link to post
Share on other sites
DarkBoost

I originally tried using Hide the child but was unable to show it again when clicking the button a second time.

Share this post


Link to post
Share on other sites
Melba23

DarkBoost,

If you want the window to be created once, hidden on exit and then shown again each time you press the button, use this:

#Include <GuiConstantsEx.au3>

Opt("MustDeclareVars",1)

Dim $guimain, $guichild, $guibutton, $array_msg

$guimain = GUICreate("",400,400)
$guibutton = GUICtrlCreateButton("child",165,180,60,20)

GUISetState(@SW_SHOW, $guimain)

$guichild = GUICreate("",200,200)
GUISetState(@SW_HIDE, $guichild)

While 1
    $array_msg = GUIGetMsg(1)
    Switch $array_msg[0]
        Case $guibutton
            GUISetState(@SW_SHOW, $guichild)
        Case $GUI_EVENT_CLOSE
            Switch $array_msg[1]
                Case $guichild
                    GUISetState(@SW_HIDE, $guichild)
                Case $guimain
                    Exit
            EndSwitch
    EndSwitch
WEnd

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
DarkBoost

Thank you very much Melba23 both examples have been very helpful.

New question, where do I put my code to control a button on the child window?

Share this post


Link to post
Share on other sites
Malkey

Thank you very much Melba23 both examples have been very helpful.

New question, where do I put my code to control a button on the child window?

This way works.
#include <GuiConstantsEx.au3>

Opt("MustDeclareVars", 1)

Dim $guimain, $guichild, $guibutton, $array_msg, $guichildbutton

$guimain = GUICreate("", 400, 400)
$guibutton = GUICtrlCreateButton("child", 165, 180, 60, 20)

GUISetState(@SW_SHOW, $guimain)

$guichild = GUICreate("", 200, 200)
$guichildbutton = GUICtrlCreateButton("Button on child", 60, 90, 80, 20)
GUISetState(@SW_HIDE, $guichild)

While 1
    $array_msg = GUIGetMsg(1)
    Switch $array_msg[0]
        Case $guibutton
            GUISetState(@SW_SHOW, $guichild)
        Case $guichildbutton
            MsgBox(0, "", "Button on Child")
        Case $GUI_EVENT_CLOSE
            Switch $array_msg[1]
                Case $guichild
                    GUISetState(@SW_HIDE, $guichild)
                Case $guimain
                    Exit
            EndSwitch
    EndSwitch
WEnd

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  

×

Important Information

We have placed cookies on your device to help make this website better. You can adjust your cookie settings, otherwise we'll assume you're okay to continue.