Anyone have an example of a startup script that only works ...

[Diana (Cda)]

Does anyone have have a working example of a Windows startup script that will launch a program, i.e., Notepad (just to give an easy example), the first time on any given day that Windows is launched?

I can handle the rest of the script now, it's just how to deal with keeping track of startups. I think an INI file might be used (?) but I'm not sure and, speaking of INIs, haven't broken that barrier successfully as yet.

Thanks! <g>

[Valuater]

Just put a shortcut in the startup folder.....done!

8)

[GEOSoft]

@Val. That won't do what she wants. It will run the app everytime Windows starts not just the first time. Here is a variation on your idea that will do it though. Just Compile the script and Run it once to create the Shortcut and Ini Entry and after that it will only start notepad if it's the first time windows is run that day.

$iDate = @Year & @Mon & @MDay

;; If the startup folder link doesn't exist then we create it
If NOT IsArray(FileGetShortcut(@StartupDir & "\" & @ScriptName & ".lnk")) Then
   FileCreateShortCut(@ScriptFullPath, @StartupDir & "\" & @ScriptName & ".lnk")
EndIf

$ini = @ScriptDir & "\sysrun.ini"
$lastrun = IniRead($Ini,"LastStart", "Date", "")
;; If the IniEntry doesn't exist or the date doesn't match then run the startup function, else Exit
If (NOT $lastRun) OR ($LastRun <> $iDate) Then _Startup()

Func _Startup()
   ShellExecute("notepad.exe")
   IniWrite($Ini, "LastStart", "Date", $iDate)
EndFunc

[Diana (Cda)]

Hi, GEOSoft! How are you?! <g>

I tried out your script immediately but have been testing it. I'm thinking I did something wrong. Here's my modified version, since I really need all the help I can get so tend to make the scripts as re-usable as possible right from the get-go.

expandcollapse popup

#NoTrayIcon     ; AutoIt's icon doesn't show in systray

;==========================================================
$appName  = "RDbdRem"
$appExec  = @ScriptDir & "\BIRTHDAY.EXE"
;----------------------------------------------------------
$iDate    = @Year & @Mon & @MDay
$shortcut = @StartupDir & "\" & @ScriptName & ".lnk"
;==========================================================


;----------------------------------------------------------
;  delete any old LNK, if it exists:
If FileExists($shortcut) THEN FileDelete($shortcut)
Sleep(150)
;----------------------------------------------------------
;  If the startup folder link doesn't exist then we create it
If NOT IsArray(FileGetShortcut(@StartupDir & "\" & @ScriptName & ".lnk")) Then
   FileCreateShortCut(@ScriptFullPath, $shortcut)
EndIf


;----------------------------------------------------------
$ini = @ScriptDir & "\z - " & $appName & "sysrun.ini"
;----------------------------------------------------------
;  delete any old INI, if it exists:
If FileExists($ini) THEN FileDelete($ini)
Sleep(150)
;----------------------------------------------------------
$lastrun = IniRead($Ini,"LastStart", "Date", "")
;; If the IniEntry doesn't exist or the date doesn't match then run the startup function, else Exit
If (NOT $lastRun) OR ($LastRun <> $iDate) Then _Startup()


Func _Startup()
   ShellExecute($appExec)
   IniWrite($Ini, "LastStart", "Date", $iDate)
EndFunc

The good thing is that the script works. The app I use it with, a birthday reminder app, does launch - it's just unfortunate that it launches each and every time Windows is run, which really sort of defeats the whole purpose.

So I'm guessing that I did something, somehow, to screw this up. For the life of me, I can't see what I've done.

Either than that, or the fact the the ini only has a date on it without anything, might indicate where the problem might lie (?).

The INI currently reads like this:

[LastStart]
Date=20090402

I've booted/rebooted a total of 3 times in total today, and the app has launched each and every time.

What could be the problem, can you tell? Perhaps it's even something completely different that's causing the problem that I can't see.

Anyway, thanks! <g>

[Jos]

How could this ever work?

If FileExists($ini) Then FileDelete($ini)
Sleep(150)
;----------------------------------------------------------
$lastrun = IniRead($ini, "LastStart", "Date", "")

[GEOSoft]

Jos is right. You can't delete that Ini file. It contains the data that determins if the app starts at startup or not.